checkpatch: fix false errors due to macro concatenation
[linux-2.6.git] / scripts / checkpatch.pl
1 #!/usr/bin/perl -w
2 # (c) 2001, Dave Jones. <davej@redhat.com> (the file handling bit)
3 # (c) 2005, Joel Schopp <jschopp@austin.ibm.com> (the ugly bit)
4 # (c) 2007,2008, Andy Whitcroft <apw@uk.ibm.com> (new conditions, test suite)
5 # (c) 2008,2009, Andy Whitcroft <apw@canonical.com>
6 # Licensed under the terms of the GNU GPL License version 2
7
8 use strict;
9
10 my $P = $0;
11 $P =~ s@.*/@@g;
12
13 my $V = '0.29';
14
15 use Getopt::Long qw(:config no_auto_abbrev);
16
17 my $quiet = 0;
18 my $tree = 1;
19 my $chk_signoff = 1;
20 my $chk_patch = 1;
21 my $tst_only;
22 my $emacs = 0;
23 my $terse = 0;
24 my $file = 0;
25 my $check = 0;
26 my $summary = 1;
27 my $mailback = 0;
28 my $summary_file = 0;
29 my $root;
30 my %debug;
31 my $help = 0;
32
33 sub help {
34         my ($exitcode) = @_;
35
36         print << "EOM";
37 Usage: $P [OPTION]... [FILE]...
38 Version: $V
39
40 Options:
41   -q, --quiet                quiet
42   --no-tree                  run without a kernel tree
43   --no-signoff               do not check for 'Signed-off-by' line
44   --patch                    treat FILE as patchfile (default)
45   --emacs                    emacs compile window format
46   --terse                    one line per report
47   -f, --file                 treat FILE as regular source file
48   --subjective, --strict     enable more subjective tests
49   --root=PATH                PATH to the kernel tree root
50   --no-summary               suppress the per-file summary
51   --mailback                 only produce a report in case of warnings/errors
52   --summary-file             include the filename in summary
53   --debug KEY=[0|1]          turn on/off debugging of KEY, where KEY is one of
54                              'values', 'possible', 'type', and 'attr' (default
55                              is all off)
56   --test-only=WORD           report only warnings/errors containing WORD
57                              literally
58   -h, --help, --version      display this help and exit
59
60 When FILE is - read standard input.
61 EOM
62
63         exit($exitcode);
64 }
65
66 GetOptions(
67         'q|quiet+'      => \$quiet,
68         'tree!'         => \$tree,
69         'signoff!'      => \$chk_signoff,
70         'patch!'        => \$chk_patch,
71         'emacs!'        => \$emacs,
72         'terse!'        => \$terse,
73         'f|file!'       => \$file,
74         'subjective!'   => \$check,
75         'strict!'       => \$check,
76         'root=s'        => \$root,
77         'summary!'      => \$summary,
78         'mailback!'     => \$mailback,
79         'summary-file!' => \$summary_file,
80
81         'debug=s'       => \%debug,
82         'test-only=s'   => \$tst_only,
83         'h|help'        => \$help,
84         'version'       => \$help
85 ) or help(1);
86
87 help(0) if ($help);
88
89 my $exit = 0;
90
91 if ($#ARGV < 0) {
92         print "$P: no input files\n";
93         exit(1);
94 }
95
96 my $dbg_values = 0;
97 my $dbg_possible = 0;
98 my $dbg_type = 0;
99 my $dbg_attr = 0;
100 for my $key (keys %debug) {
101         ## no critic
102         eval "\${dbg_$key} = '$debug{$key}';";
103         die "$@" if ($@);
104 }
105
106 if ($terse) {
107         $emacs = 1;
108         $quiet++;
109 }
110
111 if ($tree) {
112         if (defined $root) {
113                 if (!top_of_kernel_tree($root)) {
114                         die "$P: $root: --root does not point at a valid tree\n";
115                 }
116         } else {
117                 if (top_of_kernel_tree('.')) {
118                         $root = '.';
119                 } elsif ($0 =~ m@(.*)/scripts/[^/]*$@ &&
120                                                 top_of_kernel_tree($1)) {
121                         $root = $1;
122                 }
123         }
124
125         if (!defined $root) {
126                 print "Must be run from the top-level dir. of a kernel tree\n";
127                 exit(2);
128         }
129 }
130
131 my $emitted_corrupt = 0;
132
133 our $Ident      = qr{
134                         [A-Za-z_][A-Za-z\d_]*
135                         (?:\s*\#\#\s*[A-Za-z_][A-Za-z\d_]*)*
136                 }x;
137 our $Storage    = qr{extern|static|asmlinkage};
138 our $Sparse     = qr{
139                         __user|
140                         __kernel|
141                         __force|
142                         __iomem|
143                         __must_check|
144                         __init_refok|
145                         __kprobes|
146                         __ref
147                 }x;
148 our $Attribute  = qr{
149                         const|
150                         __read_mostly|
151                         __kprobes|
152                         __(?:mem|cpu|dev|)(?:initdata|init)|
153                         ____cacheline_aligned|
154                         ____cacheline_aligned_in_smp|
155                         ____cacheline_internodealigned_in_smp|
156                         __weak
157                   }x;
158 our $Modifier;
159 our $Inline     = qr{inline|__always_inline|noinline};
160 our $Member     = qr{->$Ident|\.$Ident|\[[^]]*\]};
161 our $Lval       = qr{$Ident(?:$Member)*};
162
163 our $Constant   = qr{(?:[0-9]+|0x[0-9a-fA-F]+)[UL]*};
164 our $Assignment = qr{(?:\*\=|/=|%=|\+=|-=|<<=|>>=|&=|\^=|\|=|=)};
165 our $Compare    = qr{<=|>=|==|!=|<|>};
166 our $Operators  = qr{
167                         <=|>=|==|!=|
168                         =>|->|<<|>>|<|>|!|~|
169                         &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%
170                   }x;
171
172 our $NonptrType;
173 our $Type;
174 our $Declare;
175
176 our $UTF8       = qr {
177         [\x09\x0A\x0D\x20-\x7E]              # ASCII
178         | [\xC2-\xDF][\x80-\xBF]             # non-overlong 2-byte
179         |  \xE0[\xA0-\xBF][\x80-\xBF]        # excluding overlongs
180         | [\xE1-\xEC\xEE\xEF][\x80-\xBF]{2}  # straight 3-byte
181         |  \xED[\x80-\x9F][\x80-\xBF]        # excluding surrogates
182         |  \xF0[\x90-\xBF][\x80-\xBF]{2}     # planes 1-3
183         | [\xF1-\xF3][\x80-\xBF]{3}          # planes 4-15
184         |  \xF4[\x80-\x8F][\x80-\xBF]{2}     # plane 16
185 }x;
186
187 our $typeTypedefs = qr{(?x:
188         (?:__)?(?:u|s|be|le)(?:8|16|32|64)|
189         atomic_t
190 )};
191
192 our @typeList = (
193         qr{void},
194         qr{(?:unsigned\s+)?char},
195         qr{(?:unsigned\s+)?short},
196         qr{(?:unsigned\s+)?int},
197         qr{(?:unsigned\s+)?long},
198         qr{(?:unsigned\s+)?long\s+int},
199         qr{(?:unsigned\s+)?long\s+long},
200         qr{(?:unsigned\s+)?long\s+long\s+int},
201         qr{unsigned},
202         qr{float},
203         qr{double},
204         qr{bool},
205         qr{struct\s+$Ident},
206         qr{union\s+$Ident},
207         qr{enum\s+$Ident},
208         qr{${Ident}_t},
209         qr{${Ident}_handler},
210         qr{${Ident}_handler_fn},
211 );
212 our @modifierList = (
213         qr{fastcall},
214 );
215
216 sub build_types {
217         my $mods = "(?x:  \n" . join("|\n  ", @modifierList) . "\n)";
218         my $all = "(?x:  \n" . join("|\n  ", @typeList) . "\n)";
219         $Modifier       = qr{(?:$Attribute|$Sparse|$mods)};
220         $NonptrType     = qr{
221                         (?:$Modifier\s+|const\s+)*
222                         (?:
223                                 (?:typeof|__typeof__)\s*\(\s*\**\s*$Ident\s*\)|
224                                 (?:$typeTypedefs\b)|
225                                 (?:${all}\b)
226                         )
227                         (?:\s+$Modifier|\s+const)*
228                   }x;
229         $Type   = qr{
230                         $NonptrType
231                         (?:[\s\*]+\s*const|[\s\*]+|(?:\s*\[\s*\])+)?
232                         (?:\s+$Inline|\s+$Modifier)*
233                   }x;
234         $Declare        = qr{(?:$Storage\s+)?$Type};
235 }
236 build_types();
237
238 $chk_signoff = 0 if ($file);
239
240 my @dep_includes = ();
241 my @dep_functions = ();
242 my $removal = "Documentation/feature-removal-schedule.txt";
243 if ($tree && -f "$root/$removal") {
244         open(my $REMOVE, '<', "$root/$removal") ||
245                                 die "$P: $removal: open failed - $!\n";
246         while (<$REMOVE>) {
247                 if (/^Check:\s+(.*\S)/) {
248                         for my $entry (split(/[, ]+/, $1)) {
249                                 if ($entry =~ m@include/(.*)@) {
250                                         push(@dep_includes, $1);
251
252                                 } elsif ($entry !~ m@/@) {
253                                         push(@dep_functions, $entry);
254                                 }
255                         }
256                 }
257         }
258         close($REMOVE);
259 }
260
261 my @rawlines = ();
262 my @lines = ();
263 my $vname;
264 for my $filename (@ARGV) {
265         my $FILE;
266         if ($file) {
267                 open($FILE, '-|', "diff -u /dev/null $filename") ||
268                         die "$P: $filename: diff failed - $!\n";
269         } elsif ($filename eq '-') {
270                 open($FILE, '<&STDIN');
271         } else {
272                 open($FILE, '<', "$filename") ||
273                         die "$P: $filename: open failed - $!\n";
274         }
275         if ($filename eq '-') {
276                 $vname = 'Your patch';
277         } else {
278                 $vname = $filename;
279         }
280         while (<$FILE>) {
281                 chomp;
282                 push(@rawlines, $_);
283         }
284         close($FILE);
285         if (!process($filename)) {
286                 $exit = 1;
287         }
288         @rawlines = ();
289         @lines = ();
290 }
291
292 exit($exit);
293
294 sub top_of_kernel_tree {
295         my ($root) = @_;
296
297         my @tree_check = (
298                 "COPYING", "CREDITS", "Kbuild", "MAINTAINERS", "Makefile",
299                 "README", "Documentation", "arch", "include", "drivers",
300                 "fs", "init", "ipc", "kernel", "lib", "scripts",
301         );
302
303         foreach my $check (@tree_check) {
304                 if (! -e $root . '/' . $check) {
305                         return 0;
306                 }
307         }
308         return 1;
309 }
310
311 sub expand_tabs {
312         my ($str) = @_;
313
314         my $res = '';
315         my $n = 0;
316         for my $c (split(//, $str)) {
317                 if ($c eq "\t") {
318                         $res .= ' ';
319                         $n++;
320                         for (; ($n % 8) != 0; $n++) {
321                                 $res .= ' ';
322                         }
323                         next;
324                 }
325                 $res .= $c;
326                 $n++;
327         }
328
329         return $res;
330 }
331 sub copy_spacing {
332         (my $res = shift) =~ tr/\t/ /c;
333         return $res;
334 }
335
336 sub line_stats {
337         my ($line) = @_;
338
339         # Drop the diff line leader and expand tabs
340         $line =~ s/^.//;
341         $line = expand_tabs($line);
342
343         # Pick the indent from the front of the line.
344         my ($white) = ($line =~ /^(\s*)/);
345
346         return (length($line), length($white));
347 }
348
349 my $sanitise_quote = '';
350
351 sub sanitise_line_reset {
352         my ($in_comment) = @_;
353
354         if ($in_comment) {
355                 $sanitise_quote = '*/';
356         } else {
357                 $sanitise_quote = '';
358         }
359 }
360 sub sanitise_line {
361         my ($line) = @_;
362
363         my $res = '';
364         my $l = '';
365
366         my $qlen = 0;
367         my $off = 0;
368         my $c;
369
370         # Always copy over the diff marker.
371         $res = substr($line, 0, 1);
372
373         for ($off = 1; $off < length($line); $off++) {
374                 $c = substr($line, $off, 1);
375
376                 # Comments we are wacking completly including the begin
377                 # and end, all to $;.
378                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '/*') {
379                         $sanitise_quote = '*/';
380
381                         substr($res, $off, 2, "$;$;");
382                         $off++;
383                         next;
384                 }
385                 if ($sanitise_quote eq '*/' && substr($line, $off, 2) eq '*/') {
386                         $sanitise_quote = '';
387                         substr($res, $off, 2, "$;$;");
388                         $off++;
389                         next;
390                 }
391                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '//') {
392                         $sanitise_quote = '//';
393
394                         substr($res, $off, 2, $sanitise_quote);
395                         $off++;
396                         next;
397                 }
398
399                 # A \ in a string means ignore the next character.
400                 if (($sanitise_quote eq "'" || $sanitise_quote eq '"') &&
401                     $c eq "\\") {
402                         substr($res, $off, 2, 'XX');
403                         $off++;
404                         next;
405                 }
406                 # Regular quotes.
407                 if ($c eq "'" || $c eq '"') {
408                         if ($sanitise_quote eq '') {
409                                 $sanitise_quote = $c;
410
411                                 substr($res, $off, 1, $c);
412                                 next;
413                         } elsif ($sanitise_quote eq $c) {
414                                 $sanitise_quote = '';
415                         }
416                 }
417
418                 #print "c<$c> SQ<$sanitise_quote>\n";
419                 if ($off != 0 && $sanitise_quote eq '*/' && $c ne "\t") {
420                         substr($res, $off, 1, $;);
421                 } elsif ($off != 0 && $sanitise_quote eq '//' && $c ne "\t") {
422                         substr($res, $off, 1, $;);
423                 } elsif ($off != 0 && $sanitise_quote && $c ne "\t") {
424                         substr($res, $off, 1, 'X');
425                 } else {
426                         substr($res, $off, 1, $c);
427                 }
428         }
429
430         if ($sanitise_quote eq '//') {
431                 $sanitise_quote = '';
432         }
433
434         # The pathname on a #include may be surrounded by '<' and '>'.
435         if ($res =~ /^.\s*\#\s*include\s+\<(.*)\>/) {
436                 my $clean = 'X' x length($1);
437                 $res =~ s@\<.*\>@<$clean>@;
438
439         # The whole of a #error is a string.
440         } elsif ($res =~ /^.\s*\#\s*(?:error|warning)\s+(.*)\b/) {
441                 my $clean = 'X' x length($1);
442                 $res =~ s@(\#\s*(?:error|warning)\s+).*@$1$clean@;
443         }
444
445         return $res;
446 }
447
448 sub ctx_statement_block {
449         my ($linenr, $remain, $off) = @_;
450         my $line = $linenr - 1;
451         my $blk = '';
452         my $soff = $off;
453         my $coff = $off - 1;
454         my $coff_set = 0;
455
456         my $loff = 0;
457
458         my $type = '';
459         my $level = 0;
460         my @stack = ();
461         my $p;
462         my $c;
463         my $len = 0;
464
465         my $remainder;
466         while (1) {
467                 @stack = (['', 0]) if ($#stack == -1);
468
469                 #warn "CSB: blk<$blk> remain<$remain>\n";
470                 # If we are about to drop off the end, pull in more
471                 # context.
472                 if ($off >= $len) {
473                         for (; $remain > 0; $line++) {
474                                 last if (!defined $lines[$line]);
475                                 next if ($lines[$line] =~ /^-/);
476                                 $remain--;
477                                 $loff = $len;
478                                 $blk .= $lines[$line] . "\n";
479                                 $len = length($blk);
480                                 $line++;
481                                 last;
482                         }
483                         # Bail if there is no further context.
484                         #warn "CSB: blk<$blk> off<$off> len<$len>\n";
485                         if ($off >= $len) {
486                                 last;
487                         }
488                 }
489                 $p = $c;
490                 $c = substr($blk, $off, 1);
491                 $remainder = substr($blk, $off);
492
493                 #warn "CSB: c<$c> type<$type> level<$level> remainder<$remainder> coff_set<$coff_set>\n";
494
495                 # Handle nested #if/#else.
496                 if ($remainder =~ /^#\s*(?:ifndef|ifdef|if)\s/) {
497                         push(@stack, [ $type, $level ]);
498                 } elsif ($remainder =~ /^#\s*(?:else|elif)\b/) {
499                         ($type, $level) = @{$stack[$#stack - 1]};
500                 } elsif ($remainder =~ /^#\s*endif\b/) {
501                         ($type, $level) = @{pop(@stack)};
502                 }
503
504                 # Statement ends at the ';' or a close '}' at the
505                 # outermost level.
506                 if ($level == 0 && $c eq ';') {
507                         last;
508                 }
509
510                 # An else is really a conditional as long as its not else if
511                 if ($level == 0 && $coff_set == 0 &&
512                                 (!defined($p) || $p =~ /(?:\s|\}|\+)/) &&
513                                 $remainder =~ /^(else)(?:\s|{)/ &&
514                                 $remainder !~ /^else\s+if\b/) {
515                         $coff = $off + length($1) - 1;
516                         $coff_set = 1;
517                         #warn "CSB: mark coff<$coff> soff<$soff> 1<$1>\n";
518                         #warn "[" . substr($blk, $soff, $coff - $soff + 1) . "]\n";
519                 }
520
521                 if (($type eq '' || $type eq '(') && $c eq '(') {
522                         $level++;
523                         $type = '(';
524                 }
525                 if ($type eq '(' && $c eq ')') {
526                         $level--;
527                         $type = ($level != 0)? '(' : '';
528
529                         if ($level == 0 && $coff < $soff) {
530                                 $coff = $off;
531                                 $coff_set = 1;
532                                 #warn "CSB: mark coff<$coff>\n";
533                         }
534                 }
535                 if (($type eq '' || $type eq '{') && $c eq '{') {
536                         $level++;
537                         $type = '{';
538                 }
539                 if ($type eq '{' && $c eq '}') {
540                         $level--;
541                         $type = ($level != 0)? '{' : '';
542
543                         if ($level == 0) {
544                                 last;
545                         }
546                 }
547                 $off++;
548         }
549         # We are truly at the end, so shuffle to the next line.
550         if ($off == $len) {
551                 $loff = $len + 1;
552                 $line++;
553                 $remain--;
554         }
555
556         my $statement = substr($blk, $soff, $off - $soff + 1);
557         my $condition = substr($blk, $soff, $coff - $soff + 1);
558
559         #warn "STATEMENT<$statement>\n";
560         #warn "CONDITION<$condition>\n";
561
562         #print "coff<$coff> soff<$off> loff<$loff>\n";
563
564         return ($statement, $condition,
565                         $line, $remain + 1, $off - $loff + 1, $level);
566 }
567
568 sub statement_lines {
569         my ($stmt) = @_;
570
571         # Strip the diff line prefixes and rip blank lines at start and end.
572         $stmt =~ s/(^|\n)./$1/g;
573         $stmt =~ s/^\s*//;
574         $stmt =~ s/\s*$//;
575
576         my @stmt_lines = ($stmt =~ /\n/g);
577
578         return $#stmt_lines + 2;
579 }
580
581 sub statement_rawlines {
582         my ($stmt) = @_;
583
584         my @stmt_lines = ($stmt =~ /\n/g);
585
586         return $#stmt_lines + 2;
587 }
588
589 sub statement_block_size {
590         my ($stmt) = @_;
591
592         $stmt =~ s/(^|\n)./$1/g;
593         $stmt =~ s/^\s*{//;
594         $stmt =~ s/}\s*$//;
595         $stmt =~ s/^\s*//;
596         $stmt =~ s/\s*$//;
597
598         my @stmt_lines = ($stmt =~ /\n/g);
599         my @stmt_statements = ($stmt =~ /;/g);
600
601         my $stmt_lines = $#stmt_lines + 2;
602         my $stmt_statements = $#stmt_statements + 1;
603
604         if ($stmt_lines > $stmt_statements) {
605                 return $stmt_lines;
606         } else {
607                 return $stmt_statements;
608         }
609 }
610
611 sub ctx_statement_full {
612         my ($linenr, $remain, $off) = @_;
613         my ($statement, $condition, $level);
614
615         my (@chunks);
616
617         # Grab the first conditional/block pair.
618         ($statement, $condition, $linenr, $remain, $off, $level) =
619                                 ctx_statement_block($linenr, $remain, $off);
620         #print "F: c<$condition> s<$statement> remain<$remain>\n";
621         push(@chunks, [ $condition, $statement ]);
622         if (!($remain > 0 && $condition =~ /^\s*(?:\n[+-])?\s*(?:if|else|do)\b/s)) {
623                 return ($level, $linenr, @chunks);
624         }
625
626         # Pull in the following conditional/block pairs and see if they
627         # could continue the statement.
628         for (;;) {
629                 ($statement, $condition, $linenr, $remain, $off, $level) =
630                                 ctx_statement_block($linenr, $remain, $off);
631                 #print "C: c<$condition> s<$statement> remain<$remain>\n";
632                 last if (!($remain > 0 && $condition =~ /^(?:\s*\n[+-])*\s*(?:else|do)\b/s));
633                 #print "C: push\n";
634                 push(@chunks, [ $condition, $statement ]);
635         }
636
637         return ($level, $linenr, @chunks);
638 }
639
640 sub ctx_block_get {
641         my ($linenr, $remain, $outer, $open, $close, $off) = @_;
642         my $line;
643         my $start = $linenr - 1;
644         my $blk = '';
645         my @o;
646         my @c;
647         my @res = ();
648
649         my $level = 0;
650         my @stack = ($level);
651         for ($line = $start; $remain > 0; $line++) {
652                 next if ($rawlines[$line] =~ /^-/);
653                 $remain--;
654
655                 $blk .= $rawlines[$line];
656
657                 # Handle nested #if/#else.
658                 if ($rawlines[$line] =~ /^.\s*#\s*(?:ifndef|ifdef|if)\s/) {
659                         push(@stack, $level);
660                 } elsif ($rawlines[$line] =~ /^.\s*#\s*(?:else|elif)\b/) {
661                         $level = $stack[$#stack - 1];
662                 } elsif ($rawlines[$line] =~ /^.\s*#\s*endif\b/) {
663                         $level = pop(@stack);
664                 }
665
666                 foreach my $c (split(//, $rawlines[$line])) {
667                         ##print "C<$c>L<$level><$open$close>O<$off>\n";
668                         if ($off > 0) {
669                                 $off--;
670                                 next;
671                         }
672
673                         if ($c eq $close && $level > 0) {
674                                 $level--;
675                                 last if ($level == 0);
676                         } elsif ($c eq $open) {
677                                 $level++;
678                         }
679                 }
680
681                 if (!$outer || $level <= 1) {
682                         push(@res, $rawlines[$line]);
683                 }
684
685                 last if ($level == 0);
686         }
687
688         return ($level, @res);
689 }
690 sub ctx_block_outer {
691         my ($linenr, $remain) = @_;
692
693         my ($level, @r) = ctx_block_get($linenr, $remain, 1, '{', '}', 0);
694         return @r;
695 }
696 sub ctx_block {
697         my ($linenr, $remain) = @_;
698
699         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '{', '}', 0);
700         return @r;
701 }
702 sub ctx_statement {
703         my ($linenr, $remain, $off) = @_;
704
705         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '(', ')', $off);
706         return @r;
707 }
708 sub ctx_block_level {
709         my ($linenr, $remain) = @_;
710
711         return ctx_block_get($linenr, $remain, 0, '{', '}', 0);
712 }
713 sub ctx_statement_level {
714         my ($linenr, $remain, $off) = @_;
715
716         return ctx_block_get($linenr, $remain, 0, '(', ')', $off);
717 }
718
719 sub ctx_locate_comment {
720         my ($first_line, $end_line) = @_;
721
722         # Catch a comment on the end of the line itself.
723         my ($current_comment) = ($rawlines[$end_line - 1] =~ m@.*(/\*.*\*/)\s*(?:\\\s*)?$@);
724         return $current_comment if (defined $current_comment);
725
726         # Look through the context and try and figure out if there is a
727         # comment.
728         my $in_comment = 0;
729         $current_comment = '';
730         for (my $linenr = $first_line; $linenr < $end_line; $linenr++) {
731                 my $line = $rawlines[$linenr - 1];
732                 #warn "           $line\n";
733                 if ($linenr == $first_line and $line =~ m@^.\s*\*@) {
734                         $in_comment = 1;
735                 }
736                 if ($line =~ m@/\*@) {
737                         $in_comment = 1;
738                 }
739                 if (!$in_comment && $current_comment ne '') {
740                         $current_comment = '';
741                 }
742                 $current_comment .= $line . "\n" if ($in_comment);
743                 if ($line =~ m@\*/@) {
744                         $in_comment = 0;
745                 }
746         }
747
748         chomp($current_comment);
749         return($current_comment);
750 }
751 sub ctx_has_comment {
752         my ($first_line, $end_line) = @_;
753         my $cmt = ctx_locate_comment($first_line, $end_line);
754
755         ##print "LINE: $rawlines[$end_line - 1 ]\n";
756         ##print "CMMT: $cmt\n";
757
758         return ($cmt ne '');
759 }
760
761 sub raw_line {
762         my ($linenr, $cnt) = @_;
763
764         my $offset = $linenr - 1;
765         $cnt++;
766
767         my $line;
768         while ($cnt) {
769                 $line = $rawlines[$offset++];
770                 next if (defined($line) && $line =~ /^-/);
771                 $cnt--;
772         }
773
774         return $line;
775 }
776
777 sub cat_vet {
778         my ($vet) = @_;
779         my ($res, $coded);
780
781         $res = '';
782         while ($vet =~ /([^[:cntrl:]]*)([[:cntrl:]]|$)/g) {
783                 $res .= $1;
784                 if ($2 ne '') {
785                         $coded = sprintf("^%c", unpack('C', $2) + 64);
786                         $res .= $coded;
787                 }
788         }
789         $res =~ s/$/\$/;
790
791         return $res;
792 }
793
794 my $av_preprocessor = 0;
795 my $av_pending;
796 my @av_paren_type;
797 my $av_pend_colon;
798
799 sub annotate_reset {
800         $av_preprocessor = 0;
801         $av_pending = '_';
802         @av_paren_type = ('E');
803         $av_pend_colon = 'O';
804 }
805
806 sub annotate_values {
807         my ($stream, $type) = @_;
808
809         my $res;
810         my $var = '_' x length($stream);
811         my $cur = $stream;
812
813         print "$stream\n" if ($dbg_values > 1);
814
815         while (length($cur)) {
816                 @av_paren_type = ('E') if ($#av_paren_type < 0);
817                 print " <" . join('', @av_paren_type) .
818                                 "> <$type> <$av_pending>" if ($dbg_values > 1);
819                 if ($cur =~ /^(\s+)/o) {
820                         print "WS($1)\n" if ($dbg_values > 1);
821                         if ($1 =~ /\n/ && $av_preprocessor) {
822                                 $type = pop(@av_paren_type);
823                                 $av_preprocessor = 0;
824                         }
825
826                 } elsif ($cur =~ /^($Type)\s*(?:$Ident|,|\)|\()/) {
827                         print "DECLARE($1)\n" if ($dbg_values > 1);
828                         $type = 'T';
829
830                 } elsif ($cur =~ /^($Modifier)\s*/) {
831                         print "MODIFIER($1)\n" if ($dbg_values > 1);
832                         $type = 'T';
833
834                 } elsif ($cur =~ /^(\#\s*define\s*$Ident)(\(?)/o) {
835                         print "DEFINE($1,$2)\n" if ($dbg_values > 1);
836                         $av_preprocessor = 1;
837                         push(@av_paren_type, $type);
838                         if ($2 ne '') {
839                                 $av_pending = 'N';
840                         }
841                         $type = 'E';
842
843                 } elsif ($cur =~ /^(\#\s*(?:undef\s*$Ident|include\b))/o) {
844                         print "UNDEF($1)\n" if ($dbg_values > 1);
845                         $av_preprocessor = 1;
846                         push(@av_paren_type, $type);
847
848                 } elsif ($cur =~ /^(\#\s*(?:ifdef|ifndef|if))/o) {
849                         print "PRE_START($1)\n" if ($dbg_values > 1);
850                         $av_preprocessor = 1;
851
852                         push(@av_paren_type, $type);
853                         push(@av_paren_type, $type);
854                         $type = 'E';
855
856                 } elsif ($cur =~ /^(\#\s*(?:else|elif))/o) {
857                         print "PRE_RESTART($1)\n" if ($dbg_values > 1);
858                         $av_preprocessor = 1;
859
860                         push(@av_paren_type, $av_paren_type[$#av_paren_type]);
861
862                         $type = 'E';
863
864                 } elsif ($cur =~ /^(\#\s*(?:endif))/o) {
865                         print "PRE_END($1)\n" if ($dbg_values > 1);
866
867                         $av_preprocessor = 1;
868
869                         # Assume all arms of the conditional end as this
870                         # one does, and continue as if the #endif was not here.
871                         pop(@av_paren_type);
872                         push(@av_paren_type, $type);
873                         $type = 'E';
874
875                 } elsif ($cur =~ /^(\\\n)/o) {
876                         print "PRECONT($1)\n" if ($dbg_values > 1);
877
878                 } elsif ($cur =~ /^(__attribute__)\s*\(?/o) {
879                         print "ATTR($1)\n" if ($dbg_values > 1);
880                         $av_pending = $type;
881                         $type = 'N';
882
883                 } elsif ($cur =~ /^(sizeof)\s*(\()?/o) {
884                         print "SIZEOF($1)\n" if ($dbg_values > 1);
885                         if (defined $2) {
886                                 $av_pending = 'V';
887                         }
888                         $type = 'N';
889
890                 } elsif ($cur =~ /^(if|while|for)\b/o) {
891                         print "COND($1)\n" if ($dbg_values > 1);
892                         $av_pending = 'E';
893                         $type = 'N';
894
895                 } elsif ($cur =~/^(case)/o) {
896                         print "CASE($1)\n" if ($dbg_values > 1);
897                         $av_pend_colon = 'C';
898                         $type = 'N';
899
900                 } elsif ($cur =~/^(return|else|goto|typeof|__typeof__)\b/o) {
901                         print "KEYWORD($1)\n" if ($dbg_values > 1);
902                         $type = 'N';
903
904                 } elsif ($cur =~ /^(\()/o) {
905                         print "PAREN('$1')\n" if ($dbg_values > 1);
906                         push(@av_paren_type, $av_pending);
907                         $av_pending = '_';
908                         $type = 'N';
909
910                 } elsif ($cur =~ /^(\))/o) {
911                         my $new_type = pop(@av_paren_type);
912                         if ($new_type ne '_') {
913                                 $type = $new_type;
914                                 print "PAREN('$1') -> $type\n"
915                                                         if ($dbg_values > 1);
916                         } else {
917                                 print "PAREN('$1')\n" if ($dbg_values > 1);
918                         }
919
920                 } elsif ($cur =~ /^($Ident)\s*\(/o) {
921                         print "FUNC($1)\n" if ($dbg_values > 1);
922                         $type = 'V';
923                         $av_pending = 'V';
924
925                 } elsif ($cur =~ /^($Ident\s*):(?:\s*\d+\s*(,|=|;))?/) {
926                         if (defined $2 && $type eq 'C' || $type eq 'T') {
927                                 $av_pend_colon = 'B';
928                         } elsif ($type eq 'E') {
929                                 $av_pend_colon = 'L';
930                         }
931                         print "IDENT_COLON($1,$type>$av_pend_colon)\n" if ($dbg_values > 1);
932                         $type = 'V';
933
934                 } elsif ($cur =~ /^($Ident|$Constant)/o) {
935                         print "IDENT($1)\n" if ($dbg_values > 1);
936                         $type = 'V';
937
938                 } elsif ($cur =~ /^($Assignment)/o) {
939                         print "ASSIGN($1)\n" if ($dbg_values > 1);
940                         $type = 'N';
941
942                 } elsif ($cur =~/^(;|{|})/) {
943                         print "END($1)\n" if ($dbg_values > 1);
944                         $type = 'E';
945                         $av_pend_colon = 'O';
946
947                 } elsif ($cur =~/^(,)/) {
948                         print "COMMA($1)\n" if ($dbg_values > 1);
949                         $type = 'C';
950
951                 } elsif ($cur =~ /^(\?)/o) {
952                         print "QUESTION($1)\n" if ($dbg_values > 1);
953                         $type = 'N';
954
955                 } elsif ($cur =~ /^(:)/o) {
956                         print "COLON($1,$av_pend_colon)\n" if ($dbg_values > 1);
957
958                         substr($var, length($res), 1, $av_pend_colon);
959                         if ($av_pend_colon eq 'C' || $av_pend_colon eq 'L') {
960                                 $type = 'E';
961                         } else {
962                                 $type = 'N';
963                         }
964                         $av_pend_colon = 'O';
965
966                 } elsif ($cur =~ /^(\[)/o) {
967                         print "CLOSE($1)\n" if ($dbg_values > 1);
968                         $type = 'N';
969
970                 } elsif ($cur =~ /^(-(?![->])|\+(?!\+)|\*|\&\&|\&)/o) {
971                         my $variant;
972
973                         print "OPV($1)\n" if ($dbg_values > 1);
974                         if ($type eq 'V') {
975                                 $variant = 'B';
976                         } else {
977                                 $variant = 'U';
978                         }
979
980                         substr($var, length($res), 1, $variant);
981                         $type = 'N';
982
983                 } elsif ($cur =~ /^($Operators)/o) {
984                         print "OP($1)\n" if ($dbg_values > 1);
985                         if ($1 ne '++' && $1 ne '--') {
986                                 $type = 'N';
987                         }
988
989                 } elsif ($cur =~ /(^.)/o) {
990                         print "C($1)\n" if ($dbg_values > 1);
991                 }
992                 if (defined $1) {
993                         $cur = substr($cur, length($1));
994                         $res .= $type x length($1);
995                 }
996         }
997
998         return ($res, $var);
999 }
1000
1001 sub possible {
1002         my ($possible, $line) = @_;
1003         my $notPermitted = qr{(?:
1004                 ^(?:
1005                         $Modifier|
1006                         $Storage|
1007                         $Type|
1008                         DEFINE_\S+
1009                 )$|
1010                 ^(?:
1011                         goto|
1012                         return|
1013                         case|
1014                         else|
1015                         asm|__asm__|
1016                         do
1017                 )(?:\s|$)|
1018                 ^(?:typedef|struct|enum)\b
1019             )}x;
1020         warn "CHECK<$possible> ($line)\n" if ($dbg_possible > 2);
1021         if ($possible !~ $notPermitted) {
1022                 # Check for modifiers.
1023                 $possible =~ s/\s*$Storage\s*//g;
1024                 $possible =~ s/\s*$Sparse\s*//g;
1025                 if ($possible =~ /^\s*$/) {
1026
1027                 } elsif ($possible =~ /\s/) {
1028                         $possible =~ s/\s*$Type\s*//g;
1029                         for my $modifier (split(' ', $possible)) {
1030                                 if ($modifier !~ $notPermitted) {
1031                                         warn "MODIFIER: $modifier ($possible) ($line)\n" if ($dbg_possible);
1032                                         push(@modifierList, $modifier);
1033                                 }
1034                         }
1035
1036                 } else {
1037                         warn "POSSIBLE: $possible ($line)\n" if ($dbg_possible);
1038                         push(@typeList, $possible);
1039                 }
1040                 build_types();
1041         } else {
1042                 warn "NOTPOSS: $possible ($line)\n" if ($dbg_possible > 1);
1043         }
1044 }
1045
1046 my $prefix = '';
1047
1048 sub report {
1049         if (defined $tst_only && $_[0] !~ /\Q$tst_only\E/) {
1050                 return 0;
1051         }
1052         my $line = $prefix . $_[0];
1053
1054         $line = (split('\n', $line))[0] . "\n" if ($terse);
1055
1056         push(our @report, $line);
1057
1058         return 1;
1059 }
1060 sub report_dump {
1061         our @report;
1062 }
1063 sub ERROR {
1064         if (report("ERROR: $_[0]\n")) {
1065                 our $clean = 0;
1066                 our $cnt_error++;
1067         }
1068 }
1069 sub WARN {
1070         if (report("WARNING: $_[0]\n")) {
1071                 our $clean = 0;
1072                 our $cnt_warn++;
1073         }
1074 }
1075 sub CHK {
1076         if ($check && report("CHECK: $_[0]\n")) {
1077                 our $clean = 0;
1078                 our $cnt_chk++;
1079         }
1080 }
1081
1082 sub check_absolute_file {
1083         my ($absolute, $herecurr) = @_;
1084         my $file = $absolute;
1085
1086         ##print "absolute<$absolute>\n";
1087
1088         # See if any suffix of this path is a path within the tree.
1089         while ($file =~ s@^[^/]*/@@) {
1090                 if (-f "$root/$file") {
1091                         ##print "file<$file>\n";
1092                         last;
1093                 }
1094         }
1095         if (! -f _)  {
1096                 return 0;
1097         }
1098
1099         # It is, so see if the prefix is acceptable.
1100         my $prefix = $absolute;
1101         substr($prefix, -length($file)) = '';
1102
1103         ##print "prefix<$prefix>\n";
1104         if ($prefix ne ".../") {
1105                 WARN("use relative pathname instead of absolute in changelog text\n" . $herecurr);
1106         }
1107 }
1108
1109 sub process {
1110         my $filename = shift;
1111
1112         my $linenr=0;
1113         my $prevline="";
1114         my $prevrawline="";
1115         my $stashline="";
1116         my $stashrawline="";
1117
1118         my $length;
1119         my $indent;
1120         my $previndent=0;
1121         my $stashindent=0;
1122
1123         our $clean = 1;
1124         my $signoff = 0;
1125         my $is_patch = 0;
1126
1127         our @report = ();
1128         our $cnt_lines = 0;
1129         our $cnt_error = 0;
1130         our $cnt_warn = 0;
1131         our $cnt_chk = 0;
1132
1133         # Trace the real file/line as we go.
1134         my $realfile = '';
1135         my $realline = 0;
1136         my $realcnt = 0;
1137         my $here = '';
1138         my $in_comment = 0;
1139         my $comment_edge = 0;
1140         my $first_line = 0;
1141         my $p1_prefix = '';
1142
1143         my $prev_values = 'E';
1144
1145         # suppression flags
1146         my %suppress_ifbraces;
1147         my %suppress_whiletrailers;
1148
1149         # Pre-scan the patch sanitizing the lines.
1150         # Pre-scan the patch looking for any __setup documentation.
1151         #
1152         my @setup_docs = ();
1153         my $setup_docs = 0;
1154
1155         sanitise_line_reset();
1156         my $line;
1157         foreach my $rawline (@rawlines) {
1158                 $linenr++;
1159                 $line = $rawline;
1160
1161                 if ($rawline=~/^\+\+\+\s+(\S+)/) {
1162                         $setup_docs = 0;
1163                         if ($1 =~ m@Documentation/kernel-parameters.txt$@) {
1164                                 $setup_docs = 1;
1165                         }
1166                         #next;
1167                 }
1168                 if ($rawline=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1169                         $realline=$1-1;
1170                         if (defined $2) {
1171                                 $realcnt=$3+1;
1172                         } else {
1173                                 $realcnt=1+1;
1174                         }
1175                         $in_comment = 0;
1176
1177                         # Guestimate if this is a continuing comment.  Run
1178                         # the context looking for a comment "edge".  If this
1179                         # edge is a close comment then we must be in a comment
1180                         # at context start.
1181                         my $edge;
1182                         my $cnt = $realcnt;
1183                         for (my $ln = $linenr + 1; $cnt > 0; $ln++) {
1184                                 next if (defined $rawlines[$ln - 1] &&
1185                                          $rawlines[$ln - 1] =~ /^-/);
1186                                 $cnt--;
1187                                 #print "RAW<$rawlines[$ln - 1]>\n";
1188                                 last if (!defined $rawlines[$ln - 1]);
1189                                 if ($rawlines[$ln - 1] =~ m@(/\*|\*/)@ &&
1190                                     $rawlines[$ln - 1] !~ m@"[^"]*(?:/\*|\*/)[^"]*"@) {
1191                                         ($edge) = $1;
1192                                         last;
1193                                 }
1194                         }
1195                         if (defined $edge && $edge eq '*/') {
1196                                 $in_comment = 1;
1197                         }
1198
1199                         # Guestimate if this is a continuing comment.  If this
1200                         # is the start of a diff block and this line starts
1201                         # ' *' then it is very likely a comment.
1202                         if (!defined $edge &&
1203                             $rawlines[$linenr] =~ m@^.\s*(?:\*\*+| \*)(?:\s|$)@)
1204                         {
1205                                 $in_comment = 1;
1206                         }
1207
1208                         ##print "COMMENT:$in_comment edge<$edge> $rawline\n";
1209                         sanitise_line_reset($in_comment);
1210
1211                 } elsif ($realcnt && $rawline =~ /^(?:\+| |$)/) {
1212                         # Standardise the strings and chars within the input to
1213                         # simplify matching -- only bother with positive lines.
1214                         $line = sanitise_line($rawline);
1215                 }
1216                 push(@lines, $line);
1217
1218                 if ($realcnt > 1) {
1219                         $realcnt-- if ($line =~ /^(?:\+| |$)/);
1220                 } else {
1221                         $realcnt = 0;
1222                 }
1223
1224                 #print "==>$rawline\n";
1225                 #print "-->$line\n";
1226
1227                 if ($setup_docs && $line =~ /^\+/) {
1228                         push(@setup_docs, $line);
1229                 }
1230         }
1231
1232         $prefix = '';
1233
1234         $realcnt = 0;
1235         $linenr = 0;
1236         foreach my $line (@lines) {
1237                 $linenr++;
1238
1239                 my $rawline = $rawlines[$linenr - 1];
1240
1241 #extract the line range in the file after the patch is applied
1242                 if ($line=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1243                         $is_patch = 1;
1244                         $first_line = $linenr + 1;
1245                         $realline=$1-1;
1246                         if (defined $2) {
1247                                 $realcnt=$3+1;
1248                         } else {
1249                                 $realcnt=1+1;
1250                         }
1251                         annotate_reset();
1252                         $prev_values = 'E';
1253
1254                         %suppress_ifbraces = ();
1255                         %suppress_whiletrailers = ();
1256                         next;
1257
1258 # track the line number as we move through the hunk, note that
1259 # new versions of GNU diff omit the leading space on completely
1260 # blank context lines so we need to count that too.
1261                 } elsif ($line =~ /^( |\+|$)/) {
1262                         $realline++;
1263                         $realcnt-- if ($realcnt != 0);
1264
1265                         # Measure the line length and indent.
1266                         ($length, $indent) = line_stats($rawline);
1267
1268                         # Track the previous line.
1269                         ($prevline, $stashline) = ($stashline, $line);
1270                         ($previndent, $stashindent) = ($stashindent, $indent);
1271                         ($prevrawline, $stashrawline) = ($stashrawline, $rawline);
1272
1273                         #warn "line<$line>\n";
1274
1275                 } elsif ($realcnt == 1) {
1276                         $realcnt--;
1277                 }
1278
1279                 my $hunk_line = ($realcnt != 0);
1280
1281 #make up the handle for any error we report on this line
1282                 $prefix = "$filename:$realline: " if ($emacs && $file);
1283                 $prefix = "$filename:$linenr: " if ($emacs && !$file);
1284
1285                 $here = "#$linenr: " if (!$file);
1286                 $here = "#$realline: " if ($file);
1287
1288                 # extract the filename as it passes
1289                 if ($line=~/^\+\+\+\s+(\S+)/) {
1290                         $realfile = $1;
1291                         $realfile =~ s@^([^/]*)/@@;
1292
1293                         $p1_prefix = $1;
1294                         if (!$file && $tree && $p1_prefix ne '' &&
1295                             -e "$root/$p1_prefix") {
1296                                 WARN("patch prefix '$p1_prefix' exists, appears to be a -p0 patch\n");
1297                         }
1298
1299                         if ($realfile =~ m@^include/asm/@) {
1300                                 ERROR("do not modify files in include/asm, change architecture specific files in include/asm-<architecture>\n" . "$here$rawline\n");
1301                         }
1302                         next;
1303                 }
1304
1305                 $here .= "FILE: $realfile:$realline:" if ($realcnt != 0);
1306
1307                 my $hereline = "$here\n$rawline\n";
1308                 my $herecurr = "$here\n$rawline\n";
1309                 my $hereprev = "$here\n$prevrawline\n$rawline\n";
1310
1311                 $cnt_lines++ if ($realcnt != 0);
1312
1313 #check the patch for a signoff:
1314                 if ($line =~ /^\s*signed-off-by:/i) {
1315                         # This is a signoff, if ugly, so do not double report.
1316                         $signoff++;
1317                         if (!($line =~ /^\s*Signed-off-by:/)) {
1318                                 WARN("Signed-off-by: is the preferred form\n" .
1319                                         $herecurr);
1320                         }
1321                         if ($line =~ /^\s*signed-off-by:\S/i) {
1322                                 WARN("space required after Signed-off-by:\n" .
1323                                         $herecurr);
1324                         }
1325                 }
1326
1327 # Check for wrappage within a valid hunk of the file
1328                 if ($realcnt != 0 && $line !~ m{^(?:\+|-| |\\ No newline|$)}) {
1329                         ERROR("patch seems to be corrupt (line wrapped?)\n" .
1330                                 $herecurr) if (!$emitted_corrupt++);
1331                 }
1332
1333 # Check for absolute kernel paths.
1334                 if ($tree) {
1335                         while ($line =~ m{(?:^|\s)(/\S*)}g) {
1336                                 my $file = $1;
1337
1338                                 if ($file =~ m{^(.*?)(?::\d+)+:?$} &&
1339                                     check_absolute_file($1, $herecurr)) {
1340                                         #
1341                                 } else {
1342                                         check_absolute_file($file, $herecurr);
1343                                 }
1344                         }
1345                 }
1346
1347 # UTF-8 regex found at http://www.w3.org/International/questions/qa-forms-utf-8.en.php
1348                 if (($realfile =~ /^$/ || $line =~ /^\+/) &&
1349                     $rawline !~ m/^$UTF8*$/) {
1350                         my ($utf8_prefix) = ($rawline =~ /^($UTF8*)/);
1351
1352                         my $blank = copy_spacing($rawline);
1353                         my $ptr = substr($blank, 0, length($utf8_prefix)) . "^";
1354                         my $hereptr = "$hereline$ptr\n";
1355
1356                         ERROR("Invalid UTF-8, patch and commit message should be encoded in UTF-8\n" . $hereptr);
1357                 }
1358
1359 # ignore non-hunk lines and lines being removed
1360                 next if (!$hunk_line || $line =~ /^-/);
1361
1362 #trailing whitespace
1363                 if ($line =~ /^\+.*\015/) {
1364                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1365                         ERROR("DOS line endings\n" . $herevet);
1366
1367                 } elsif ($rawline =~ /^\+.*\S\s+$/ || $rawline =~ /^\+\s+$/) {
1368                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1369                         ERROR("trailing whitespace\n" . $herevet);
1370                 }
1371
1372 # check we are in a valid source file if not then ignore this hunk
1373                 next if ($realfile !~ /\.(h|c|s|S|pl|sh)$/);
1374
1375 #80 column limit
1376                 if ($line =~ /^\+/ && $prevrawline !~ /\/\*\*/ &&
1377                     $rawline !~ /^.\s*\*\s*\@$Ident\s/ &&
1378                     $line !~ /^\+\s*printk\s*\(\s*(?:KERN_\S+\s*)?"[X\t]*"\s*(?:,|\)\s*;)\s*$/ &&
1379                     $length > 80)
1380                 {
1381                         WARN("line over 80 characters\n" . $herecurr);
1382                 }
1383
1384 # check for adding lines without a newline.
1385                 if ($line =~ /^\+/ && defined $lines[$linenr] && $lines[$linenr] =~ /^\\ No newline at end of file/) {
1386                         WARN("adding a line without newline at end of file\n" . $herecurr);
1387                 }
1388
1389 # Blackfin: use hi/lo macros
1390                 if ($realfile =~ m@arch/blackfin/.*\.S$@) {
1391                         if ($line =~ /\.[lL][[:space:]]*=.*&[[:space:]]*0x[fF][fF][fF][fF]/) {
1392                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1393                                 ERROR("use the LO() macro, not (... & 0xFFFF)\n" . $herevet);
1394                         }
1395                         if ($line =~ /\.[hH][[:space:]]*=.*>>[[:space:]]*16/) {
1396                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1397                                 ERROR("use the HI() macro, not (... >> 16)\n" . $herevet);
1398                         }
1399                 }
1400
1401 # check we are in a valid source file C or perl if not then ignore this hunk
1402                 next if ($realfile !~ /\.(h|c|pl)$/);
1403
1404 # at the beginning of a line any tabs must come first and anything
1405 # more than 8 must use tabs.
1406                 if ($rawline =~ /^\+\s* \t\s*\S/ ||
1407                     $rawline =~ /^\+\s*        \s*/) {
1408                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1409                         ERROR("code indent should use tabs where possible\n" . $herevet);
1410                 }
1411
1412 # check we are in a valid C source file if not then ignore this hunk
1413                 next if ($realfile !~ /\.(h|c)$/);
1414
1415 # check for RCS/CVS revision markers
1416                 if ($rawline =~ /^\+.*\$(Revision|Log|Id)(?:\$|)/) {
1417                         WARN("CVS style keyword markers, these will _not_ be updated\n". $herecurr);
1418                 }
1419
1420 # Blackfin: don't use __builtin_bfin_[cs]sync
1421                 if ($line =~ /__builtin_bfin_csync/) {
1422                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1423                         ERROR("use the CSYNC() macro in asm/blackfin.h\n" . $herevet);
1424                 }
1425                 if ($line =~ /__builtin_bfin_ssync/) {
1426                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1427                         ERROR("use the SSYNC() macro in asm/blackfin.h\n" . $herevet);
1428                 }
1429
1430 # Check for potential 'bare' types
1431                 my ($stat, $cond, $line_nr_next, $remain_next, $off_next);
1432                 if ($realcnt && $line =~ /.\s*\S/) {
1433                         ($stat, $cond, $line_nr_next, $remain_next, $off_next) =
1434                                 ctx_statement_block($linenr, $realcnt, 0);
1435                         $stat =~ s/\n./\n /g;
1436                         $cond =~ s/\n./\n /g;
1437
1438                         my $s = $stat;
1439                         $s =~ s/{.*$//s;
1440
1441                         # Ignore goto labels.
1442                         if ($s =~ /$Ident:\*$/s) {
1443
1444                         # Ignore functions being called
1445                         } elsif ($s =~ /^.\s*$Ident\s*\(/s) {
1446
1447                         } elsif ($s =~ /^.\s*else\b/s) {
1448
1449                         # declarations always start with types
1450                         } elsif ($prev_values eq 'E' && $s =~ /^.\s*(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?((?:\s*$Ident)+?)\b(?:\s+$Sparse)?\s*\**\s*(?:$Ident|\(\*[^\)]*\))(?:\s*$Modifier)?\s*(?:;|=|,|\()/s) {
1451                                 my $type = $1;
1452                                 $type =~ s/\s+/ /g;
1453                                 possible($type, "A:" . $s);
1454
1455                         # definitions in global scope can only start with types
1456                         } elsif ($s =~ /^.(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?($Ident)\b\s*(?!:)/s) {
1457                                 possible($1, "B:" . $s);
1458                         }
1459
1460                         # any (foo ... *) is a pointer cast, and foo is a type
1461                         while ($s =~ /\(($Ident)(?:\s+$Sparse)*[\s\*]+\s*\)/sg) {
1462                                 possible($1, "C:" . $s);
1463                         }
1464
1465                         # Check for any sort of function declaration.
1466                         # int foo(something bar, other baz);
1467                         # void (*store_gdt)(x86_descr_ptr *);
1468                         if ($prev_values eq 'E' && $s =~ /^(.(?:typedef\s*)?(?:(?:$Storage|$Inline)\s*)*\s*$Type\s*(?:\b$Ident|\(\*\s*$Ident\))\s*)\(/s) {
1469                                 my ($name_len) = length($1);
1470
1471                                 my $ctx = $s;
1472                                 substr($ctx, 0, $name_len + 1, '');
1473                                 $ctx =~ s/\)[^\)]*$//;
1474
1475                                 for my $arg (split(/\s*,\s*/, $ctx)) {
1476                                         if ($arg =~ /^(?:const\s+)?($Ident)(?:\s+$Sparse)*\s*\**\s*(:?\b$Ident)?$/s || $arg =~ /^($Ident)$/s) {
1477
1478                                                 possible($1, "D:" . $s);
1479                                         }
1480                                 }
1481                         }
1482
1483                 }
1484
1485 #
1486 # Checks which may be anchored in the context.
1487 #
1488
1489 # Check for switch () and associated case and default
1490 # statements should be at the same indent.
1491                 if ($line=~/\bswitch\s*\(.*\)/) {
1492                         my $err = '';
1493                         my $sep = '';
1494                         my @ctx = ctx_block_outer($linenr, $realcnt);
1495                         shift(@ctx);
1496                         for my $ctx (@ctx) {
1497                                 my ($clen, $cindent) = line_stats($ctx);
1498                                 if ($ctx =~ /^\+\s*(case\s+|default:)/ &&
1499                                                         $indent != $cindent) {
1500                                         $err .= "$sep$ctx\n";
1501                                         $sep = '';
1502                                 } else {
1503                                         $sep = "[...]\n";
1504                                 }
1505                         }
1506                         if ($err ne '') {
1507                                 ERROR("switch and case should be at the same indent\n$hereline$err");
1508                         }
1509                 }
1510
1511 # if/while/etc brace do not go on next line, unless defining a do while loop,
1512 # or if that brace on the next line is for something else
1513                 if ($line =~ /(.*)\b((?:if|while|for|switch)\s*\(|do\b|else\b)/ && $line !~ /^.\s*\#/) {
1514                         my $pre_ctx = "$1$2";
1515
1516                         my ($level, @ctx) = ctx_statement_level($linenr, $realcnt, 0);
1517                         my $ctx_cnt = $realcnt - $#ctx - 1;
1518                         my $ctx = join("\n", @ctx);
1519
1520                         my $ctx_ln = $linenr;
1521                         my $ctx_skip = $realcnt;
1522
1523                         while ($ctx_skip > $ctx_cnt || ($ctx_skip == $ctx_cnt &&
1524                                         defined $lines[$ctx_ln - 1] &&
1525                                         $lines[$ctx_ln - 1] =~ /^-/)) {
1526                                 ##print "SKIP<$ctx_skip> CNT<$ctx_cnt>\n";
1527                                 $ctx_skip-- if (!defined $lines[$ctx_ln - 1] || $lines[$ctx_ln - 1] !~ /^-/);
1528                                 $ctx_ln++;
1529                         }
1530
1531                         #print "realcnt<$realcnt> ctx_cnt<$ctx_cnt>\n";
1532                         #print "pre<$pre_ctx>\nline<$line>\nctx<$ctx>\nnext<$lines[$ctx_ln - 1]>\n";
1533
1534                         if ($ctx !~ /{\s*/ && defined($lines[$ctx_ln -1]) && $lines[$ctx_ln - 1] =~ /^\+\s*{/) {
1535                                 ERROR("that open brace { should be on the previous line\n" .
1536                                         "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1537                         }
1538                         if ($level == 0 && $pre_ctx !~ /}\s*while\s*\($/ &&
1539                             $ctx =~ /\)\s*\;\s*$/ &&
1540                             defined $lines[$ctx_ln - 1])
1541                         {
1542                                 my ($nlength, $nindent) = line_stats($lines[$ctx_ln - 1]);
1543                                 if ($nindent > $indent) {
1544                                         WARN("trailing semicolon indicates no statements, indent implies otherwise\n" .
1545                                                 "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1546                                 }
1547                         }
1548                 }
1549
1550 # Check relative indent for conditionals and blocks.
1551                 if ($line =~ /\b(?:(?:if|while|for)\s*\(|do\b)/ && $line !~ /^.\s*#/ && $line !~ /\}\s*while\s*/) {
1552                         my ($s, $c) = ($stat, $cond);
1553
1554                         substr($s, 0, length($c), '');
1555
1556                         # Make sure we remove the line prefixes as we have
1557                         # none on the first line, and are going to readd them
1558                         # where necessary.
1559                         $s =~ s/\n./\n/gs;
1560
1561                         # Find out how long the conditional actually is.
1562                         my @newlines = ($c =~ /\n/gs);
1563                         my $cond_lines = 1 + $#newlines;
1564
1565                         # We want to check the first line inside the block
1566                         # starting at the end of the conditional, so remove:
1567                         #  1) any blank line termination
1568                         #  2) any opening brace { on end of the line
1569                         #  3) any do (...) {
1570                         my $continuation = 0;
1571                         my $check = 0;
1572                         $s =~ s/^.*\bdo\b//;
1573                         $s =~ s/^\s*{//;
1574                         if ($s =~ s/^\s*\\//) {
1575                                 $continuation = 1;
1576                         }
1577                         if ($s =~ s/^\s*?\n//) {
1578                                 $check = 1;
1579                                 $cond_lines++;
1580                         }
1581
1582                         # Also ignore a loop construct at the end of a
1583                         # preprocessor statement.
1584                         if (($prevline =~ /^.\s*#\s*define\s/ ||
1585                             $prevline =~ /\\\s*$/) && $continuation == 0) {
1586                                 $check = 0;
1587                         }
1588
1589                         my $cond_ptr = -1;
1590                         $continuation = 0;
1591                         while ($cond_ptr != $cond_lines) {
1592                                 $cond_ptr = $cond_lines;
1593
1594                                 # If we see an #else/#elif then the code
1595                                 # is not linear.
1596                                 if ($s =~ /^\s*\#\s*(?:else|elif)/) {
1597                                         $check = 0;
1598                                 }
1599
1600                                 # Ignore:
1601                                 #  1) blank lines, they should be at 0,
1602                                 #  2) preprocessor lines, and
1603                                 #  3) labels.
1604                                 if ($continuation ||
1605                                     $s =~ /^\s*?\n/ ||
1606                                     $s =~ /^\s*#\s*?/ ||
1607                                     $s =~ /^\s*$Ident\s*:/) {
1608                                         $continuation = ($s =~ /^.*?\\\n/) ? 1 : 0;
1609                                         if ($s =~ s/^.*?\n//) {
1610                                                 $cond_lines++;
1611                                         }
1612                                 }
1613                         }
1614
1615                         my (undef, $sindent) = line_stats("+" . $s);
1616                         my $stat_real = raw_line($linenr, $cond_lines);
1617
1618                         # Check if either of these lines are modified, else
1619                         # this is not this patch's fault.
1620                         if (!defined($stat_real) ||
1621                             $stat !~ /^\+/ && $stat_real !~ /^\+/) {
1622                                 $check = 0;
1623                         }
1624                         if (defined($stat_real) && $cond_lines > 1) {
1625                                 $stat_real = "[...]\n$stat_real";
1626                         }
1627
1628                         #print "line<$line> prevline<$prevline> indent<$indent> sindent<$sindent> check<$check> continuation<$continuation> s<$s> cond_lines<$cond_lines> stat_real<$stat_real> stat<$stat>\n";
1629
1630                         if ($check && (($sindent % 8) != 0 ||
1631                             ($sindent <= $indent && $s ne ''))) {
1632                                 WARN("suspect code indent for conditional statements ($indent, $sindent)\n" . $herecurr . "$stat_real\n");
1633                         }
1634                 }
1635
1636                 # Track the 'values' across context and added lines.
1637                 my $opline = $line; $opline =~ s/^./ /;
1638                 my ($curr_values, $curr_vars) =
1639                                 annotate_values($opline . "\n", $prev_values);
1640                 $curr_values = $prev_values . $curr_values;
1641                 if ($dbg_values) {
1642                         my $outline = $opline; $outline =~ s/\t/ /g;
1643                         print "$linenr > .$outline\n";
1644                         print "$linenr > $curr_values\n";
1645                         print "$linenr >  $curr_vars\n";
1646                 }
1647                 $prev_values = substr($curr_values, -1);
1648
1649 #ignore lines not being added
1650                 if ($line=~/^[^\+]/) {next;}
1651
1652 # TEST: allow direct testing of the type matcher.
1653                 if ($dbg_type) {
1654                         if ($line =~ /^.\s*$Declare\s*$/) {
1655                                 ERROR("TEST: is type\n" . $herecurr);
1656                         } elsif ($dbg_type > 1 && $line =~ /^.+($Declare)/) {
1657                                 ERROR("TEST: is not type ($1 is)\n". $herecurr);
1658                         }
1659                         next;
1660                 }
1661 # TEST: allow direct testing of the attribute matcher.
1662                 if ($dbg_attr) {
1663                         if ($line =~ /^.\s*$Modifier\s*$/) {
1664                                 ERROR("TEST: is attr\n" . $herecurr);
1665                         } elsif ($dbg_attr > 1 && $line =~ /^.+($Modifier)/) {
1666                                 ERROR("TEST: is not attr ($1 is)\n". $herecurr);
1667                         }
1668                         next;
1669                 }
1670
1671 # check for initialisation to aggregates open brace on the next line
1672                 if ($prevline =~ /$Declare\s*$Ident\s*=\s*$/ &&
1673                     $line =~ /^.\s*{/) {
1674                         ERROR("that open brace { should be on the previous line\n" . $hereprev);
1675                 }
1676
1677 #
1678 # Checks which are anchored on the added line.
1679 #
1680
1681 # check for malformed paths in #include statements (uses RAW line)
1682                 if ($rawline =~ m{^.\s*\#\s*include\s+[<"](.*)[">]}) {
1683                         my $path = $1;
1684                         if ($path =~ m{//}) {
1685                                 ERROR("malformed #include filename\n" .
1686                                         $herecurr);
1687                         }
1688                 }
1689
1690 # no C99 // comments
1691                 if ($line =~ m{//}) {
1692                         ERROR("do not use C99 // comments\n" . $herecurr);
1693                 }
1694                 # Remove C99 comments.
1695                 $line =~ s@//.*@@;
1696                 $opline =~ s@//.*@@;
1697
1698 #EXPORT_SYMBOL should immediately follow its function closing }.
1699                 if (($line =~ /EXPORT_SYMBOL.*\((.*)\)/) ||
1700                     ($line =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
1701                         my $name = $1;
1702                         if ($prevline !~ /(?:
1703                                 ^.}|
1704                                 ^.DEFINE_$Ident\(\Q$name\E\)|
1705                                 ^.DECLARE_$Ident\(\Q$name\E\)|
1706                                 ^.LIST_HEAD\(\Q$name\E\)|
1707                                 ^.$Type\s*\(\s*\*\s*\Q$name\E\s*\)\s*\(|
1708                                 \b\Q$name\E(?:\s+$Attribute)?\s*(?:;|=|\[)
1709                             )/x) {
1710                                 WARN("EXPORT_SYMBOL(foo); should immediately follow its function/variable\n" . $herecurr);
1711                         }
1712                 }
1713
1714 # check for external initialisers.
1715                 if ($line =~ /^.$Type\s*$Ident\s*(?:\s+$Modifier)*\s*=\s*(0|NULL|false)\s*;/) {
1716                         ERROR("do not initialise externals to 0 or NULL\n" .
1717                                 $herecurr);
1718                 }
1719 # check for static initialisers.
1720                 if ($line =~ /\bstatic\s.*=\s*(0|NULL|false)\s*;/) {
1721                         ERROR("do not initialise statics to 0 or NULL\n" .
1722                                 $herecurr);
1723                 }
1724
1725 # check for new typedefs, only function parameters and sparse annotations
1726 # make sense.
1727                 if ($line =~ /\btypedef\s/ &&
1728                     $line !~ /\btypedef\s+$Type\s*\(\s*\*?$Ident\s*\)\s*\(/ &&
1729                     $line !~ /\btypedef\s+$Type\s+$Ident\s*\(/ &&
1730                     $line !~ /\b$typeTypedefs\b/ &&
1731                     $line !~ /\b__bitwise(?:__|)\b/) {
1732                         WARN("do not add new typedefs\n" . $herecurr);
1733                 }
1734
1735 # * goes on variable not on type
1736                 # (char*[ const])
1737                 if ($line =~ m{\($NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)\)}) {
1738                         my ($from, $to) = ($1, $1);
1739
1740                         # Should start with a space.
1741                         $to =~ s/^(\S)/ $1/;
1742                         # Should not end with a space.
1743                         $to =~ s/\s+$//;
1744                         # '*'s should not have spaces between.
1745                         while ($to =~ s/\*\s+\*/\*\*/) {
1746                         }
1747
1748                         #print "from<$from> to<$to>\n";
1749                         if ($from ne $to) {
1750                                 ERROR("\"(foo$from)\" should be \"(foo$to)\"\n" .  $herecurr);
1751                         }
1752                 } elsif ($line =~ m{\b$NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)($Ident)}) {
1753                         my ($from, $to, $ident) = ($1, $1, $2);
1754
1755                         # Should start with a space.
1756                         $to =~ s/^(\S)/ $1/;
1757                         # Should not end with a space.
1758                         $to =~ s/\s+$//;
1759                         # '*'s should not have spaces between.
1760                         while ($to =~ s/\*\s+\*/\*\*/) {
1761                         }
1762                         # Modifiers should have spaces.
1763                         $to =~ s/(\b$Modifier$)/$1 /;
1764
1765                         #print "from<$from> to<$to> ident<$ident>\n";
1766                         if ($from ne $to && $ident !~ /^$Modifier$/) {
1767                                 ERROR("\"foo${from}bar\" should be \"foo${to}bar\"\n" .  $herecurr);
1768                         }
1769                 }
1770
1771 # # no BUG() or BUG_ON()
1772 #               if ($line =~ /\b(BUG|BUG_ON)\b/) {
1773 #                       print "Try to use WARN_ON & Recovery code rather than BUG() or BUG_ON()\n";
1774 #                       print "$herecurr";
1775 #                       $clean = 0;
1776 #               }
1777
1778                 if ($line =~ /\bLINUX_VERSION_CODE\b/) {
1779                         WARN("LINUX_VERSION_CODE should be avoided, code should be for the version to which it is merged\n" . $herecurr);
1780                 }
1781
1782 # printk should use KERN_* levels.  Note that follow on printk's on the
1783 # same line do not need a level, so we use the current block context
1784 # to try and find and validate the current printk.  In summary the current
1785 # printk includes all preceeding printk's which have no newline on the end.
1786 # we assume the first bad printk is the one to report.
1787                 if ($line =~ /\bprintk\((?!KERN_)\s*"/) {
1788                         my $ok = 0;
1789                         for (my $ln = $linenr - 1; $ln >= $first_line; $ln--) {
1790                                 #print "CHECK<$lines[$ln - 1]\n";
1791                                 # we have a preceeding printk if it ends
1792                                 # with "\n" ignore it, else it is to blame
1793                                 if ($lines[$ln - 1] =~ m{\bprintk\(}) {
1794                                         if ($rawlines[$ln - 1] !~ m{\\n"}) {
1795                                                 $ok = 1;
1796                                         }
1797                                         last;
1798                                 }
1799                         }
1800                         if ($ok == 0) {
1801                                 WARN("printk() should include KERN_ facility level\n" . $herecurr);
1802                         }
1803                 }
1804
1805 # function brace can't be on same line, except for #defines of do while,
1806 # or if closed on same line
1807                 if (($line=~/$Type\s*$Ident\(.*\).*\s{/) and
1808                     !($line=~/\#\s*define.*do\s{/) and !($line=~/}/)) {
1809                         ERROR("open brace '{' following function declarations go on the next line\n" . $herecurr);
1810                 }
1811
1812 # open braces for enum, union and struct go on the same line.
1813                 if ($line =~ /^.\s*{/ &&
1814                     $prevline =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?\s*$/) {
1815                         ERROR("open brace '{' following $1 go on the same line\n" . $hereprev);
1816                 }
1817
1818 # check for spacing round square brackets; allowed:
1819 #  1. with a type on the left -- int [] a;
1820 #  2. at the beginning of a line for slice initialisers -- [0...10] = 5,
1821 #  3. inside a curly brace -- = { [0...10] = 5 }
1822                 while ($line =~ /(.*?\s)\[/g) {
1823                         my ($where, $prefix) = ($-[1], $1);
1824                         if ($prefix !~ /$Type\s+$/ &&
1825                             ($where != 0 || $prefix !~ /^.\s+$/) &&
1826                             $prefix !~ /{\s+$/) {
1827                                 ERROR("space prohibited before open square bracket '['\n" . $herecurr);
1828                         }
1829                 }
1830
1831 # check for spaces between functions and their parentheses.
1832                 while ($line =~ /($Ident)\s+\(/g) {
1833                         my $name = $1;
1834                         my $ctx_before = substr($line, 0, $-[1]);
1835                         my $ctx = "$ctx_before$name";
1836
1837                         # Ignore those directives where spaces _are_ permitted.
1838                         if ($name =~ /^(?:
1839                                 if|for|while|switch|return|case|
1840                                 volatile|__volatile__|
1841                                 __attribute__|format|__extension__|
1842                                 asm|__asm__)$/x)
1843                         {
1844
1845                         # cpp #define statements have non-optional spaces, ie
1846                         # if there is a space between the name and the open
1847                         # parenthesis it is simply not a parameter group.
1848                         } elsif ($ctx_before =~ /^.\s*\#\s*define\s*$/) {
1849
1850                         # cpp #elif statement condition may start with a (
1851                         } elsif ($ctx =~ /^.\s*\#\s*elif\s*$/) {
1852
1853                         # If this whole things ends with a type its most
1854                         # likely a typedef for a function.
1855                         } elsif ($ctx =~ /$Type$/) {
1856
1857                         } else {
1858                                 WARN("space prohibited between function name and open parenthesis '('\n" . $herecurr);
1859                         }
1860                 }
1861 # Check operator spacing.
1862                 if (!($line=~/\#\s*include/)) {
1863                         my $ops = qr{
1864                                 <<=|>>=|<=|>=|==|!=|
1865                                 \+=|-=|\*=|\/=|%=|\^=|\|=|&=|
1866                                 =>|->|<<|>>|<|>|=|!|~|
1867                                 &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%|
1868                                 \?|:
1869                         }x;
1870                         my @elements = split(/($ops|;)/, $opline);
1871                         my $off = 0;
1872
1873                         my $blank = copy_spacing($opline);
1874
1875                         for (my $n = 0; $n < $#elements; $n += 2) {
1876                                 $off += length($elements[$n]);
1877
1878                                 # Pick up the preceeding and succeeding characters.
1879                                 my $ca = substr($opline, 0, $off);
1880                                 my $cc = '';
1881                                 if (length($opline) >= ($off + length($elements[$n + 1]))) {
1882                                         $cc = substr($opline, $off + length($elements[$n + 1]));
1883                                 }
1884                                 my $cb = "$ca$;$cc";
1885
1886                                 my $a = '';
1887                                 $a = 'V' if ($elements[$n] ne '');
1888                                 $a = 'W' if ($elements[$n] =~ /\s$/);
1889                                 $a = 'C' if ($elements[$n] =~ /$;$/);
1890                                 $a = 'B' if ($elements[$n] =~ /(\[|\()$/);
1891                                 $a = 'O' if ($elements[$n] eq '');
1892                                 $a = 'E' if ($ca =~ /^\s*$/);
1893
1894                                 my $op = $elements[$n + 1];
1895
1896                                 my $c = '';
1897                                 if (defined $elements[$n + 2]) {
1898                                         $c = 'V' if ($elements[$n + 2] ne '');
1899                                         $c = 'W' if ($elements[$n + 2] =~ /^\s/);
1900                                         $c = 'C' if ($elements[$n + 2] =~ /^$;/);
1901                                         $c = 'B' if ($elements[$n + 2] =~ /^(\)|\]|;)/);
1902                                         $c = 'O' if ($elements[$n + 2] eq '');
1903                                         $c = 'E' if ($elements[$n + 2] =~ /^\s*\\$/);
1904                                 } else {
1905                                         $c = 'E';
1906                                 }
1907
1908                                 my $ctx = "${a}x${c}";
1909
1910                                 my $at = "(ctx:$ctx)";
1911
1912                                 my $ptr = substr($blank, 0, $off) . "^";
1913                                 my $hereptr = "$hereline$ptr\n";
1914
1915                                 # Pull out the value of this operator.
1916                                 my $op_type = substr($curr_values, $off + 1, 1);
1917
1918                                 # Get the full operator variant.
1919                                 my $opv = $op . substr($curr_vars, $off, 1);
1920
1921                                 # Ignore operators passed as parameters.
1922                                 if ($op_type ne 'V' &&
1923                                     $ca =~ /\s$/ && $cc =~ /^\s*,/) {
1924
1925 #                               # Ignore comments
1926 #                               } elsif ($op =~ /^$;+$/) {
1927
1928                                 # ; should have either the end of line or a space or \ after it
1929                                 } elsif ($op eq ';') {
1930                                         if ($ctx !~ /.x[WEBC]/ &&
1931                                             $cc !~ /^\\/ && $cc !~ /^;/) {
1932                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1933                                         }
1934
1935                                 # // is a comment
1936                                 } elsif ($op eq '//') {
1937
1938                                 # No spaces for:
1939                                 #   ->
1940                                 #   :   when part of a bitfield
1941                                 } elsif ($op eq '->' || $opv eq ':B') {
1942                                         if ($ctx =~ /Wx.|.xW/) {
1943                                                 ERROR("spaces prohibited around that '$op' $at\n" . $hereptr);
1944                                         }
1945
1946                                 # , must have a space on the right.
1947                                 } elsif ($op eq ',') {
1948                                         if ($ctx !~ /.x[WEC]/ && $cc !~ /^}/) {
1949                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1950                                         }
1951
1952                                 # '*' as part of a type definition -- reported already.
1953                                 } elsif ($opv eq '*_') {
1954                                         #warn "'*' is part of type\n";
1955
1956                                 # unary operators should have a space before and
1957                                 # none after.  May be left adjacent to another
1958                                 # unary operator, or a cast
1959                                 } elsif ($op eq '!' || $op eq '~' ||
1960                                          $opv eq '*U' || $opv eq '-U' ||
1961                                          $opv eq '&U' || $opv eq '&&U') {
1962                                         if ($ctx !~ /[WEBC]x./ && $ca !~ /(?:\)|!|~|\*|-|\&|\||\+\+|\-\-|\{)$/) {
1963                                                 ERROR("space required before that '$op' $at\n" . $hereptr);
1964                                         }
1965                                         if ($op eq '*' && $cc =~/\s*$Modifier\b/) {
1966                                                 # A unary '*' may be const
1967
1968                                         } elsif ($ctx =~ /.xW/) {
1969                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1970                                         }
1971
1972                                 # unary ++ and unary -- are allowed no space on one side.
1973                                 } elsif ($op eq '++' or $op eq '--') {
1974                                         if ($ctx !~ /[WEOBC]x[^W]/ && $ctx !~ /[^W]x[WOBEC]/) {
1975                                                 ERROR("space required one side of that '$op' $at\n" . $hereptr);
1976                                         }
1977                                         if ($ctx =~ /Wx[BE]/ ||
1978                                             ($ctx =~ /Wx./ && $cc =~ /^;/)) {
1979                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
1980                                         }
1981                                         if ($ctx =~ /ExW/) {
1982                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1983                                         }
1984
1985
1986                                 # << and >> may either have or not have spaces both sides
1987                                 } elsif ($op eq '<<' or $op eq '>>' or
1988                                          $op eq '&' or $op eq '^' or $op eq '|' or
1989                                          $op eq '+' or $op eq '-' or
1990                                          $op eq '*' or $op eq '/' or
1991                                          $op eq '%')
1992                                 {
1993                                         if ($ctx =~ /Wx[^WCE]|[^WCE]xW/) {
1994                                                 ERROR("need consistent spacing around '$op' $at\n" .
1995                                                         $hereptr);
1996                                         }
1997
1998                                 # A colon needs no spaces before when it is
1999                                 # terminating a case value or a label.
2000                                 } elsif ($opv eq ':C' || $opv eq ':L') {
2001                                         if ($ctx =~ /Wx./) {
2002                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
2003                                         }
2004
2005                                 # All the others need spaces both sides.
2006                                 } elsif ($ctx !~ /[EWC]x[CWE]/) {
2007                                         my $ok = 0;
2008
2009                                         # Ignore email addresses <foo@bar>
2010                                         if (($op eq '<' &&
2011                                              $cc =~ /^\S+\@\S+>/) ||
2012                                             ($op eq '>' &&
2013                                              $ca =~ /<\S+\@\S+$/))
2014                                         {
2015                                                 $ok = 1;
2016                                         }
2017
2018                                         # Ignore ?:
2019                                         if (($opv eq ':O' && $ca =~ /\?$/) ||
2020                                             ($op eq '?' && $cc =~ /^:/)) {
2021                                                 $ok = 1;
2022                                         }
2023
2024                                         if ($ok == 0) {
2025                                                 ERROR("spaces required around that '$op' $at\n" . $hereptr);
2026                                         }
2027                                 }
2028                                 $off += length($elements[$n + 1]);
2029                         }
2030                 }
2031
2032 # check for multiple assignments
2033                 if ($line =~ /^.\s*$Lval\s*=\s*$Lval\s*=(?!=)/) {
2034                         CHK("multiple assignments should be avoided\n" . $herecurr);
2035                 }
2036
2037 ## # check for multiple declarations, allowing for a function declaration
2038 ## # continuation.
2039 ##              if ($line =~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Ident.*/ &&
2040 ##                  $line !~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Type\s*$Ident.*/) {
2041 ##
2042 ##                      # Remove any bracketed sections to ensure we do not
2043 ##                      # falsly report the parameters of functions.
2044 ##                      my $ln = $line;
2045 ##                      while ($ln =~ s/\([^\(\)]*\)//g) {
2046 ##                      }
2047 ##                      if ($ln =~ /,/) {
2048 ##                              WARN("declaring multiple variables together should be avoided\n" . $herecurr);
2049 ##                      }
2050 ##              }
2051
2052 #need space before brace following if, while, etc
2053                 if (($line =~ /\(.*\){/ && $line !~ /\($Type\){/) ||
2054                     $line =~ /do{/) {
2055                         ERROR("space required before the open brace '{'\n" . $herecurr);
2056                 }
2057
2058 # closing brace should have a space following it when it has anything
2059 # on the line
2060                 if ($line =~ /}(?!(?:,|;|\)))\S/) {
2061                         ERROR("space required after that close brace '}'\n" . $herecurr);
2062                 }
2063
2064 # check spacing on square brackets
2065                 if ($line =~ /\[\s/ && $line !~ /\[\s*$/) {
2066                         ERROR("space prohibited after that open square bracket '['\n" . $herecurr);
2067                 }
2068                 if ($line =~ /\s\]/) {
2069                         ERROR("space prohibited before that close square bracket ']'\n" . $herecurr);
2070                 }
2071
2072 # check spacing on parentheses
2073                 if ($line =~ /\(\s/ && $line !~ /\(\s*(?:\\)?$/ &&
2074                     $line !~ /for\s*\(\s+;/) {
2075                         ERROR("space prohibited after that open parenthesis '('\n" . $herecurr);
2076                 }
2077                 if ($line =~ /(\s+)\)/ && $line !~ /^.\s*\)/ &&
2078                     $line !~ /for\s*\(.*;\s+\)/ &&
2079                     $line !~ /:\s+\)/) {
2080                         ERROR("space prohibited before that close parenthesis ')'\n" . $herecurr);
2081                 }
2082
2083 #goto labels aren't indented, allow a single space however
2084                 if ($line=~/^.\s+[A-Za-z\d_]+:(?![0-9]+)/ and
2085                    !($line=~/^. [A-Za-z\d_]+:/) and !($line=~/^.\s+default:/)) {
2086                         WARN("labels should not be indented\n" . $herecurr);
2087                 }
2088
2089 # Return is not a function.
2090                 if (defined($stat) && $stat =~ /^.\s*return(\s*)(\(.*);/s) {
2091                         my $spacing = $1;
2092                         my $value = $2;
2093
2094                         # Flatten any parentheses
2095                         $value =~ s/\)\(/\) \(/g;
2096                         while ($value =~ s/\[[^\{\}]*\]/1/ ||
2097                                $value !~ /(?:$Ident|-?$Constant)\s*
2098                                              $Compare\s*
2099                                              (?:$Ident|-?$Constant)/x &&
2100                                $value =~ s/\([^\(\)]*\)/1/) {
2101                         }
2102
2103                         if ($value =~ /^(?:$Ident|-?$Constant)$/) {
2104                                 ERROR("return is not a function, parentheses are not required\n" . $herecurr);
2105
2106                         } elsif ($spacing !~ /\s+/) {
2107                                 ERROR("space required before the open parenthesis '('\n" . $herecurr);
2108                         }
2109                 }
2110
2111 # Need a space before open parenthesis after if, while etc
2112                 if ($line=~/\b(if|while|for|switch)\(/) {
2113                         ERROR("space required before the open parenthesis '('\n" . $herecurr);
2114                 }
2115
2116 # Check for illegal assignment in if conditional -- and check for trailing
2117 # statements after the conditional.
2118                 if ($line =~ /do\s*(?!{)/) {
2119                         my ($stat_next) = ctx_statement_block($line_nr_next,
2120                                                 $remain_next, $off_next);
2121                         $stat_next =~ s/\n./\n /g;
2122                         ##print "stat<$stat> stat_next<$stat_next>\n";
2123
2124                         if ($stat_next =~ /^\s*while\b/) {
2125                                 # If the statement carries leading newlines,
2126                                 # then count those as offsets.
2127                                 my ($whitespace) =
2128                                         ($stat_next =~ /^((?:\s*\n[+-])*\s*)/s);
2129                                 my $offset =
2130                                         statement_rawlines($whitespace) - 1;
2131
2132                                 $suppress_whiletrailers{$line_nr_next +
2133                                                                 $offset} = 1;
2134                         }
2135                 }
2136                 if (!defined $suppress_whiletrailers{$linenr} &&
2137                     $line =~ /\b(?:if|while|for)\s*\(/ && $line !~ /^.\s*#/) {
2138                         my ($s, $c) = ($stat, $cond);
2139
2140                         if ($c =~ /\bif\s*\(.*[^<>!=]=[^=].*/s) {
2141                                 ERROR("do not use assignment in if condition\n" . $herecurr);
2142                         }
2143
2144                         # Find out what is on the end of the line after the
2145                         # conditional.
2146                         substr($s, 0, length($c), '');
2147                         $s =~ s/\n.*//g;
2148                         $s =~ s/$;//g;  # Remove any comments
2149                         if (length($c) && $s !~ /^\s*{?\s*\\*\s*$/ &&
2150                             $c !~ /}\s*while\s*/)
2151                         {
2152                                 # Find out how long the conditional actually is.
2153                                 my @newlines = ($c =~ /\n/gs);
2154                                 my $cond_lines = 1 + $#newlines;
2155
2156                                 my $stat_real = raw_line($linenr, $cond_lines);
2157                                 if (defined($stat_real) && $cond_lines > 1) {
2158                                         $stat_real = "[...]\n$stat_real";
2159                                 }
2160
2161                                 ERROR("trailing statements should be on next line\n" . $herecurr . $stat_real);
2162                         }
2163                 }
2164
2165 # Check for bitwise tests written as boolean
2166                 if ($line =~ /
2167                         (?:
2168                                 (?:\[|\(|\&\&|\|\|)
2169                                 \s*0[xX][0-9]+\s*
2170                                 (?:\&\&|\|\|)
2171                         |
2172                                 (?:\&\&|\|\|)
2173                                 \s*0[xX][0-9]+\s*
2174                                 (?:\&\&|\|\||\)|\])
2175                         )/x)
2176                 {
2177                         WARN("boolean test with hexadecimal, perhaps just 1 \& or \|?\n" . $herecurr);
2178                 }
2179
2180 # if and else should not have general statements after it
2181                 if ($line =~ /^.\s*(?:}\s*)?else\b(.*)/) {
2182                         my $s = $1;
2183                         $s =~ s/$;//g;  # Remove any comments
2184                         if ($s !~ /^\s*(?:\sif|(?:{|)\s*\\?\s*$)/) {
2185                                 ERROR("trailing statements should be on next line\n" . $herecurr);
2186                         }
2187                 }
2188 # if should not continue a brace
2189                 if ($line =~ /}\s*if\b/) {
2190                         ERROR("trailing statements should be on next line\n" .
2191                                 $herecurr);
2192                 }
2193 # case and default should not have general statements after them
2194                 if ($line =~ /^.\s*(?:case\s*.*|default\s*):/g &&
2195                     $line !~ /\G(?:
2196                         (?:\s*$;*)(?:\s*{)?(?:\s*$;*)(?:\s*\\)?\s*$|
2197                         \s*return\s+
2198                     )/xg)
2199                 {
2200                         ERROR("trailing statements should be on next line\n" . $herecurr);
2201                 }
2202
2203                 # Check for }<nl>else {, these must be at the same
2204                 # indent level to be relevant to each other.
2205                 if ($prevline=~/}\s*$/ and $line=~/^.\s*else\s*/ and
2206                                                 $previndent == $indent) {
2207                         ERROR("else should follow close brace '}'\n" . $hereprev);
2208                 }
2209
2210                 if ($prevline=~/}\s*$/ and $line=~/^.\s*while\s*/ and
2211                                                 $previndent == $indent) {
2212                         my ($s, $c) = ctx_statement_block($linenr, $realcnt, 0);
2213
2214                         # Find out what is on the end of the line after the
2215                         # conditional.
2216                         substr($s, 0, length($c), '');
2217                         $s =~ s/\n.*//g;
2218
2219                         if ($s =~ /^\s*;/) {
2220                                 ERROR("while should follow close brace '}'\n" . $hereprev);
2221                         }
2222                 }
2223
2224 #studly caps, commented out until figure out how to distinguish between use of existing and adding new
2225 #               if (($line=~/[\w_][a-z\d]+[A-Z]/) and !($line=~/print/)) {
2226 #                   print "No studly caps, use _\n";
2227 #                   print "$herecurr";
2228 #                   $clean = 0;
2229 #               }
2230
2231 #no spaces allowed after \ in define
2232                 if ($line=~/\#\s*define.*\\\s$/) {
2233                         WARN("Whitepspace after \\ makes next lines useless\n" . $herecurr);
2234                 }
2235
2236 #warn if <asm/foo.h> is #included and <linux/foo.h> is available (uses RAW line)
2237                 if ($tree && $rawline =~ m{^.\s*\#\s*include\s*\<asm\/(.*)\.h\>}) {
2238                         my $file = "$1.h";
2239                         my $checkfile = "include/linux/$file";
2240                         if (-f "$root/$checkfile" &&
2241                             $realfile ne $checkfile &&
2242                             $1 ne 'irq')
2243                         {
2244                                 if ($realfile =~ m{^arch/}) {
2245                                         CHK("Consider using #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2246                                 } else {
2247                                         WARN("Use #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2248                                 }
2249                         }
2250                 }
2251
2252 # multi-statement macros should be enclosed in a do while loop, grab the
2253 # first statement and ensure its the whole macro if its not enclosed
2254 # in a known good container
2255                 if ($realfile !~ m@/vmlinux.lds.h$@ &&
2256                     $line =~ /^.\s*\#\s*define\s*$Ident(\()?/) {
2257                         my $ln = $linenr;
2258                         my $cnt = $realcnt;
2259                         my ($off, $dstat, $dcond, $rest);
2260                         my $ctx = '';
2261
2262                         my $args = defined($1);
2263
2264                         # Find the end of the macro and limit our statement
2265                         # search to that.
2266                         while ($cnt > 0 && defined $lines[$ln - 1] &&
2267                                 $lines[$ln - 1] =~ /^(?:-|..*\\$)/)
2268                         {
2269                                 $ctx .= $rawlines[$ln - 1] . "\n";
2270                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
2271                                 $ln++;
2272                         }
2273                         $ctx .= $rawlines[$ln - 1];
2274
2275                         ($dstat, $dcond, $ln, $cnt, $off) =
2276                                 ctx_statement_block($linenr, $ln - $linenr + 1, 0);
2277                         #print "dstat<$dstat> dcond<$dcond> cnt<$cnt> off<$off>\n";
2278                         #print "LINE<$lines[$ln-1]> len<" . length($lines[$ln-1]) . "\n";
2279
2280                         # Extract the remainder of the define (if any) and
2281                         # rip off surrounding spaces, and trailing \'s.
2282                         $rest = '';
2283                         while ($off != 0 || ($cnt > 0 && $rest =~ /\\\s*$/)) {
2284                                 #print "ADDING cnt<$cnt> $off <" . substr($lines[$ln - 1], $off) . "> rest<$rest>\n";
2285                                 if ($off != 0 || $lines[$ln - 1] !~ /^-/) {
2286                                         $rest .= substr($lines[$ln - 1], $off) . "\n";
2287                                         $cnt--;
2288                                 }
2289                                 $ln++;
2290                                 $off = 0;
2291                         }
2292                         $rest =~ s/\\\n.//g;
2293                         $rest =~ s/^\s*//s;
2294                         $rest =~ s/\s*$//s;
2295
2296                         # Clean up the original statement.
2297                         if ($args) {
2298                                 substr($dstat, 0, length($dcond), '');
2299                         } else {
2300                                 $dstat =~ s/^.\s*\#\s*define\s+$Ident\s*//;
2301                         }
2302                         $dstat =~ s/$;//g;
2303                         $dstat =~ s/\\\n.//g;
2304                         $dstat =~ s/^\s*//s;
2305                         $dstat =~ s/\s*$//s;
2306
2307                         # Flatten any parentheses and braces
2308                         while ($dstat =~ s/\([^\(\)]*\)/1/ ||
2309                                $dstat =~ s/\{[^\{\}]*\}/1/ ||
2310                                $dstat =~ s/\[[^\{\}]*\]/1/)
2311                         {
2312                         }
2313
2314                         my $exceptions = qr{
2315                                 $Declare|
2316                                 module_param_named|
2317                                 MODULE_PARAM_DESC|
2318                                 DECLARE_PER_CPU|
2319                                 DEFINE_PER_CPU|
2320                                 __typeof__\(|
2321                                 \.$Ident\s*=\s*|
2322                                 ^\"|\"$
2323                         }x;
2324                         #print "REST<$rest> dstat<$dstat>\n";
2325                         if ($rest ne '') {
2326                                 if ($rest !~ /while\s*\(/ &&
2327                                     $dstat !~ /$exceptions/)
2328                                 {
2329                                         ERROR("Macros with multiple statements should be enclosed in a do - while loop\n" . "$here\n$ctx\n");
2330                                 }
2331
2332                         } elsif ($ctx !~ /;/) {
2333                                 if ($dstat ne '' &&
2334                                     $dstat !~ /^(?:$Ident|-?$Constant)$/ &&
2335                                     $dstat !~ /$exceptions/ &&
2336                                     $dstat !~ /^\.$Ident\s*=/ &&
2337                                     $dstat =~ /$Operators/)
2338                                 {
2339                                         ERROR("Macros with complex values should be enclosed in parenthesis\n" . "$here\n$ctx\n");
2340                                 }
2341                         }
2342                 }
2343
2344 # make sure symbols are always wrapped with VMLINUX_SYMBOL() ...
2345 # all assignments may have only one of the following with an assignment:
2346 #       .
2347 #       ALIGN(...)
2348 #       VMLINUX_SYMBOL(...)
2349                 if ($realfile eq 'vmlinux.lds.h' && $line =~ /(?:(?:^|\s)$Ident\s*=|=\s*$Ident(?:\s|$))/) {
2350                         WARN("vmlinux.lds.h needs VMLINUX_SYMBOL() around C-visible symbols\n" . $herecurr);
2351                 }
2352
2353 # check for redundant bracing round if etc
2354                 if ($line =~ /(^.*)\bif\b/ && $1 !~ /else\s*$/) {
2355                         my ($level, $endln, @chunks) =
2356                                 ctx_statement_full($linenr, $realcnt, 1);
2357                         #print "chunks<$#chunks> linenr<$linenr> endln<$endln> level<$level>\n";
2358                         #print "APW: <<$chunks[1][0]>><<$chunks[1][1]>>\n";
2359                         if ($#chunks > 0 && $level == 0) {
2360                                 my $allowed = 0;
2361                                 my $seen = 0;
2362                                 my $herectx = $here . "\n";
2363                                 my $ln = $linenr - 1;
2364                                 for my $chunk (@chunks) {
2365                                         my ($cond, $block) = @{$chunk};
2366
2367                                         # If the condition carries leading newlines, then count those as offsets.
2368                                         my ($whitespace) = ($cond =~ /^((?:\s*\n[+-])*\s*)/s);
2369                                         my $offset = statement_rawlines($whitespace) - 1;
2370
2371                                         #print "COND<$cond> whitespace<$whitespace> offset<$offset>\n";
2372
2373                                         # We have looked at and allowed this specific line.
2374                                         $suppress_ifbraces{$ln + $offset} = 1;
2375
2376                                         $herectx .= "$rawlines[$ln + $offset]\n[...]\n";
2377                                         $ln += statement_rawlines($block) - 1;
2378
2379                                         substr($block, 0, length($cond), '');
2380
2381                                         $seen++ if ($block =~ /^\s*{/);
2382
2383                                         #print "cond<$cond> block<$block> allowed<$allowed>\n";
2384                                         if (statement_lines($cond) > 1) {
2385                                                 #print "APW: ALLOWED: cond<$cond>\n";
2386                                                 $allowed = 1;
2387                                         }
2388                                         if ($block =~/\b(?:if|for|while)\b/) {
2389                                                 #print "APW: ALLOWED: block<$block>\n";
2390                                                 $allowed = 1;
2391                                         }
2392                                         if (statement_block_size($block) > 1) {
2393                                                 #print "APW: ALLOWED: lines block<$block>\n";
2394                                                 $allowed = 1;
2395                                         }
2396                                 }
2397                                 if ($seen && !$allowed) {
2398                                         WARN("braces {} are not necessary for any arm of this statement\n" . $herectx);
2399                                 }
2400                         }
2401                 }
2402                 if (!defined $suppress_ifbraces{$linenr - 1} &&
2403                                         $line =~ /\b(if|while|for|else)\b/) {
2404                         my $allowed = 0;
2405
2406                         # Check the pre-context.
2407                         if (substr($line, 0, $-[0]) =~ /(\}\s*)$/) {
2408                                 #print "APW: ALLOWED: pre<$1>\n";
2409                                 $allowed = 1;
2410                         }
2411
2412                         my ($level, $endln, @chunks) =
2413                                 ctx_statement_full($linenr, $realcnt, $-[0]);
2414
2415                         # Check the condition.
2416                         my ($cond, $block) = @{$chunks[0]};
2417                         #print "CHECKING<$linenr> cond<$cond> block<$block>\n";
2418                         if (defined $cond) {
2419                                 substr($block, 0, length($cond), '');
2420                         }
2421                         if (statement_lines($cond) > 1) {
2422                                 #print "APW: ALLOWED: cond<$cond>\n";
2423                                 $allowed = 1;
2424                         }
2425                         if ($block =~/\b(?:if|for|while)\b/) {
2426                                 #print "APW: ALLOWED: block<$block>\n";
2427                                 $allowed = 1;
2428                         }
2429                         if (statement_block_size($block) > 1) {
2430                                 #print "APW: ALLOWED: lines block<$block>\n";
2431                                 $allowed = 1;
2432                         }
2433                         # Check the post-context.
2434                         if (defined $chunks[1]) {
2435                                 my ($cond, $block) = @{$chunks[1]};
2436                                 if (defined $cond) {
2437                                         substr($block, 0, length($cond), '');
2438                                 }
2439                                 if ($block =~ /^\s*\{/) {
2440                                         #print "APW: ALLOWED: chunk-1 block<$block>\n";
2441                                         $allowed = 1;
2442                                 }
2443                         }
2444                         if ($level == 0 && $block =~ /^\s*\{/ && !$allowed) {
2445                                 my $herectx = $here . "\n";;
2446                                 my $cnt = statement_rawlines($block);
2447
2448                                 for (my $n = 0; $n < $cnt; $n++) {
2449                                         $herectx .= raw_line($linenr, $n) . "\n";;
2450                                 }
2451
2452                                 WARN("braces {} are not necessary for single statement blocks\n" . $herectx);
2453                         }
2454                 }
2455
2456 # don't include deprecated include files (uses RAW line)
2457                 for my $inc (@dep_includes) {
2458                         if ($rawline =~ m@^.\s*\#\s*include\s*\<$inc>@) {
2459                                 ERROR("Don't use <$inc>: see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2460                         }
2461                 }
2462
2463 # don't use deprecated functions
2464                 for my $func (@dep_functions) {
2465                         if ($line =~ /\b$func\b/) {
2466                                 ERROR("Don't use $func(): see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2467                         }
2468                 }
2469
2470 # no volatiles please
2471                 my $asm_volatile = qr{\b(__asm__|asm)\s+(__volatile__|volatile)\b};
2472                 if ($line =~ /\bvolatile\b/ && $line !~ /$asm_volatile/) {
2473                         WARN("Use of volatile is usually wrong: see Documentation/volatile-considered-harmful.txt\n" . $herecurr);
2474                 }
2475
2476 # SPIN_LOCK_UNLOCKED & RW_LOCK_UNLOCKED are deprecated
2477                 if ($line =~ /\b(SPIN_LOCK_UNLOCKED|RW_LOCK_UNLOCKED)/) {
2478                         ERROR("Use of $1 is deprecated: see Documentation/spinlocks.txt\n" . $herecurr);
2479                 }
2480
2481 # warn about #if 0
2482                 if ($line =~ /^.\s*\#\s*if\s+0\b/) {
2483                         CHK("if this code is redundant consider removing it\n" .
2484                                 $herecurr);
2485                 }
2486
2487 # check for needless kfree() checks
2488                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2489                         my $expr = $1;
2490                         if ($line =~ /\bkfree\(\Q$expr\E\);/) {
2491                                 WARN("kfree(NULL) is safe this check is probably not required\n" . $hereprev);
2492                         }
2493                 }
2494 # check for needless usb_free_urb() checks
2495                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2496                         my $expr = $1;
2497                         if ($line =~ /\busb_free_urb\(\Q$expr\E\);/) {
2498                                 WARN("usb_free_urb(NULL) is safe this check is probably not required\n" . $hereprev);
2499                         }
2500                 }
2501
2502 # warn about #ifdefs in C files
2503 #               if ($line =~ /^.\s*\#\s*if(|n)def/ && ($realfile =~ /\.c$/)) {
2504 #                       print "#ifdef in C files should be avoided\n";
2505 #                       print "$herecurr";
2506 #                       $clean = 0;
2507 #               }
2508
2509 # warn about spacing in #ifdefs
2510                 if ($line =~ /^.\s*\#\s*(ifdef|ifndef|elif)\s\s+/) {
2511                         ERROR("exactly one space required after that #$1\n" . $herecurr);
2512                 }
2513
2514 # check for spinlock_t definitions without a comment.
2515                 if ($line =~ /^.\s*(struct\s+mutex|spinlock_t)\s+\S+;/ ||
2516                     $line =~ /^.\s*(DEFINE_MUTEX)\s*\(/) {
2517                         my $which = $1;
2518                         if (!ctx_has_comment($first_line, $linenr)) {
2519                                 CHK("$1 definition without comment\n" . $herecurr);
2520                         }
2521                 }
2522 # check for memory barriers without a comment.
2523                 if ($line =~ /\b(mb|rmb|wmb|read_barrier_depends|smp_mb|smp_rmb|smp_wmb|smp_read_barrier_depends)\(/) {
2524                         if (!ctx_has_comment($first_line, $linenr)) {
2525                                 CHK("memory barrier without comment\n" . $herecurr);
2526                         }
2527                 }
2528 # check of hardware specific defines
2529                 if ($line =~ m@^.\s*\#\s*if.*\b(__i386__|__powerpc64__|__sun__|__s390x__)\b@ && $realfile !~ m@include/asm-@) {
2530                         CHK("architecture specific defines should be avoided\n" .  $herecurr);
2531                 }
2532
2533 # check the location of the inline attribute, that it is between
2534 # storage class and type.
2535                 if ($line =~ /\b$Type\s+$Inline\b/ ||
2536                     $line =~ /\b$Inline\s+$Storage\b/) {
2537                         ERROR("inline keyword should sit between storage class and type\n" . $herecurr);
2538                 }
2539
2540 # Check for __inline__ and __inline, prefer inline
2541                 if ($line =~ /\b(__inline__|__inline)\b/) {
2542                         WARN("plain inline is preferred over $1\n" . $herecurr);
2543                 }
2544
2545 # check for new externs in .c files.
2546                 if ($realfile =~ /\.c$/ && defined $stat &&
2547                     $stat =~ /^.\s*(?:extern\s+)?$Type\s+($Ident)(\s*)\(/s)
2548                 {
2549                         my $function_name = $1;
2550                         my $paren_space = $2;
2551
2552                         my $s = $stat;
2553                         if (defined $cond) {
2554                                 substr($s, 0, length($cond), '');
2555                         }
2556                         if ($s =~ /^\s*;/ &&
2557                             $function_name ne 'uninitialized_var')
2558                         {
2559                                 WARN("externs should be avoided in .c files\n" .  $herecurr);
2560                         }
2561
2562                         if ($paren_space =~ /\n/) {
2563                                 WARN("arguments for function declarations should follow identifier\n" . $herecurr);
2564                         }
2565
2566                 } elsif ($realfile =~ /\.c$/ && defined $stat &&
2567                     $stat =~ /^.\s*extern\s+/)
2568                 {
2569                         WARN("externs should be avoided in .c files\n" .  $herecurr);
2570                 }
2571
2572 # checks for new __setup's
2573                 if ($rawline =~ /\b__setup\("([^"]*)"/) {
2574                         my $name = $1;
2575
2576                         if (!grep(/$name/, @setup_docs)) {
2577                                 CHK("__setup appears un-documented -- check Documentation/kernel-parameters.txt\n" . $herecurr);
2578                         }
2579                 }
2580
2581 # check for pointless casting of kmalloc return
2582                 if ($line =~ /\*\s*\)\s*k[czm]alloc\b/) {
2583                         WARN("unnecessary cast may hide bugs, see http://c-faq.com/malloc/mallocnocast.html\n" . $herecurr);
2584                 }
2585
2586 # check for gcc specific __FUNCTION__
2587                 if ($line =~ /__FUNCTION__/) {
2588                         WARN("__func__ should be used instead of gcc specific __FUNCTION__\n"  . $herecurr);
2589                 }
2590
2591 # check for semaphores used as mutexes
2592                 if ($line =~ /^.\s*(DECLARE_MUTEX|init_MUTEX)\s*\(/) {
2593                         WARN("mutexes are preferred for single holder semaphores\n" . $herecurr);
2594                 }
2595 # check for semaphores used as mutexes
2596                 if ($line =~ /^.\s*init_MUTEX_LOCKED\s*\(/) {
2597                         WARN("consider using a completion\n" . $herecurr);
2598                 }
2599 # recommend strict_strto* over simple_strto*
2600                 if ($line =~ /\bsimple_(strto.*?)\s*\(/) {
2601                         WARN("consider using strict_$1 in preference to simple_$1\n" . $herecurr);
2602                 }
2603 # check for __initcall(), use device_initcall() explicitly please
2604                 if ($line =~ /^.\s*__initcall\s*\(/) {
2605                         WARN("please use device_initcall() instead of __initcall()\n" . $herecurr);
2606                 }
2607 # check for struct file_operations, ensure they are const.
2608                 if ($line !~ /\bconst\b/ &&
2609                     $line =~ /\bstruct\s+(file_operations|seq_operations)\b/) {
2610                         WARN("struct $1 should normally be const\n" .
2611                                 $herecurr);
2612                 }
2613
2614 # use of NR_CPUS is usually wrong
2615 # ignore definitions of NR_CPUS and usage to define arrays as likely right
2616                 if ($line =~ /\bNR_CPUS\b/ &&
2617                     $line !~ /^.\s*\s*#\s*if\b.*\bNR_CPUS\b/ &&
2618                     $line !~ /^.\s*\s*#\s*define\b.*\bNR_CPUS\b/ &&
2619                     $line !~ /^.\s*$Declare\s.*\[[^\]]*NR_CPUS[^\]]*\]/ &&
2620                     $line !~ /\[[^\]]*\.\.\.[^\]]*NR_CPUS[^\]]*\]/ &&
2621                     $line !~ /\[[^\]]*NR_CPUS[^\]]*\.\.\.[^\]]*\]/)
2622                 {
2623                         WARN("usage of NR_CPUS is often wrong - consider using cpu_possible(), num_possible_cpus(), for_each_possible_cpu(), etc\n" . $herecurr);
2624                 }
2625
2626 # check for %L{u,d,i} in strings
2627                 my $string;
2628                 while ($line =~ /(?:^|")([X\t]*)(?:"|$)/g) {
2629                         $string = substr($rawline, $-[1], $+[1] - $-[1]);
2630                         $string =~ s/%%/__/g;
2631                         if ($string =~ /(?<!%)%L[udi]/) {
2632                                 WARN("\%Ld/%Lu are not-standard C, use %lld/%llu\n" . $herecurr);
2633                                 last;
2634                         }
2635                 }
2636
2637 # whine mightly about in_atomic
2638                 if ($line =~ /\bin_atomic\s*\(/) {
2639                         if ($realfile =~ m@^drivers/@) {
2640                                 ERROR("do not use in_atomic in drivers\n" . $herecurr);
2641                         } elsif ($realfile !~ m@^kernel/@) {
2642                                 WARN("use of in_atomic() is incorrect outside core kernel code\n" . $herecurr);
2643                         }
2644                 }
2645         }
2646
2647         # If we have no input at all, then there is nothing to report on
2648         # so just keep quiet.
2649         if ($#rawlines == -1) {
2650                 exit(0);
2651         }
2652
2653         # In mailback mode only produce a report in the negative, for
2654         # things that appear to be patches.
2655         if ($mailback && ($clean == 1 || !$is_patch)) {
2656                 exit(0);
2657         }
2658
2659         # This is not a patch, and we are are in 'no-patch' mode so
2660         # just keep quiet.
2661         if (!$chk_patch && !$is_patch) {
2662                 exit(0);
2663         }
2664
2665         if (!$is_patch) {
2666                 ERROR("Does not appear to be a unified-diff format patch\n");
2667         }
2668         if ($is_patch && $chk_signoff && $signoff == 0) {
2669                 ERROR("Missing Signed-off-by: line(s)\n");
2670         }
2671
2672         print report_dump();
2673         if ($summary && !($clean == 1 && $quiet == 1)) {
2674                 print "$filename " if ($summary_file);
2675                 print "total: $cnt_error errors, $cnt_warn warnings, " .
2676                         (($check)? "$cnt_chk checks, " : "") .
2677                         "$cnt_lines lines checked\n";
2678                 print "\n" if ($quiet == 0);
2679         }
2680
2681         if ($clean == 1 && $quiet == 0) {
2682                 print "$vname has no obvious style problems and is ready for submission.\n"
2683         }
2684         if ($clean == 0 && $quiet == 0) {
2685                 print "$vname has style problems, please review.  If any of these errors\n";
2686                 print "are false positives report them to the maintainer, see\n";
2687                 print "CHECKPATCH in MAINTAINERS.\n";
2688         }
2689
2690         return $clean;
2691 }