1c032b1fa9eb58151f61023ec95e471472cac36a
[linux-2.6.git] / scripts / checkpatch.pl
1 #!/usr/bin/perl -w
2 # (c) 2001, Dave Jones. <davej@codemonkey.org.uk> (the file handling bit)
3 # (c) 2005, Joel Schopp <jschopp@austin.ibm.com> (the ugly bit)
4 # (c) 2007, Andy Whitcroft <apw@uk.ibm.com> (new conditions, test suite, etc)
5 # Licensed under the terms of the GNU GPL License version 2
6
7 use strict;
8
9 my $P = $0;
10 $P =~ s@.*/@@g;
11
12 my $V = '0.21';
13
14 use Getopt::Long qw(:config no_auto_abbrev);
15
16 my $quiet = 0;
17 my $tree = 1;
18 my $chk_signoff = 1;
19 my $chk_patch = 1;
20 my $tst_only;
21 my $emacs = 0;
22 my $terse = 0;
23 my $file = 0;
24 my $check = 0;
25 my $summary = 1;
26 my $mailback = 0;
27 my $summary_file = 0;
28 my $root;
29 my %debug;
30 GetOptions(
31         'q|quiet+'      => \$quiet,
32         'tree!'         => \$tree,
33         'signoff!'      => \$chk_signoff,
34         'patch!'        => \$chk_patch,
35         'emacs!'        => \$emacs,
36         'terse!'        => \$terse,
37         'file!'         => \$file,
38         'subjective!'   => \$check,
39         'strict!'       => \$check,
40         'root=s'        => \$root,
41         'summary!'      => \$summary,
42         'mailback!'     => \$mailback,
43         'summary-file!' => \$summary_file,
44
45         'debug=s'       => \%debug,
46         'test-only=s'   => \$tst_only,
47 ) or exit;
48
49 my $exit = 0;
50
51 if ($#ARGV < 0) {
52         print "usage: $P [options] patchfile\n";
53         print "version: $V\n";
54         print "options: -q               => quiet\n";
55         print "         --no-tree        => run without a kernel tree\n";
56         print "         --terse          => one line per report\n";
57         print "         --emacs          => emacs compile window format\n";
58         print "         --file           => check a source file\n";
59         print "         --strict         => enable more subjective tests\n";
60         print "         --root           => path to the kernel tree root\n";
61         print "         --no-summary     => suppress the per-file summary\n";
62         print "         --summary-file   => include the filename in summary\n";
63         exit(1);
64 }
65
66 my $dbg_values = 0;
67 my $dbg_possible = 0;
68 my $dbg_type = 0;
69 my $dbg_attr = 0;
70 for my $key (keys %debug) {
71         eval "\${dbg_$key} = '$debug{$key}';"
72 }
73
74 if ($terse) {
75         $emacs = 1;
76         $quiet++;
77 }
78
79 if ($tree) {
80         if (defined $root) {
81                 if (!top_of_kernel_tree($root)) {
82                         die "$P: $root: --root does not point at a valid tree\n";
83                 }
84         } else {
85                 if (top_of_kernel_tree('.')) {
86                         $root = '.';
87                 } elsif ($0 =~ m@(.*)/scripts/[^/]*$@ &&
88                                                 top_of_kernel_tree($1)) {
89                         $root = $1;
90                 }
91         }
92
93         if (!defined $root) {
94                 print "Must be run from the top-level dir. of a kernel tree\n";
95                 exit(2);
96         }
97 }
98
99 my $emitted_corrupt = 0;
100
101 our $Ident       = qr{[A-Za-z_][A-Za-z\d_]*};
102 our $Storage    = qr{extern|static|asmlinkage};
103 our $Sparse     = qr{
104                         __user|
105                         __kernel|
106                         __force|
107                         __iomem|
108                         __must_check|
109                         __init_refok|
110                         __kprobes
111                 }x;
112 our $Attribute  = qr{
113                         const|
114                         __read_mostly|
115                         __kprobes|
116                         __(?:mem|cpu|dev|)(?:initdata|init)
117                   }x;
118 our $Modifier;
119 our $Inline     = qr{inline|__always_inline|noinline};
120 our $Member     = qr{->$Ident|\.$Ident|\[[^]]*\]};
121 our $Lval       = qr{$Ident(?:$Member)*};
122
123 our $Constant   = qr{(?:[0-9]+|0x[0-9a-fA-F]+)[UL]*};
124 our $Assignment = qr{(?:\*\=|/=|%=|\+=|-=|<<=|>>=|&=|\^=|\|=|=)};
125 our $Operators  = qr{
126                         <=|>=|==|!=|
127                         =>|->|<<|>>|<|>|!|~|
128                         &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%
129                   }x;
130
131 our $NonptrType;
132 our $Type;
133 our $Declare;
134
135 our $UTF8       = qr {
136         [\x09\x0A\x0D\x20-\x7E]              # ASCII
137         | [\xC2-\xDF][\x80-\xBF]             # non-overlong 2-byte
138         |  \xE0[\xA0-\xBF][\x80-\xBF]        # excluding overlongs
139         | [\xE1-\xEC\xEE\xEF][\x80-\xBF]{2}  # straight 3-byte
140         |  \xED[\x80-\x9F][\x80-\xBF]        # excluding surrogates
141         |  \xF0[\x90-\xBF][\x80-\xBF]{2}     # planes 1-3
142         | [\xF1-\xF3][\x80-\xBF]{3}          # planes 4-15
143         |  \xF4[\x80-\x8F][\x80-\xBF]{2}     # plane 16
144 }x;
145
146 our @typeList = (
147         qr{void},
148         qr{(?:unsigned\s+)?char},
149         qr{(?:unsigned\s+)?short},
150         qr{(?:unsigned\s+)?int},
151         qr{(?:unsigned\s+)?long},
152         qr{(?:unsigned\s+)?long\s+int},
153         qr{(?:unsigned\s+)?long\s+long},
154         qr{(?:unsigned\s+)?long\s+long\s+int},
155         qr{unsigned},
156         qr{float},
157         qr{double},
158         qr{bool},
159         qr{(?:__)?(?:u|s|be|le)(?:8|16|32|64)},
160         qr{struct\s+$Ident},
161         qr{union\s+$Ident},
162         qr{enum\s+$Ident},
163         qr{${Ident}_t},
164         qr{${Ident}_handler},
165         qr{${Ident}_handler_fn},
166 );
167 our @modifierList = (
168         qr{fastcall},
169 );
170
171 sub build_types {
172         my $mods = "(?x:  \n" . join("|\n  ", @modifierList) . "\n)";
173         my $all = "(?x:  \n" . join("|\n  ", @typeList) . "\n)";
174         $Modifier       = qr{(?:$Attribute|$Sparse|$mods)};
175         $NonptrType     = qr{
176                         (?:$Modifier\s+|const\s+)*
177                         (?:
178                                 (?:typeof|__typeof__)\s*\(\s*\**\s*$Ident\s*\)|
179                                 (?:${all}\b)
180                         )
181                         (?:\s+$Modifier|\s+const)*
182                   }x;
183         $Type   = qr{
184                         $NonptrType
185                         (?:\s*\*+\s*const|\s*\*+|(?:\s*\[\s*\])+)?
186                         (?:\s+$Inline|\s+$Modifier)*
187                   }x;
188         $Declare        = qr{(?:$Storage\s+)?$Type};
189 }
190 build_types();
191
192 $chk_signoff = 0 if ($file);
193
194 my @dep_includes = ();
195 my @dep_functions = ();
196 my $removal = "Documentation/feature-removal-schedule.txt";
197 if ($tree && -f "$root/$removal") {
198         open(REMOVE, "<$root/$removal") ||
199                                 die "$P: $removal: open failed - $!\n";
200         while (<REMOVE>) {
201                 if (/^Check:\s+(.*\S)/) {
202                         for my $entry (split(/[, ]+/, $1)) {
203                                 if ($entry =~ m@include/(.*)@) {
204                                         push(@dep_includes, $1);
205
206                                 } elsif ($entry !~ m@/@) {
207                                         push(@dep_functions, $entry);
208                                 }
209                         }
210                 }
211         }
212 }
213
214 my @rawlines = ();
215 my @lines = ();
216 my $vname;
217 for my $filename (@ARGV) {
218         if ($file) {
219                 open(FILE, "diff -u /dev/null $filename|") ||
220                         die "$P: $filename: diff failed - $!\n";
221         } else {
222                 open(FILE, "<$filename") ||
223                         die "$P: $filename: open failed - $!\n";
224         }
225         if ($filename eq '-') {
226                 $vname = 'Your patch';
227         } else {
228                 $vname = $filename;
229         }
230         while (<FILE>) {
231                 chomp;
232                 push(@rawlines, $_);
233         }
234         close(FILE);
235         if (!process($filename)) {
236                 $exit = 1;
237         }
238         @rawlines = ();
239         @lines = ();
240 }
241
242 exit($exit);
243
244 sub top_of_kernel_tree {
245         my ($root) = @_;
246
247         my @tree_check = (
248                 "COPYING", "CREDITS", "Kbuild", "MAINTAINERS", "Makefile",
249                 "README", "Documentation", "arch", "include", "drivers",
250                 "fs", "init", "ipc", "kernel", "lib", "scripts",
251         );
252
253         foreach my $check (@tree_check) {
254                 if (! -e $root . '/' . $check) {
255                         return 0;
256                 }
257         }
258         return 1;
259 }
260
261 sub expand_tabs {
262         my ($str) = @_;
263
264         my $res = '';
265         my $n = 0;
266         for my $c (split(//, $str)) {
267                 if ($c eq "\t") {
268                         $res .= ' ';
269                         $n++;
270                         for (; ($n % 8) != 0; $n++) {
271                                 $res .= ' ';
272                         }
273                         next;
274                 }
275                 $res .= $c;
276                 $n++;
277         }
278
279         return $res;
280 }
281 sub copy_spacing {
282         (my $res = shift) =~ tr/\t/ /c;
283         return $res;
284 }
285
286 sub line_stats {
287         my ($line) = @_;
288
289         # Drop the diff line leader and expand tabs
290         $line =~ s/^.//;
291         $line = expand_tabs($line);
292
293         # Pick the indent from the front of the line.
294         my ($white) = ($line =~ /^(\s*)/);
295
296         return (length($line), length($white));
297 }
298
299 my $sanitise_quote = '';
300
301 sub sanitise_line_reset {
302         my ($in_comment) = @_;
303
304         if ($in_comment) {
305                 $sanitise_quote = '*/';
306         } else {
307                 $sanitise_quote = '';
308         }
309 }
310 sub sanitise_line {
311         my ($line) = @_;
312
313         my $res = '';
314         my $l = '';
315
316         my $qlen = 0;
317         my $off = 0;
318         my $c;
319
320         # Always copy over the diff marker.
321         $res = substr($line, 0, 1);
322
323         for ($off = 1; $off < length($line); $off++) {
324                 $c = substr($line, $off, 1);
325
326                 # Comments we are wacking completly including the begin
327                 # and end, all to $;.
328                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '/*') {
329                         $sanitise_quote = '*/';
330
331                         substr($res, $off, 2, "$;$;");
332                         $off++;
333                         next;
334                 }
335                 if (substr($line, $off, 2) eq '*/') {
336                         $sanitise_quote = '';
337                         substr($res, $off, 2, "$;$;");
338                         $off++;
339                         next;
340                 }
341
342                 # A \ in a string means ignore the next character.
343                 if (($sanitise_quote eq "'" || $sanitise_quote eq '"') &&
344                     $c eq "\\") {
345                         substr($res, $off, 2, 'XX');
346                         $off++;
347                         next;
348                 }
349                 # Regular quotes.
350                 if ($c eq "'" || $c eq '"') {
351                         if ($sanitise_quote eq '') {
352                                 $sanitise_quote = $c;
353
354                                 substr($res, $off, 1, $c);
355                                 next;
356                         } elsif ($sanitise_quote eq $c) {
357                                 $sanitise_quote = '';
358                         }
359                 }
360
361                 #print "SQ:$sanitise_quote\n";
362                 if ($off != 0 && $sanitise_quote eq '*/' && $c ne "\t") {
363                         substr($res, $off, 1, $;);
364                 } elsif ($off != 0 && $sanitise_quote && $c ne "\t") {
365                         substr($res, $off, 1, 'X');
366                 } else {
367                         substr($res, $off, 1, $c);
368                 }
369         }
370
371         # The pathname on a #include may be surrounded by '<' and '>'.
372         if ($res =~ /^.\s*\#\s*include\s+\<(.*)\>/) {
373                 my $clean = 'X' x length($1);
374                 $res =~ s@\<.*\>@<$clean>@;
375
376         # The whole of a #error is a string.
377         } elsif ($res =~ /^.\s*\#\s*(?:error|warning)\s+(.*)\b/) {
378                 my $clean = 'X' x length($1);
379                 $res =~ s@(\#\s*(?:error|warning)\s+).*@$1$clean@;
380         }
381
382         return $res;
383 }
384
385 sub ctx_statement_block {
386         my ($linenr, $remain, $off) = @_;
387         my $line = $linenr - 1;
388         my $blk = '';
389         my $soff = $off;
390         my $coff = $off - 1;
391         my $coff_set = 0;
392
393         my $loff = 0;
394
395         my $type = '';
396         my $level = 0;
397         my $p;
398         my $c;
399         my $len = 0;
400
401         my $remainder;
402         while (1) {
403                 #warn "CSB: blk<$blk> remain<$remain>\n";
404                 # If we are about to drop off the end, pull in more
405                 # context.
406                 if ($off >= $len) {
407                         for (; $remain > 0; $line++) {
408                                 next if ($lines[$line] =~ /^-/);
409                                 $remain--;
410                                 $loff = $len;
411                                 $blk .= $lines[$line] . "\n";
412                                 $len = length($blk);
413                                 $line++;
414                                 last;
415                         }
416                         # Bail if there is no further context.
417                         #warn "CSB: blk<$blk> off<$off> len<$len>\n";
418                         if ($off >= $len) {
419                                 last;
420                         }
421                 }
422                 $p = $c;
423                 $c = substr($blk, $off, 1);
424                 $remainder = substr($blk, $off);
425
426                 #warn "CSB: c<$c> type<$type> level<$level> remainder<$remainder> coff_set<$coff_set>\n";
427                 # Statement ends at the ';' or a close '}' at the
428                 # outermost level.
429                 if ($level == 0 && $c eq ';') {
430                         last;
431                 }
432
433                 # An else is really a conditional as long as its not else if
434                 if ($level == 0 && $coff_set == 0 &&
435                                 (!defined($p) || $p =~ /(?:\s|\}|\+)/) &&
436                                 $remainder =~ /^(else)(?:\s|{)/ &&
437                                 $remainder !~ /^else\s+if\b/) {
438                         $coff = $off + length($1) - 1;
439                         $coff_set = 1;
440                         #warn "CSB: mark coff<$coff> soff<$soff> 1<$1>\n";
441                         #warn "[" . substr($blk, $soff, $coff - $soff + 1) . "]\n";
442                 }
443
444                 if (($type eq '' || $type eq '(') && $c eq '(') {
445                         $level++;
446                         $type = '(';
447                 }
448                 if ($type eq '(' && $c eq ')') {
449                         $level--;
450                         $type = ($level != 0)? '(' : '';
451
452                         if ($level == 0 && $coff < $soff) {
453                                 $coff = $off;
454                                 $coff_set = 1;
455                                 #warn "CSB: mark coff<$coff>\n";
456                         }
457                 }
458                 if (($type eq '' || $type eq '{') && $c eq '{') {
459                         $level++;
460                         $type = '{';
461                 }
462                 if ($type eq '{' && $c eq '}') {
463                         $level--;
464                         $type = ($level != 0)? '{' : '';
465
466                         if ($level == 0) {
467                                 last;
468                         }
469                 }
470                 $off++;
471         }
472         # We are truly at the end, so shuffle to the next line.
473         if ($off == $len) {
474                 $loff = $len + 1;
475                 $line++;
476                 $remain--;
477         }
478
479         my $statement = substr($blk, $soff, $off - $soff + 1);
480         my $condition = substr($blk, $soff, $coff - $soff + 1);
481
482         #warn "STATEMENT<$statement>\n";
483         #warn "CONDITION<$condition>\n";
484
485         #print "coff<$coff> soff<$off> loff<$loff>\n";
486
487         return ($statement, $condition,
488                         $line, $remain + 1, $off - $loff + 1, $level);
489 }
490
491 sub statement_lines {
492         my ($stmt) = @_;
493
494         # Strip the diff line prefixes and rip blank lines at start and end.
495         $stmt =~ s/(^|\n)./$1/g;
496         $stmt =~ s/^\s*//;
497         $stmt =~ s/\s*$//;
498
499         my @stmt_lines = ($stmt =~ /\n/g);
500
501         return $#stmt_lines + 2;
502 }
503
504 sub statement_rawlines {
505         my ($stmt) = @_;
506
507         my @stmt_lines = ($stmt =~ /\n/g);
508
509         return $#stmt_lines + 2;
510 }
511
512 sub statement_block_size {
513         my ($stmt) = @_;
514
515         $stmt =~ s/(^|\n)./$1/g;
516         $stmt =~ s/^\s*{//;
517         $stmt =~ s/}\s*$//;
518         $stmt =~ s/^\s*//;
519         $stmt =~ s/\s*$//;
520
521         my @stmt_lines = ($stmt =~ /\n/g);
522         my @stmt_statements = ($stmt =~ /;/g);
523
524         my $stmt_lines = $#stmt_lines + 2;
525         my $stmt_statements = $#stmt_statements + 1;
526
527         if ($stmt_lines > $stmt_statements) {
528                 return $stmt_lines;
529         } else {
530                 return $stmt_statements;
531         }
532 }
533
534 sub ctx_statement_full {
535         my ($linenr, $remain, $off) = @_;
536         my ($statement, $condition, $level);
537
538         my (@chunks);
539
540         # Grab the first conditional/block pair.
541         ($statement, $condition, $linenr, $remain, $off, $level) =
542                                 ctx_statement_block($linenr, $remain, $off);
543         #print "F: c<$condition> s<$statement> remain<$remain>\n";
544         push(@chunks, [ $condition, $statement ]);
545         if (!($remain > 0 && $condition =~ /^\s*(?:\n[+-])?\s*(?:if|else|do)\b/s)) {
546                 return ($level, $linenr, @chunks);
547         }
548
549         # Pull in the following conditional/block pairs and see if they
550         # could continue the statement.
551         for (;;) {
552                 ($statement, $condition, $linenr, $remain, $off, $level) =
553                                 ctx_statement_block($linenr, $remain, $off);
554                 #print "C: c<$condition> s<$statement> remain<$remain>\n";
555                 last if (!($remain > 0 && $condition =~ /^(?:\s*\n[+-])*\s*(?:else|do)\b/s));
556                 #print "C: push\n";
557                 push(@chunks, [ $condition, $statement ]);
558         }
559
560         return ($level, $linenr, @chunks);
561 }
562
563 sub ctx_block_get {
564         my ($linenr, $remain, $outer, $open, $close, $off) = @_;
565         my $line;
566         my $start = $linenr - 1;
567         my $blk = '';
568         my @o;
569         my @c;
570         my @res = ();
571
572         my $level = 0;
573         for ($line = $start; $remain > 0; $line++) {
574                 next if ($rawlines[$line] =~ /^-/);
575                 $remain--;
576
577                 $blk .= $rawlines[$line];
578                 foreach my $c (split(//, $rawlines[$line])) {
579                         ##print "C<$c>L<$level><$open$close>O<$off>\n";
580                         if ($off > 0) {
581                                 $off--;
582                                 next;
583                         }
584
585                         if ($c eq $close && $level > 0) {
586                                 $level--;
587                                 last if ($level == 0);
588                         } elsif ($c eq $open) {
589                                 $level++;
590                         }
591                 }
592
593                 if (!$outer || $level <= 1) {
594                         push(@res, $rawlines[$line]);
595                 }
596
597                 last if ($level == 0);
598         }
599
600         return ($level, @res);
601 }
602 sub ctx_block_outer {
603         my ($linenr, $remain) = @_;
604
605         my ($level, @r) = ctx_block_get($linenr, $remain, 1, '{', '}', 0);
606         return @r;
607 }
608 sub ctx_block {
609         my ($linenr, $remain) = @_;
610
611         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '{', '}', 0);
612         return @r;
613 }
614 sub ctx_statement {
615         my ($linenr, $remain, $off) = @_;
616
617         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '(', ')', $off);
618         return @r;
619 }
620 sub ctx_block_level {
621         my ($linenr, $remain) = @_;
622
623         return ctx_block_get($linenr, $remain, 0, '{', '}', 0);
624 }
625 sub ctx_statement_level {
626         my ($linenr, $remain, $off) = @_;
627
628         return ctx_block_get($linenr, $remain, 0, '(', ')', $off);
629 }
630
631 sub ctx_locate_comment {
632         my ($first_line, $end_line) = @_;
633
634         # Catch a comment on the end of the line itself.
635         my ($current_comment) = ($rawlines[$end_line - 1] =~ m@.*(/\*.*\*/)\s*(?:\\\s*)?$@);
636         return $current_comment if (defined $current_comment);
637
638         # Look through the context and try and figure out if there is a
639         # comment.
640         my $in_comment = 0;
641         $current_comment = '';
642         for (my $linenr = $first_line; $linenr < $end_line; $linenr++) {
643                 my $line = $rawlines[$linenr - 1];
644                 #warn "           $line\n";
645                 if ($linenr == $first_line and $line =~ m@^.\s*\*@) {
646                         $in_comment = 1;
647                 }
648                 if ($line =~ m@/\*@) {
649                         $in_comment = 1;
650                 }
651                 if (!$in_comment && $current_comment ne '') {
652                         $current_comment = '';
653                 }
654                 $current_comment .= $line . "\n" if ($in_comment);
655                 if ($line =~ m@\*/@) {
656                         $in_comment = 0;
657                 }
658         }
659
660         chomp($current_comment);
661         return($current_comment);
662 }
663 sub ctx_has_comment {
664         my ($first_line, $end_line) = @_;
665         my $cmt = ctx_locate_comment($first_line, $end_line);
666
667         ##print "LINE: $rawlines[$end_line - 1 ]\n";
668         ##print "CMMT: $cmt\n";
669
670         return ($cmt ne '');
671 }
672
673 sub cat_vet {
674         my ($vet) = @_;
675         my ($res, $coded);
676
677         $res = '';
678         while ($vet =~ /([^[:cntrl:]]*)([[:cntrl:]]|$)/g) {
679                 $res .= $1;
680                 if ($2 ne '') {
681                         $coded = sprintf("^%c", unpack('C', $2) + 64);
682                         $res .= $coded;
683                 }
684         }
685         $res =~ s/$/\$/;
686
687         return $res;
688 }
689
690 my $av_preprocessor = 0;
691 my $av_pending;
692 my @av_paren_type;
693 my $av_pend_colon;
694
695 sub annotate_reset {
696         $av_preprocessor = 0;
697         $av_pending = '_';
698         @av_paren_type = ('E');
699         $av_pend_colon = 'O';
700 }
701
702 sub annotate_values {
703         my ($stream, $type) = @_;
704
705         my $res;
706         my $var = '_' x length($stream);
707         my $cur = $stream;
708
709         print "$stream\n" if ($dbg_values > 1);
710
711         while (length($cur)) {
712                 @av_paren_type = ('E') if ($#av_paren_type < 0);
713                 print " <" . join('', @av_paren_type) .
714                                 "> <$type> <$av_pending>" if ($dbg_values > 1);
715                 if ($cur =~ /^(\s+)/o) {
716                         print "WS($1)\n" if ($dbg_values > 1);
717                         if ($1 =~ /\n/ && $av_preprocessor) {
718                                 $type = pop(@av_paren_type);
719                                 $av_preprocessor = 0;
720                         }
721
722                 } elsif ($cur =~ /^($Type)\s*(?:$Ident|,|\)|\()/) {
723                         print "DECLARE($1)\n" if ($dbg_values > 1);
724                         $type = 'T';
725
726                 } elsif ($cur =~ /^($Modifier)\s*/) {
727                         print "MODIFIER($1)\n" if ($dbg_values > 1);
728                         $type = 'T';
729
730                 } elsif ($cur =~ /^(\#\s*define\s*$Ident)(\(?)/o) {
731                         print "DEFINE($1,$2)\n" if ($dbg_values > 1);
732                         $av_preprocessor = 1;
733                         push(@av_paren_type, $type);
734                         if ($2 ne '') {
735                                 $av_pending = 'N';
736                         }
737                         $type = 'E';
738
739                 } elsif ($cur =~ /^(\#\s*(?:undef\s*$Ident|include\b))/o) {
740                         print "UNDEF($1)\n" if ($dbg_values > 1);
741                         $av_preprocessor = 1;
742                         push(@av_paren_type, $type);
743
744                 } elsif ($cur =~ /^(\#\s*(?:ifdef|ifndef|if))/o) {
745                         print "PRE_START($1)\n" if ($dbg_values > 1);
746                         $av_preprocessor = 1;
747
748                         push(@av_paren_type, $type);
749                         push(@av_paren_type, $type);
750                         $type = 'E';
751
752                 } elsif ($cur =~ /^(\#\s*(?:else|elif))/o) {
753                         print "PRE_RESTART($1)\n" if ($dbg_values > 1);
754                         $av_preprocessor = 1;
755
756                         push(@av_paren_type, $av_paren_type[$#av_paren_type]);
757
758                         $type = 'E';
759
760                 } elsif ($cur =~ /^(\#\s*(?:endif))/o) {
761                         print "PRE_END($1)\n" if ($dbg_values > 1);
762
763                         $av_preprocessor = 1;
764
765                         # Assume all arms of the conditional end as this
766                         # one does, and continue as if the #endif was not here.
767                         pop(@av_paren_type);
768                         push(@av_paren_type, $type);
769                         $type = 'E';
770
771                 } elsif ($cur =~ /^(\\\n)/o) {
772                         print "PRECONT($1)\n" if ($dbg_values > 1);
773
774                 } elsif ($cur =~ /^(__attribute__)\s*\(?/o) {
775                         print "ATTR($1)\n" if ($dbg_values > 1);
776                         $av_pending = $type;
777                         $type = 'N';
778
779                 } elsif ($cur =~ /^(sizeof)\s*(\()?/o) {
780                         print "SIZEOF($1)\n" if ($dbg_values > 1);
781                         if (defined $2) {
782                                 $av_pending = 'V';
783                         }
784                         $type = 'N';
785
786                 } elsif ($cur =~ /^(if|while|for)\b/o) {
787                         print "COND($1)\n" if ($dbg_values > 1);
788                         $av_pending = 'E';
789                         $type = 'N';
790
791                 } elsif ($cur =~/^(case)/o) {
792                         print "CASE($1)\n" if ($dbg_values > 1);
793                         $av_pend_colon = 'C';
794                         $type = 'N';
795
796                 } elsif ($cur =~/^(return|else|goto|typeof|__typeof__)\b/o) {
797                         print "KEYWORD($1)\n" if ($dbg_values > 1);
798                         $type = 'N';
799
800                 } elsif ($cur =~ /^(\()/o) {
801                         print "PAREN('$1')\n" if ($dbg_values > 1);
802                         push(@av_paren_type, $av_pending);
803                         $av_pending = '_';
804                         $type = 'N';
805
806                 } elsif ($cur =~ /^(\))/o) {
807                         my $new_type = pop(@av_paren_type);
808                         if ($new_type ne '_') {
809                                 $type = $new_type;
810                                 print "PAREN('$1') -> $type\n"
811                                                         if ($dbg_values > 1);
812                         } else {
813                                 print "PAREN('$1')\n" if ($dbg_values > 1);
814                         }
815
816                 } elsif ($cur =~ /^($Ident)\s*\(/o) {
817                         print "FUNC($1)\n" if ($dbg_values > 1);
818                         $type = 'V';
819                         $av_pending = 'V';
820
821                 } elsif ($cur =~ /^($Ident\s*):/) {
822                         if ($type eq 'E') {
823                                 $av_pend_colon = 'L';
824                         } elsif ($type eq 'T') {
825                                 $av_pend_colon = 'B';
826                         }
827                         print "IDENT_COLON($1,$type>$av_pend_colon)\n" if ($dbg_values > 1);
828                         $type = 'V';
829
830                 } elsif ($cur =~ /^($Ident|$Constant)/o) {
831                         print "IDENT($1)\n" if ($dbg_values > 1);
832                         $type = 'V';
833
834                 } elsif ($cur =~ /^($Assignment)/o) {
835                         print "ASSIGN($1)\n" if ($dbg_values > 1);
836                         $type = 'N';
837
838                 } elsif ($cur =~/^(;|{|})/) {
839                         print "END($1)\n" if ($dbg_values > 1);
840                         $type = 'E';
841                         $av_pend_colon = 'O';
842
843                 } elsif ($cur =~ /^(\?)/o) {
844                         print "QUESTION($1)\n" if ($dbg_values > 1);
845                         $type = 'N';
846
847                 } elsif ($cur =~ /^(:)/o) {
848                         print "COLON($1,$av_pend_colon)\n" if ($dbg_values > 1);
849
850                         substr($var, length($res), 1, $av_pend_colon);
851                         if ($av_pend_colon eq 'C' || $av_pend_colon eq 'L') {
852                                 $type = 'E';
853                         } else {
854                                 $type = 'N';
855                         }
856                         $av_pend_colon = 'O';
857
858                 } elsif ($cur =~ /^(;|\[)/o) {
859                         print "CLOSE($1)\n" if ($dbg_values > 1);
860                         $type = 'N';
861
862                 } elsif ($cur =~ /^(-(?![->])|\+(?!\+)|\*|\&\&|\&)/o) {
863                         my $variant;
864
865                         print "OPV($1)\n" if ($dbg_values > 1);
866                         if ($type eq 'V') {
867                                 $variant = 'B';
868                         } else {
869                                 $variant = 'U';
870                         }
871
872                         substr($var, length($res), 1, $variant);
873                         $type = 'N';
874
875                 } elsif ($cur =~ /^($Operators)/o) {
876                         print "OP($1)\n" if ($dbg_values > 1);
877                         if ($1 ne '++' && $1 ne '--') {
878                                 $type = 'N';
879                         }
880
881                 } elsif ($cur =~ /(^.)/o) {
882                         print "C($1)\n" if ($dbg_values > 1);
883                 }
884                 if (defined $1) {
885                         $cur = substr($cur, length($1));
886                         $res .= $type x length($1);
887                 }
888         }
889
890         return ($res, $var);
891 }
892
893 sub possible {
894         my ($possible, $line) = @_;
895
896         print "CHECK<$possible> ($line)\n" if ($dbg_possible > 1);
897         if ($possible !~ /^(?:$Modifier|$Storage|$Type|DEFINE_\S+)$/ &&
898             $possible ne 'goto' && $possible ne 'return' &&
899             $possible ne 'case' && $possible ne 'else' &&
900             $possible ne 'asm' && $possible ne '__asm__' &&
901             $possible !~ /^(typedef|struct|enum)\b/) {
902                 # Check for modifiers.
903                 $possible =~ s/\s*$Storage\s*//g;
904                 $possible =~ s/\s*$Sparse\s*//g;
905                 if ($possible =~ /^\s*$/) {
906
907                 } elsif ($possible =~ /\s/) {
908                         $possible =~ s/\s*$Type\s*//g;
909                         for my $modifier (split(' ', $possible)) {
910                                 warn "MODIFIER: $modifier ($possible) ($line)\n" if ($dbg_possible);
911                                 push(@modifierList, $modifier);
912                         }
913
914                 } else {
915                         warn "POSSIBLE: $possible ($line)\n" if ($dbg_possible);
916                         push(@typeList, $possible);
917                 }
918                 build_types();
919         }
920 }
921
922 my $prefix = '';
923
924 sub report {
925         if (defined $tst_only && $_[0] !~ /\Q$tst_only\E/) {
926                 return 0;
927         }
928         my $line = $prefix . $_[0];
929
930         $line = (split('\n', $line))[0] . "\n" if ($terse);
931
932         push(our @report, $line);
933
934         return 1;
935 }
936 sub report_dump {
937         our @report;
938 }
939 sub ERROR {
940         if (report("ERROR: $_[0]\n")) {
941                 our $clean = 0;
942                 our $cnt_error++;
943         }
944 }
945 sub WARN {
946         if (report("WARNING: $_[0]\n")) {
947                 our $clean = 0;
948                 our $cnt_warn++;
949         }
950 }
951 sub CHK {
952         if ($check && report("CHECK: $_[0]\n")) {
953                 our $clean = 0;
954                 our $cnt_chk++;
955         }
956 }
957
958 sub process {
959         my $filename = shift;
960
961         my $linenr=0;
962         my $prevline="";
963         my $prevrawline="";
964         my $stashline="";
965         my $stashrawline="";
966
967         my $length;
968         my $indent;
969         my $previndent=0;
970         my $stashindent=0;
971
972         our $clean = 1;
973         my $signoff = 0;
974         my $is_patch = 0;
975
976         our @report = ();
977         our $cnt_lines = 0;
978         our $cnt_error = 0;
979         our $cnt_warn = 0;
980         our $cnt_chk = 0;
981
982         # Trace the real file/line as we go.
983         my $realfile = '';
984         my $realline = 0;
985         my $realcnt = 0;
986         my $here = '';
987         my $in_comment = 0;
988         my $comment_edge = 0;
989         my $first_line = 0;
990
991         my $prev_values = 'E';
992
993         # suppression flags
994         my %suppress_ifbraces;
995
996         # Pre-scan the patch sanitizing the lines.
997         # Pre-scan the patch looking for any __setup documentation.
998         #
999         my @setup_docs = ();
1000         my $setup_docs = 0;
1001
1002         sanitise_line_reset();
1003         my $line;
1004         foreach my $rawline (@rawlines) {
1005                 $linenr++;
1006                 $line = $rawline;
1007
1008                 if ($rawline=~/^\+\+\+\s+(\S+)/) {
1009                         $setup_docs = 0;
1010                         if ($1 =~ m@Documentation/kernel-parameters.txt$@) {
1011                                 $setup_docs = 1;
1012                         }
1013                         #next;
1014                 }
1015                 if ($rawline=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1016                         $realline=$1-1;
1017                         if (defined $2) {
1018                                 $realcnt=$3+1;
1019                         } else {
1020                                 $realcnt=1+1;
1021                         }
1022                         $in_comment = 0;
1023
1024                         # Guestimate if this is a continuing comment.  Run
1025                         # the context looking for a comment "edge".  If this
1026                         # edge is a close comment then we must be in a comment
1027                         # at context start.
1028                         my $edge;
1029                         for (my $ln = $linenr + 1; $ln < ($linenr + $realcnt); $ln++) {
1030                                 next if ($line =~ /^-/);
1031                                 ($edge) = ($rawlines[$ln - 1] =~ m@(/\*|\*/)@);
1032                                 last if (defined $edge);
1033                         }
1034                         if (defined $edge && $edge eq '*/') {
1035                                 $in_comment = 1;
1036                         }
1037
1038                         # Guestimate if this is a continuing comment.  If this
1039                         # is the start of a diff block and this line starts
1040                         # ' *' then it is very likely a comment.
1041                         if (!defined $edge &&
1042                             $rawlines[$linenr] =~ m@^.\s* \*(?:\s|$)@)
1043                         {
1044                                 $in_comment = 1;
1045                         }
1046
1047                         ##print "COMMENT:$in_comment edge<$edge> $rawline\n";
1048                         sanitise_line_reset($in_comment);
1049
1050                 } elsif ($realcnt && $rawline =~ /^(?:\+| |$)/) {
1051                         # Standardise the strings and chars within the input to
1052                         # simplify matching -- only bother with positive lines.
1053                         $line = sanitise_line($rawline);
1054                 }
1055                 push(@lines, $line);
1056
1057                 if ($realcnt > 1) {
1058                         $realcnt-- if ($line =~ /^(?:\+| |$)/);
1059                 } else {
1060                         $realcnt = 0;
1061                 }
1062
1063                 #print "==>$rawline\n";
1064                 #print "-->$line\n";
1065
1066                 if ($setup_docs && $line =~ /^\+/) {
1067                         push(@setup_docs, $line);
1068                 }
1069         }
1070
1071         $prefix = '';
1072
1073         $realcnt = 0;
1074         $linenr = 0;
1075         foreach my $line (@lines) {
1076                 $linenr++;
1077
1078                 my $rawline = $rawlines[$linenr - 1];
1079
1080 #extract the line range in the file after the patch is applied
1081                 if ($line=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1082                         $is_patch = 1;
1083                         $first_line = $linenr + 1;
1084                         $realline=$1-1;
1085                         if (defined $2) {
1086                                 $realcnt=$3+1;
1087                         } else {
1088                                 $realcnt=1+1;
1089                         }
1090                         annotate_reset();
1091                         $prev_values = 'E';
1092
1093                         %suppress_ifbraces = ();
1094                         next;
1095
1096 # track the line number as we move through the hunk, note that
1097 # new versions of GNU diff omit the leading space on completely
1098 # blank context lines so we need to count that too.
1099                 } elsif ($line =~ /^( |\+|$)/) {
1100                         $realline++;
1101                         $realcnt-- if ($realcnt != 0);
1102
1103                         # Measure the line length and indent.
1104                         ($length, $indent) = line_stats($rawline);
1105
1106                         # Track the previous line.
1107                         ($prevline, $stashline) = ($stashline, $line);
1108                         ($previndent, $stashindent) = ($stashindent, $indent);
1109                         ($prevrawline, $stashrawline) = ($stashrawline, $rawline);
1110
1111                         #warn "line<$line>\n";
1112
1113                 } elsif ($realcnt == 1) {
1114                         $realcnt--;
1115                 }
1116
1117 #make up the handle for any error we report on this line
1118                 $prefix = "$filename:$realline: " if ($emacs && $file);
1119                 $prefix = "$filename:$linenr: " if ($emacs && !$file);
1120
1121                 $here = "#$linenr: " if (!$file);
1122                 $here = "#$realline: " if ($file);
1123
1124                 # extract the filename as it passes
1125                 if ($line=~/^\+\+\+\s+(\S+)/) {
1126                         $realfile = $1;
1127                         $realfile =~ s@^[^/]*/@@;
1128
1129                         if ($realfile =~ m@include/asm/@) {
1130                                 ERROR("do not modify files in include/asm, change architecture specific files in include/asm-<architecture>\n" . "$here$rawline\n");
1131                         }
1132                         next;
1133                 }
1134
1135                 $here .= "FILE: $realfile:$realline:" if ($realcnt != 0);
1136
1137                 my $hereline = "$here\n$rawline\n";
1138                 my $herecurr = "$here\n$rawline\n";
1139                 my $hereprev = "$here\n$prevrawline\n$rawline\n";
1140
1141                 $cnt_lines++ if ($realcnt != 0);
1142
1143 #check the patch for a signoff:
1144                 if ($line =~ /^\s*signed-off-by:/i) {
1145                         # This is a signoff, if ugly, so do not double report.
1146                         $signoff++;
1147                         if (!($line =~ /^\s*Signed-off-by:/)) {
1148                                 WARN("Signed-off-by: is the preferred form\n" .
1149                                         $herecurr);
1150                         }
1151                         if ($line =~ /^\s*signed-off-by:\S/i) {
1152                                 WARN("space required after Signed-off-by:\n" .
1153                                         $herecurr);
1154                         }
1155                 }
1156
1157 # Check for wrappage within a valid hunk of the file
1158                 if ($realcnt != 0 && $line !~ m{^(?:\+|-| |\\ No newline|$)}) {
1159                         ERROR("patch seems to be corrupt (line wrapped?)\n" .
1160                                 $herecurr) if (!$emitted_corrupt++);
1161                 }
1162
1163 # UTF-8 regex found at http://www.w3.org/International/questions/qa-forms-utf-8.en.php
1164                 if (($realfile =~ /^$/ || $line =~ /^\+/) &&
1165                     $rawline !~ m/^$UTF8*$/) {
1166                         my ($utf8_prefix) = ($rawline =~ /^($UTF8*)/);
1167
1168                         my $blank = copy_spacing($rawline);
1169                         my $ptr = substr($blank, 0, length($utf8_prefix)) . "^";
1170                         my $hereptr = "$hereline$ptr\n";
1171
1172                         ERROR("Invalid UTF-8, patch and commit message should be encoded in UTF-8\n" . $hereptr);
1173                 }
1174
1175 #ignore lines being removed
1176                 if ($line=~/^-/) {next;}
1177
1178 # check we are in a valid source file if not then ignore this hunk
1179                 next if ($realfile !~ /\.(h|c|s|S|pl|sh)$/);
1180
1181 #trailing whitespace
1182                 if ($line =~ /^\+.*\015/) {
1183                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1184                         ERROR("DOS line endings\n" . $herevet);
1185
1186                 } elsif ($rawline =~ /^\+.*\S\s+$/ || $rawline =~ /^\+\s+$/) {
1187                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1188                         ERROR("trailing whitespace\n" . $herevet);
1189                 }
1190 #80 column limit
1191                 if ($line =~ /^\+/ && $prevrawline !~ /\/\*\*/ &&
1192                     $rawline !~ /^.\s*\*\s*\@$Ident\s/ &&
1193                     $line !~ /^\+\s*printk\s*\(\s*(?:KERN_\S+\s*)?"[X\t]*"\s*(?:,|\)\s*;)\s*$/ &&
1194                     $length > 80)
1195                 {
1196                         WARN("line over 80 characters\n" . $herecurr);
1197                 }
1198
1199 # check for adding lines without a newline.
1200                 if ($line =~ /^\+/ && defined $lines[$linenr] && $lines[$linenr] =~ /^\\ No newline at end of file/) {
1201                         WARN("adding a line without newline at end of file\n" . $herecurr);
1202                 }
1203
1204 # check we are in a valid source file *.[hc] if not then ignore this hunk
1205                 next if ($realfile !~ /\.[hc]$/);
1206
1207 # at the beginning of a line any tabs must come first and anything
1208 # more than 8 must use tabs.
1209                 if ($rawline =~ /^\+\s* \t\s*\S/ ||
1210                     $rawline =~ /^\+\s*        \s*/) {
1211                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1212                         ERROR("code indent should use tabs where possible\n" . $herevet);
1213                 }
1214
1215 # check for RCS/CVS revision markers
1216                 if ($rawline =~ /^\+.*\$(Revision|Log|Id)(?:\$|)/) {
1217                         WARN("CVS style keyword markers, these will _not_ be updated\n". $herecurr);
1218                 }
1219
1220 # Check for potential 'bare' types
1221                 my ($stat, $cond, $line_nr_next, $remain_next);
1222                 if ($realcnt && $line =~ /.\s*\S/) {
1223                         ($stat, $cond, $line_nr_next, $remain_next) =
1224                                 ctx_statement_block($linenr, $realcnt, 0);
1225                         $stat =~ s/\n./\n /g;
1226                         $cond =~ s/\n./\n /g;
1227
1228                         my $s = $stat;
1229                         $s =~ s/{.*$//s;
1230
1231                         # Ignore goto labels.
1232                         if ($s =~ /$Ident:\*$/s) {
1233
1234                         # Ignore functions being called
1235                         } elsif ($s =~ /^.\s*$Ident\s*\(/s) {
1236
1237                         # declarations always start with types
1238                         } elsif ($prev_values eq 'E' && $s =~ /^.\s*(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?((?:\s*$Ident)+?)\b(?:\s+$Sparse)?\s*\**\s*(?:$Ident|\(\*[^\)]*\))(?:\s*$Modifier)?\s*(?:;|=|,|\()/s) {
1239                                 my $type = $1;
1240                                 $type =~ s/\s+/ /g;
1241                                 possible($type, "A:" . $s);
1242
1243                         # definitions in global scope can only start with types
1244                         } elsif ($s =~ /^.(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?($Ident)\b/s) {
1245                                 possible($1, "B:" . $s);
1246                         }
1247
1248                         # any (foo ... *) is a pointer cast, and foo is a type
1249                         while ($s =~ /\(($Ident)(?:\s+$Sparse)*\s*\*+\s*\)/sg) {
1250                                 possible($1, "C:" . $s);
1251                         }
1252
1253                         # Check for any sort of function declaration.
1254                         # int foo(something bar, other baz);
1255                         # void (*store_gdt)(x86_descr_ptr *);
1256                         if ($prev_values eq 'E' && $s =~ /^(.(?:typedef\s*)?(?:(?:$Storage|$Inline)\s*)*\s*$Type\s*(?:\b$Ident|\(\*\s*$Ident\))\s*)\(/s) {
1257                                 my ($name_len) = length($1);
1258
1259                                 my $ctx = $s;
1260                                 substr($ctx, 0, $name_len + 1, '');
1261                                 $ctx =~ s/\)[^\)]*$//;
1262
1263                                 for my $arg (split(/\s*,\s*/, $ctx)) {
1264                                         if ($arg =~ /^(?:const\s+)?($Ident)(?:\s+$Sparse)*\s*\**\s*(:?\b$Ident)?$/s || $arg =~ /^($Ident)$/s) {
1265
1266                                                 possible($1, "D:" . $s);
1267                                         }
1268                                 }
1269                         }
1270
1271                 }
1272
1273 #
1274 # Checks which may be anchored in the context.
1275 #
1276
1277 # Check for switch () and associated case and default
1278 # statements should be at the same indent.
1279                 if ($line=~/\bswitch\s*\(.*\)/) {
1280                         my $err = '';
1281                         my $sep = '';
1282                         my @ctx = ctx_block_outer($linenr, $realcnt);
1283                         shift(@ctx);
1284                         for my $ctx (@ctx) {
1285                                 my ($clen, $cindent) = line_stats($ctx);
1286                                 if ($ctx =~ /^\+\s*(case\s+|default:)/ &&
1287                                                         $indent != $cindent) {
1288                                         $err .= "$sep$ctx\n";
1289                                         $sep = '';
1290                                 } else {
1291                                         $sep = "[...]\n";
1292                                 }
1293                         }
1294                         if ($err ne '') {
1295                                 ERROR("switch and case should be at the same indent\n$hereline$err");
1296                         }
1297                 }
1298                 if ($line =~ /^.\s*(?:case\s*.*|default\s*):/g &&
1299                     $line !~ /\G(?:
1300                         (?:\s*{)?(?:\s*$;*)(?:\s*\\)?\s*$|
1301                         \s*return\s+
1302                     )/xg)
1303                 {
1304                         ERROR("trailing statements should be on next line\n" . $herecurr);
1305                 }
1306
1307 # if/while/etc brace do not go on next line, unless defining a do while loop,
1308 # or if that brace on the next line is for something else
1309                 if ($line =~ /(.*)\b((?:if|while|for|switch)\s*\(|do\b|else\b)/ && $line !~ /^.\s*\#/) {
1310                         my $pre_ctx = "$1$2";
1311
1312                         my ($level, @ctx) = ctx_statement_level($linenr, $realcnt, 0);
1313                         my $ctx_cnt = $realcnt - $#ctx - 1;
1314                         my $ctx = join("\n", @ctx);
1315
1316                         my $ctx_ln = $linenr;
1317                         my $ctx_skip = $realcnt;
1318
1319                         while ($ctx_skip > $ctx_cnt || ($ctx_skip == $ctx_cnt &&
1320                                         defined $lines[$ctx_ln - 1] &&
1321                                         $lines[$ctx_ln - 1] =~ /^-/)) {
1322                                 ##print "SKIP<$ctx_skip> CNT<$ctx_cnt>\n";
1323                                 $ctx_skip-- if (!defined $lines[$ctx_ln - 1] || $lines[$ctx_ln - 1] !~ /^-/);
1324                                 $ctx_ln++;
1325                         }
1326
1327                         #print "realcnt<$realcnt> ctx_cnt<$ctx_cnt>\n";
1328                         #print "pre<$pre_ctx>\nline<$line>\nctx<$ctx>\nnext<$lines[$ctx_ln - 1]>\n";
1329
1330                         if ($ctx !~ /{\s*/ && defined($lines[$ctx_ln -1]) && $lines[$ctx_ln - 1] =~ /^\+\s*{/) {
1331                                 ERROR("that open brace { should be on the previous line\n" .
1332                                         "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1333                         }
1334                         if ($level == 0 && $pre_ctx !~ /}\s*while\s*\($/ &&
1335                             $ctx =~ /\)\s*\;\s*$/ &&
1336                             defined $lines[$ctx_ln - 1])
1337                         {
1338                                 my ($nlength, $nindent) = line_stats($lines[$ctx_ln - 1]);
1339                                 if ($nindent > $indent) {
1340                                         WARN("trailing semicolon indicates no statements, indent implies otherwise\n" .
1341                                                 "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1342                                 }
1343                         }
1344                 }
1345
1346                 # Track the 'values' across context and added lines.
1347                 my $opline = $line; $opline =~ s/^./ /;
1348                 my ($curr_values, $curr_vars) =
1349                                 annotate_values($opline . "\n", $prev_values);
1350                 $curr_values = $prev_values . $curr_values;
1351                 if ($dbg_values) {
1352                         my $outline = $opline; $outline =~ s/\t/ /g;
1353                         print "$linenr > .$outline\n";
1354                         print "$linenr > $curr_values\n";
1355                         print "$linenr >  $curr_vars\n";
1356                 }
1357                 $prev_values = substr($curr_values, -1);
1358
1359 #ignore lines not being added
1360                 if ($line=~/^[^\+]/) {next;}
1361
1362 # TEST: allow direct testing of the type matcher.
1363                 if ($dbg_type) {
1364                         if ($line =~ /^.\s*$Declare\s*$/) {
1365                                 ERROR("TEST: is type\n" . $herecurr);
1366                         } elsif ($dbg_type > 1 && $line =~ /^.+($Declare)/) {
1367                                 ERROR("TEST: is not type ($1 is)\n". $herecurr);
1368                         }
1369                         next;
1370                 }
1371 # TEST: allow direct testing of the attribute matcher.
1372                 if ($dbg_attr) {
1373                         if ($line =~ /^.\s*$Attribute\s*$/) {
1374                                 ERROR("TEST: is attr\n" . $herecurr);
1375                         } elsif ($dbg_attr > 1 && $line =~ /^.+($Attribute)/) {
1376                                 ERROR("TEST: is not attr ($1 is)\n". $herecurr);
1377                         }
1378                         next;
1379                 }
1380
1381 # check for initialisation to aggregates open brace on the next line
1382                 if ($prevline =~ /$Declare\s*$Ident\s*=\s*$/ &&
1383                     $line =~ /^.\s*{/) {
1384                         ERROR("that open brace { should be on the previous line\n" . $hereprev);
1385                 }
1386
1387 #
1388 # Checks which are anchored on the added line.
1389 #
1390
1391 # check for malformed paths in #include statements (uses RAW line)
1392                 if ($rawline =~ m{^.\s*\#\s*include\s+[<"](.*)[">]}) {
1393                         my $path = $1;
1394                         if ($path =~ m{//}) {
1395                                 ERROR("malformed #include filename\n" .
1396                                         $herecurr);
1397                         }
1398                 }
1399
1400 # no C99 // comments
1401                 if ($line =~ m{//}) {
1402                         ERROR("do not use C99 // comments\n" . $herecurr);
1403                 }
1404                 # Remove C99 comments.
1405                 $line =~ s@//.*@@;
1406                 $opline =~ s@//.*@@;
1407
1408 #EXPORT_SYMBOL should immediately follow its function closing }.
1409                 if (($line =~ /EXPORT_SYMBOL.*\((.*)\)/) ||
1410                     ($line =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
1411                         my $name = $1;
1412                         if (($prevline !~ /^}/) &&
1413                            ($prevline !~ /^\+}/) &&
1414                            ($prevline !~ /^ }/) &&
1415                            ($prevline !~ /^.DECLARE_$Ident\(\Q$name\E\)/) &&
1416                            ($prevline !~ /^.LIST_HEAD\(\Q$name\E\)/) &&
1417                            ($prevline !~ /^.$Type\s*\(\s*\*\s*\Q$name\E\s*\)\s*\(/) &&
1418                            ($prevline !~ /\b\Q$name\E(?:\s+$Attribute)?\s*(?:;|=|\[)/)) {
1419                                 WARN("EXPORT_SYMBOL(foo); should immediately follow its function/variable\n" . $herecurr);
1420                         }
1421                 }
1422
1423 # check for external initialisers.
1424                 if ($line =~ /^.$Type\s*$Ident\s*(?:\s+$Modifier)*\s*=\s*(0|NULL|false)\s*;/) {
1425                         ERROR("do not initialise externals to 0 or NULL\n" .
1426                                 $herecurr);
1427                 }
1428 # check for static initialisers.
1429                 if ($line =~ /\s*static\s.*=\s*(0|NULL|false)\s*;/) {
1430                         ERROR("do not initialise statics to 0 or NULL\n" .
1431                                 $herecurr);
1432                 }
1433
1434 # check for new typedefs, only function parameters and sparse annotations
1435 # make sense.
1436                 if ($line =~ /\btypedef\s/ &&
1437                     $line !~ /\btypedef\s+$Type\s+\(\s*\*?$Ident\s*\)\s*\(/ &&
1438                     $line !~ /\btypedef\s+$Type\s+$Ident\s*\(/ &&
1439                     $line !~ /\b__bitwise(?:__|)\b/) {
1440                         WARN("do not add new typedefs\n" . $herecurr);
1441                 }
1442
1443 # * goes on variable not on type
1444                 if ($line =~ m{\($NonptrType(\*+)(?:\s+const)?\)}) {
1445                         ERROR("\"(foo$1)\" should be \"(foo $1)\"\n" .
1446                                 $herecurr);
1447
1448                 } elsif ($line =~ m{\($NonptrType\s+(\*+)(?!\s+const)\s+\)}) {
1449                         ERROR("\"(foo $1 )\" should be \"(foo $1)\"\n" .
1450                                 $herecurr);
1451
1452                 } elsif ($line =~ m{\b$NonptrType(\*+)(?:\s+(?:$Attribute|$Sparse))?\s+[A-Za-z\d_]+}) {
1453                         ERROR("\"foo$1 bar\" should be \"foo $1bar\"\n" .
1454                                 $herecurr);
1455
1456                 } elsif ($line =~ m{\b$NonptrType\s+(\*+)(?!\s+(?:$Attribute|$Sparse))\s+[A-Za-z\d_]+}) {
1457                         ERROR("\"foo $1 bar\" should be \"foo $1bar\"\n" .
1458                                 $herecurr);
1459                 }
1460
1461 # # no BUG() or BUG_ON()
1462 #               if ($line =~ /\b(BUG|BUG_ON)\b/) {
1463 #                       print "Try to use WARN_ON & Recovery code rather than BUG() or BUG_ON()\n";
1464 #                       print "$herecurr";
1465 #                       $clean = 0;
1466 #               }
1467
1468                 if ($line =~ /\bLINUX_VERSION_CODE\b/) {
1469                         WARN("LINUX_VERSION_CODE should be avoided, code should be for the version to which it is merged\n" . $herecurr);
1470                 }
1471
1472 # printk should use KERN_* levels.  Note that follow on printk's on the
1473 # same line do not need a level, so we use the current block context
1474 # to try and find and validate the current printk.  In summary the current
1475 # printk includes all preceeding printk's which have no newline on the end.
1476 # we assume the first bad printk is the one to report.
1477                 if ($line =~ /\bprintk\((?!KERN_)\s*"/) {
1478                         my $ok = 0;
1479                         for (my $ln = $linenr - 1; $ln >= $first_line; $ln--) {
1480                                 #print "CHECK<$lines[$ln - 1]\n";
1481                                 # we have a preceeding printk if it ends
1482                                 # with "\n" ignore it, else it is to blame
1483                                 if ($lines[$ln - 1] =~ m{\bprintk\(}) {
1484                                         if ($rawlines[$ln - 1] !~ m{\\n"}) {
1485                                                 $ok = 1;
1486                                         }
1487                                         last;
1488                                 }
1489                         }
1490                         if ($ok == 0) {
1491                                 WARN("printk() should include KERN_ facility level\n" . $herecurr);
1492                         }
1493                 }
1494
1495 # function brace can't be on same line, except for #defines of do while,
1496 # or if closed on same line
1497                 if (($line=~/$Type\s*$Ident\(.*\).*\s{/) and
1498                     !($line=~/\#\s*define.*do\s{/) and !($line=~/}/)) {
1499                         ERROR("open brace '{' following function declarations go on the next line\n" . $herecurr);
1500                 }
1501
1502 # open braces for enum, union and struct go on the same line.
1503                 if ($line =~ /^.\s*{/ &&
1504                     $prevline =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?\s*$/) {
1505                         ERROR("open brace '{' following $1 go on the same line\n" . $hereprev);
1506                 }
1507
1508 # check for spacing round square brackets; allowed:
1509 #  1. with a type on the left -- int [] a;
1510 #  2. at the beginning of a line for slice initialisers -- [0...10] = 5,
1511 #  3. inside a curly brace -- = { [0...10] = 5 }
1512                 while ($line =~ /(.*?\s)\[/g) {
1513                         my ($where, $prefix) = ($-[1], $1);
1514                         if ($prefix !~ /$Type\s+$/ &&
1515                             ($where != 0 || $prefix !~ /^.\s+$/) &&
1516                             $prefix !~ /{\s+$/) {
1517                                 ERROR("space prohibited before open square bracket '['\n" . $herecurr);
1518                         }
1519                 }
1520
1521 # check for spaces between functions and their parentheses.
1522                 while ($line =~ /($Ident)\s+\(/g) {
1523                         my $name = $1;
1524                         my $ctx_before = substr($line, 0, $-[1]);
1525                         my $ctx = "$ctx_before$name";
1526
1527                         # Ignore those directives where spaces _are_ permitted.
1528                         if ($name =~ /^(?:
1529                                 if|for|while|switch|return|case|
1530                                 volatile|__volatile__|
1531                                 __attribute__|format|__extension__|
1532                                 asm|__asm__)$/x)
1533                         {
1534
1535                         # cpp #define statements have non-optional spaces, ie
1536                         # if there is a space between the name and the open
1537                         # parenthesis it is simply not a parameter group.
1538                         } elsif ($ctx_before =~ /^.\s*\#\s*define\s*$/) {
1539
1540                         # cpp #elif statement condition may start with a (
1541                         } elsif ($ctx =~ /^.\s*\#\s*elif\s*$/) {
1542
1543                         # If this whole things ends with a type its most
1544                         # likely a typedef for a function.
1545                         } elsif ($ctx =~ /$Type$/) {
1546
1547                         } else {
1548                                 WARN("space prohibited between function name and open parenthesis '('\n" . $herecurr);
1549                         }
1550                 }
1551 # Check operator spacing.
1552                 if (!($line=~/\#\s*include/)) {
1553                         my $ops = qr{
1554                                 <<=|>>=|<=|>=|==|!=|
1555                                 \+=|-=|\*=|\/=|%=|\^=|\|=|&=|
1556                                 =>|->|<<|>>|<|>|=|!|~|
1557                                 &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%|
1558                                 \?|:
1559                         }x;
1560                         my @elements = split(/($ops|;)/, $opline);
1561                         my $off = 0;
1562
1563                         my $blank = copy_spacing($opline);
1564
1565                         for (my $n = 0; $n < $#elements; $n += 2) {
1566                                 $off += length($elements[$n]);
1567
1568                                 # Pick up the preceeding and succeeding characters.
1569                                 my $ca = substr($opline, 0, $off);
1570                                 my $cc = '';
1571                                 if (length($opline) >= ($off + length($elements[$n + 1]))) {
1572                                         $cc = substr($opline, $off + length($elements[$n + 1]));
1573                                 }
1574                                 my $cb = "$ca$;$cc";
1575
1576                                 my $a = '';
1577                                 $a = 'V' if ($elements[$n] ne '');
1578                                 $a = 'W' if ($elements[$n] =~ /\s$/);
1579                                 $a = 'C' if ($elements[$n] =~ /$;$/);
1580                                 $a = 'B' if ($elements[$n] =~ /(\[|\()$/);
1581                                 $a = 'O' if ($elements[$n] eq '');
1582                                 $a = 'E' if ($ca =~ /^\s*$/);
1583
1584                                 my $op = $elements[$n + 1];
1585
1586                                 my $c = '';
1587                                 if (defined $elements[$n + 2]) {
1588                                         $c = 'V' if ($elements[$n + 2] ne '');
1589                                         $c = 'W' if ($elements[$n + 2] =~ /^\s/);
1590                                         $c = 'C' if ($elements[$n + 2] =~ /^$;/);
1591                                         $c = 'B' if ($elements[$n + 2] =~ /^(\)|\]|;)/);
1592                                         $c = 'O' if ($elements[$n + 2] eq '');
1593                                         $c = 'E' if ($elements[$n + 2] =~ /\s*\\$/);
1594                                 } else {
1595                                         $c = 'E';
1596                                 }
1597
1598                                 my $ctx = "${a}x${c}";
1599
1600                                 my $at = "(ctx:$ctx)";
1601
1602                                 my $ptr = substr($blank, 0, $off) . "^";
1603                                 my $hereptr = "$hereline$ptr\n";
1604
1605                                 # Pull out the value of this operator.
1606                                 my $op_type = substr($curr_values, $off + 1, 1);
1607
1608                                 # Get the full operator variant.
1609                                 my $opv = $op . substr($curr_vars, $off, 1);
1610
1611                                 # Ignore operators passed as parameters.
1612                                 if ($op_type ne 'V' &&
1613                                     $ca =~ /\s$/ && $cc =~ /^\s*,/) {
1614
1615 #                               # Ignore comments
1616 #                               } elsif ($op =~ /^$;+$/) {
1617
1618                                 # ; should have either the end of line or a space or \ after it
1619                                 } elsif ($op eq ';') {
1620                                         if ($ctx !~ /.x[WEBC]/ &&
1621                                             $cc !~ /^\\/ && $cc !~ /^;/) {
1622                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1623                                         }
1624
1625                                 # // is a comment
1626                                 } elsif ($op eq '//') {
1627
1628                                 # No spaces for:
1629                                 #   ->
1630                                 #   :   when part of a bitfield
1631                                 } elsif ($op eq '->' || $opv eq ':B') {
1632                                         if ($ctx =~ /Wx.|.xW/) {
1633                                                 ERROR("spaces prohibited around that '$op' $at\n" . $hereptr);
1634                                         }
1635
1636                                 # , must have a space on the right.
1637                                 } elsif ($op eq ',') {
1638                                         if ($ctx !~ /.x[WEC]/ && $cc !~ /^}/) {
1639                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1640                                         }
1641
1642                                 # '*' as part of a type definition -- reported already.
1643                                 } elsif ($opv eq '*_') {
1644                                         #warn "'*' is part of type\n";
1645
1646                                 # unary operators should have a space before and
1647                                 # none after.  May be left adjacent to another
1648                                 # unary operator, or a cast
1649                                 } elsif ($op eq '!' || $op eq '~' ||
1650                                          $opv eq '*U' || $opv eq '-U' ||
1651                                          $opv eq '&U' || $opv eq '&&U') {
1652                                         if ($ctx !~ /[WEBC]x./ && $ca !~ /(?:\)|!|~|\*|-|\&|\||\+\+|\-\-|\{)$/) {
1653                                                 ERROR("space required before that '$op' $at\n" . $hereptr);
1654                                         }
1655                                         if ($op eq '*' && $cc =~/\s*const\b/) {
1656                                                 # A unary '*' may be const
1657
1658                                         } elsif ($ctx =~ /.xW/) {
1659                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1660                                         }
1661
1662                                 # unary ++ and unary -- are allowed no space on one side.
1663                                 } elsif ($op eq '++' or $op eq '--') {
1664                                         if ($ctx !~ /[WEOBC]x[^W]/ && $ctx !~ /[^W]x[WOBEC]/) {
1665                                                 ERROR("space required one side of that '$op' $at\n" . $hereptr);
1666                                         }
1667                                         if ($ctx =~ /Wx[BE]/ ||
1668                                             ($ctx =~ /Wx./ && $cc =~ /^;/)) {
1669                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
1670                                         }
1671                                         if ($ctx =~ /ExW/) {
1672                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1673                                         }
1674
1675
1676                                 # << and >> may either have or not have spaces both sides
1677                                 } elsif ($op eq '<<' or $op eq '>>' or
1678                                          $op eq '&' or $op eq '^' or $op eq '|' or
1679                                          $op eq '+' or $op eq '-' or
1680                                          $op eq '*' or $op eq '/' or
1681                                          $op eq '%')
1682                                 {
1683                                         if ($ctx =~ /Wx[^WCE]|[^WCE]xW/) {
1684                                                 ERROR("need consistent spacing around '$op' $at\n" .
1685                                                         $hereptr);
1686                                         }
1687
1688                                 # A colon needs no spaces before when it is
1689                                 # terminating a case value or a label.
1690                                 } elsif ($opv eq ':C' || $opv eq ':L') {
1691                                         if ($ctx =~ /Wx./) {
1692                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
1693                                         }
1694
1695                                 # All the others need spaces both sides.
1696                                 } elsif ($ctx !~ /[EWC]x[CWE]/) {
1697                                         my $ok = 0;
1698
1699                                         # Ignore email addresses <foo@bar>
1700                                         if (($op eq '<' &&
1701                                              $cc =~ /^\S+\@\S+>/) ||
1702                                             ($op eq '>' &&
1703                                              $ca =~ /<\S+\@\S+$/))
1704                                         {
1705                                                 $ok = 1;
1706                                         }
1707
1708                                         # Ignore ?:
1709                                         if (($opv eq ':O' && $ca =~ /\?$/) ||
1710                                             ($op eq '?' && $cc =~ /^:/)) {
1711                                                 $ok = 1;
1712                                         }
1713
1714                                         if ($ok == 0) {
1715                                                 ERROR("spaces required around that '$op' $at\n" . $hereptr);
1716                                         }
1717                                 }
1718                                 $off += length($elements[$n + 1]);
1719                         }
1720                 }
1721
1722 # check for multiple assignments
1723                 if ($line =~ /^.\s*$Lval\s*=\s*$Lval\s*=(?!=)/) {
1724                         CHK("multiple assignments should be avoided\n" . $herecurr);
1725                 }
1726
1727 ## # check for multiple declarations, allowing for a function declaration
1728 ## # continuation.
1729 ##              if ($line =~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Ident.*/ &&
1730 ##                  $line !~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Type\s*$Ident.*/) {
1731 ##
1732 ##                      # Remove any bracketed sections to ensure we do not
1733 ##                      # falsly report the parameters of functions.
1734 ##                      my $ln = $line;
1735 ##                      while ($ln =~ s/\([^\(\)]*\)//g) {
1736 ##                      }
1737 ##                      if ($ln =~ /,/) {
1738 ##                              WARN("declaring multiple variables together should be avoided\n" . $herecurr);
1739 ##                      }
1740 ##              }
1741
1742 #need space before brace following if, while, etc
1743                 if (($line =~ /\(.*\){/ && $line !~ /\($Type\){/) ||
1744                     $line =~ /do{/) {
1745                         ERROR("space required before the open brace '{'\n" . $herecurr);
1746                 }
1747
1748 # closing brace should have a space following it when it has anything
1749 # on the line
1750                 if ($line =~ /}(?!(?:,|;|\)))\S/) {
1751                         ERROR("space required after that close brace '}'\n" . $herecurr);
1752                 }
1753
1754 # check spacing on square brackets
1755                 if ($line =~ /\[\s/ && $line !~ /\[\s*$/) {
1756                         ERROR("space prohibited after that open square bracket '['\n" . $herecurr);
1757                 }
1758                 if ($line =~ /\s\]/) {
1759                         ERROR("space prohibited before that close square bracket ']'\n" . $herecurr);
1760                 }
1761
1762 # check spacing on parentheses
1763                 if ($line =~ /\(\s/ && $line !~ /\(\s*(?:\\)?$/ &&
1764                     $line !~ /for\s*\(\s+;/) {
1765                         ERROR("space prohibited after that open parenthesis '('\n" . $herecurr);
1766                 }
1767                 if ($line =~ /(\s+)\)/ && $line !~ /^.\s*\)/ &&
1768                     $line !~ /for\s*\(.*;\s+\)/ &&
1769                     $line !~ /:\s+\)/) {
1770                         ERROR("space prohibited before that close parenthesis ')'\n" . $herecurr);
1771                 }
1772
1773 #goto labels aren't indented, allow a single space however
1774                 if ($line=~/^.\s+[A-Za-z\d_]+:(?![0-9]+)/ and
1775                    !($line=~/^. [A-Za-z\d_]+:/) and !($line=~/^.\s+default:/)) {
1776                         WARN("labels should not be indented\n" . $herecurr);
1777                 }
1778
1779 # Return is not a function.
1780                 if (defined($stat) && $stat =~ /^.\s*return(\s*)(\(.*);/s) {
1781                         my $spacing = $1;
1782                         my $value = $2;
1783
1784                         # Flatten any parentheses and braces
1785                         $value =~ s/\)\(/\) \(/g;
1786                         while ($value =~ s/\([^\(\)]*\)/1/) {
1787                         }
1788
1789                         if ($value =~ /^(?:$Ident|-?$Constant)$/) {
1790                                 ERROR("return is not a function, parentheses are not required\n" . $herecurr);
1791
1792                         } elsif ($spacing !~ /\s+/) {
1793                                 ERROR("space required before the open parenthesis '('\n" . $herecurr);
1794                         }
1795                 }
1796
1797 # Need a space before open parenthesis after if, while etc
1798                 if ($line=~/\b(if|while|for|switch)\(/) {
1799                         ERROR("space required before the open parenthesis '('\n" . $herecurr);
1800                 }
1801
1802 # Check for illegal assignment in if conditional -- and check for trailing
1803 # statements after the conditional.
1804                 if ($line =~ /\b(?:if|while|for)\s*\(/ && $line !~ /^.\s*#/) {
1805                         my ($s, $c) = ($stat, $cond);
1806
1807                         if ($c =~ /\bif\s*\(.*[^<>!=]=[^=].*/) {
1808                                 ERROR("do not use assignment in if condition\n" . $herecurr);
1809                         }
1810
1811                         # Find out what is on the end of the line after the
1812                         # conditional.
1813                         substr($s, 0, length($c), '');
1814                         $s =~ s/\n.*//g;
1815                         $s =~ s/$;//g;  # Remove any comments
1816                         if (length($c) && $s !~ /^\s*{?\s*\\*\s*$/ &&
1817                             $c !~ /}\s*while\s*/)
1818                         {
1819                                 ERROR("trailing statements should be on next line\n" . $herecurr);
1820                         }
1821                 }
1822
1823 # Check relative indent for conditionals and blocks.
1824                 if ($line =~ /\b(?:(?:if|while|for)\s*\(|do\b)/ && $line !~ /^.\s*#/ && $line !~ /\}\s*while\s*/) {
1825                         my ($s, $c) = ($stat, $cond);
1826
1827                         substr($s, 0, length($c), '');
1828
1829                         # Make sure we remove the line prefixes as we have
1830                         # none on the first line, and are going to readd them
1831                         # where necessary.
1832                         $s =~ s/\n./\n/gs;
1833
1834                         # We want to check the first line inside the block
1835                         # starting at the end of the conditional, so remove:
1836                         #  1) any blank line termination
1837                         #  2) any opening brace { on end of the line
1838                         #  3) any do (...) {
1839                         my $continuation = 0;
1840                         my $check = 0;
1841                         $s =~ s/^.*\bdo\b//;
1842                         $s =~ s/^\s*{//;
1843                         if ($s =~ s/^\s*\\//) {
1844                                 $continuation = 1;
1845                         }
1846                         if ($s =~ s/^\s*\n//) {
1847                                 $check = 1;
1848                         }
1849
1850                         # Also ignore a loop construct at the end of a
1851                         # preprocessor statement.
1852                         if (($prevline =~ /^.\s*#\s*define\s/ ||
1853                             $prevline =~ /\\\s*$/) && $continuation == 0) {
1854                                 $check = 0;
1855                         }
1856
1857                         # Ignore the current line if its is a preprocessor
1858                         # line.
1859                         if ($s =~ /^\s*#\s*/) {
1860                                 $check = 0;
1861                         }
1862
1863                         # Ignore the current line if it is label.
1864                         if ($s =~ /^\s*$Ident\s*:/) {
1865                                 $check = 0;
1866                         }
1867
1868                         my (undef, $sindent) = line_stats("+" . $s);
1869
1870                         ##print "line<$line> prevline<$prevline> indent<$indent> sindent<$sindent> check<$check> continuation<$continuation> s<$s>\n";
1871
1872                         if ($check && (($sindent % 8) != 0 ||
1873                             ($sindent <= $indent && $s ne ''))) {
1874                                 WARN("suspect code indent for conditional statements\n" . $herecurr);
1875                         }
1876                 }
1877
1878 # Check for bitwise tests written as boolean
1879                 if ($line =~ /
1880                         (?:
1881                                 (?:\[|\(|\&\&|\|\|)
1882                                 \s*0[xX][0-9]+\s*
1883                                 (?:\&\&|\|\|)
1884                         |
1885                                 (?:\&\&|\|\|)
1886                                 \s*0[xX][0-9]+\s*
1887                                 (?:\&\&|\|\||\)|\])
1888                         )/x)
1889                 {
1890                         WARN("boolean test with hexadecimal, perhaps just 1 \& or \|?\n" . $herecurr);
1891                 }
1892
1893 # if and else should not have general statements after it
1894                 if ($line =~ /^.\s*(?:}\s*)?else\b(.*)/) {
1895                         my $s = $1;
1896                         $s =~ s/$;//g;  # Remove any comments
1897                         if ($s !~ /^\s*(?:\sif|(?:{|)\s*\\?\s*$)/) {
1898                                 ERROR("trailing statements should be on next line\n" . $herecurr);
1899                         }
1900                 }
1901
1902                 # Check for }<nl>else {, these must be at the same
1903                 # indent level to be relevant to each other.
1904                 if ($prevline=~/}\s*$/ and $line=~/^.\s*else\s*/ and
1905                                                 $previndent == $indent) {
1906                         ERROR("else should follow close brace '}'\n" . $hereprev);
1907                 }
1908
1909                 if ($prevline=~/}\s*$/ and $line=~/^.\s*while\s*/ and
1910                                                 $previndent == $indent) {
1911                         my ($s, $c) = ctx_statement_block($linenr, $realcnt, 0);
1912
1913                         # Find out what is on the end of the line after the
1914                         # conditional.
1915                         substr($s, 0, length($c), '');
1916                         $s =~ s/\n.*//g;
1917
1918                         if ($s =~ /^\s*;/) {
1919                                 ERROR("while should follow close brace '}'\n" . $hereprev);
1920                         }
1921                 }
1922
1923 #studly caps, commented out until figure out how to distinguish between use of existing and adding new
1924 #               if (($line=~/[\w_][a-z\d]+[A-Z]/) and !($line=~/print/)) {
1925 #                   print "No studly caps, use _\n";
1926 #                   print "$herecurr";
1927 #                   $clean = 0;
1928 #               }
1929
1930 #no spaces allowed after \ in define
1931                 if ($line=~/\#\s*define.*\\\s$/) {
1932                         WARN("Whitepspace after \\ makes next lines useless\n" . $herecurr);
1933                 }
1934
1935 #warn if <asm/foo.h> is #included and <linux/foo.h> is available (uses RAW line)
1936                 if ($tree && $rawline =~ m{^.\s*\#\s*include\s*\<asm\/(.*)\.h\>}) {
1937                         my $checkfile = "include/linux/$1.h";
1938                         if (-f "$root/$checkfile" && $realfile ne $checkfile &&
1939                             $1 ne 'irq')
1940                         {
1941                                 WARN("Use #include <linux/$1.h> instead of <asm/$1.h>\n" .
1942                                         $herecurr);
1943                         }
1944                 }
1945
1946 # multi-statement macros should be enclosed in a do while loop, grab the
1947 # first statement and ensure its the whole macro if its not enclosed
1948 # in a known good container
1949                 if ($realfile !~ m@/vmlinux.lds.h$@ &&
1950                     $line =~ /^.\s*\#\s*define\s*$Ident(\()?/) {
1951                         my $ln = $linenr;
1952                         my $cnt = $realcnt;
1953                         my ($off, $dstat, $dcond, $rest);
1954                         my $ctx = '';
1955
1956                         my $args = defined($1);
1957
1958                         # Find the end of the macro and limit our statement
1959                         # search to that.
1960                         while ($cnt > 0 && defined $lines[$ln - 1] &&
1961                                 $lines[$ln - 1] =~ /^(?:-|..*\\$)/)
1962                         {
1963                                 $ctx .= $rawlines[$ln - 1] . "\n";
1964                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
1965                                 $ln++;
1966                         }
1967                         $ctx .= $rawlines[$ln - 1];
1968
1969                         ($dstat, $dcond, $ln, $cnt, $off) =
1970                                 ctx_statement_block($linenr, $ln - $linenr + 1, 0);
1971                         #print "dstat<$dstat> dcond<$dcond> cnt<$cnt> off<$off>\n";
1972                         #print "LINE<$lines[$ln-1]> len<" . length($lines[$ln-1]) . "\n";
1973
1974                         # Extract the remainder of the define (if any) and
1975                         # rip off surrounding spaces, and trailing \'s.
1976                         $rest = '';
1977                         while ($off != 0 || ($cnt > 0 && $rest =~ /(?:^|\\)\s*$/)) {
1978                                 #print "ADDING $off <" . substr($lines[$ln - 1], $off) . ">\n";
1979                                 if ($off != 0 || $lines[$ln - 1] !~ /^-/) {
1980                                         $rest .= substr($lines[$ln - 1], $off) . "\n";
1981                                         $cnt--;
1982                                 }
1983                                 $ln++;
1984                                 $off = 0;
1985                         }
1986                         $rest =~ s/\\\n.//g;
1987                         $rest =~ s/^\s*//s;
1988                         $rest =~ s/\s*$//s;
1989
1990                         # Clean up the original statement.
1991                         if ($args) {
1992                                 substr($dstat, 0, length($dcond), '');
1993                         } else {
1994                                 $dstat =~ s/^.\s*\#\s*define\s+$Ident\s*//;
1995                         }
1996                         $dstat =~ s/$;//g;
1997                         $dstat =~ s/\\\n.//g;
1998                         $dstat =~ s/^\s*//s;
1999                         $dstat =~ s/\s*$//s;
2000
2001                         # Flatten any parentheses and braces
2002                         while ($dstat =~ s/\([^\(\)]*\)/1/) {
2003                         }
2004                         while ($dstat =~ s/\{[^\{\}]*\}/1/) {
2005                         }
2006
2007                         my $exceptions = qr{
2008                                 $Declare|
2009                                 module_param_named|
2010                                 MODULE_PARAM_DESC|
2011                                 DECLARE_PER_CPU|
2012                                 DEFINE_PER_CPU|
2013                                 __typeof__\(
2014                         }x;
2015                         #print "REST<$rest>\n";
2016                         if ($rest ne '') {
2017                                 if ($rest !~ /while\s*\(/ &&
2018                                     $dstat !~ /$exceptions/)
2019                                 {
2020                                         ERROR("Macros with multiple statements should be enclosed in a do - while loop\n" . "$here\n$ctx\n");
2021                                 }
2022
2023                         } elsif ($ctx !~ /;/) {
2024                                 if ($dstat ne '' &&
2025                                     $dstat !~ /^(?:$Ident|-?$Constant)$/ &&
2026                                     $dstat !~ /$exceptions/ &&
2027                                     $dstat =~ /$Operators/)
2028                                 {
2029                                         ERROR("Macros with complex values should be enclosed in parenthesis\n" . "$here\n$ctx\n");
2030                                 }
2031                         }
2032                 }
2033
2034 # check for redundant bracing round if etc
2035                 if ($line =~ /(^.*)\bif\b/ && $1 !~ /else\s*$/) {
2036                         my ($level, $endln, @chunks) =
2037                                 ctx_statement_full($linenr, $realcnt, 1);
2038                         #print "chunks<$#chunks> linenr<$linenr> endln<$endln> level<$level>\n";
2039                         #print "APW: <<$chunks[1][0]>><<$chunks[1][1]>>\n";
2040                         if ($#chunks > 0 && $level == 0) {
2041                                 my $allowed = 0;
2042                                 my $seen = 0;
2043                                 my $herectx = $here . "\n";
2044                                 my $ln = $linenr - 1;
2045                                 for my $chunk (@chunks) {
2046                                         my ($cond, $block) = @{$chunk};
2047
2048                                         # If the condition carries leading newlines, then count those as offsets.
2049                                         my ($whitespace) = ($cond =~ /^((?:\s*\n[+-])*\s*)/s);
2050                                         my $offset = statement_rawlines($whitespace) - 1;
2051
2052                                         #print "COND<$cond> whitespace<$whitespace> offset<$offset>\n";
2053
2054                                         # We have looked at and allowed this specific line.
2055                                         $suppress_ifbraces{$ln + $offset} = 1;
2056
2057                                         $herectx .= "$rawlines[$ln + $offset]\n[...]\n";
2058                                         $ln += statement_rawlines($block) - 1;
2059
2060                                         substr($block, 0, length($cond), '');
2061
2062                                         $seen++ if ($block =~ /^\s*{/);
2063
2064                                         #print "cond<$cond> block<$block> allowed<$allowed>\n";
2065                                         if (statement_lines($cond) > 1) {
2066                                                 #print "APW: ALLOWED: cond<$cond>\n";
2067                                                 $allowed = 1;
2068                                         }
2069                                         if ($block =~/\b(?:if|for|while)\b/) {
2070                                                 #print "APW: ALLOWED: block<$block>\n";
2071                                                 $allowed = 1;
2072                                         }
2073                                         if (statement_block_size($block) > 1) {
2074                                                 #print "APW: ALLOWED: lines block<$block>\n";
2075                                                 $allowed = 1;
2076                                         }
2077                                 }
2078                                 if ($seen && !$allowed) {
2079                                         WARN("braces {} are not necessary for any arm of this statement\n" . $herectx);
2080                                 }
2081                         }
2082                 }
2083                 if (!defined $suppress_ifbraces{$linenr - 1} &&
2084                                         $line =~ /\b(if|while|for|else)\b/) {
2085                         my $allowed = 0;
2086
2087                         # Check the pre-context.
2088                         if (substr($line, 0, $-[0]) =~ /(\}\s*)$/) {
2089                                 #print "APW: ALLOWED: pre<$1>\n";
2090                                 $allowed = 1;
2091                         }
2092
2093                         my ($level, $endln, @chunks) =
2094                                 ctx_statement_full($linenr, $realcnt, $-[0]);
2095
2096                         # Check the condition.
2097                         my ($cond, $block) = @{$chunks[0]};
2098                         #print "CHECKING<$linenr> cond<$cond> block<$block>\n";
2099                         if (defined $cond) {
2100                                 substr($block, 0, length($cond), '');
2101                         }
2102                         if (statement_lines($cond) > 1) {
2103                                 #print "APW: ALLOWED: cond<$cond>\n";
2104                                 $allowed = 1;
2105                         }
2106                         if ($block =~/\b(?:if|for|while)\b/) {
2107                                 #print "APW: ALLOWED: block<$block>\n";
2108                                 $allowed = 1;
2109                         }
2110                         if (statement_block_size($block) > 1) {
2111                                 #print "APW: ALLOWED: lines block<$block>\n";
2112                                 $allowed = 1;
2113                         }
2114                         # Check the post-context.
2115                         if (defined $chunks[1]) {
2116                                 my ($cond, $block) = @{$chunks[1]};
2117                                 if (defined $cond) {
2118                                         substr($block, 0, length($cond), '');
2119                                 }
2120                                 if ($block =~ /^\s*\{/) {
2121                                         #print "APW: ALLOWED: chunk-1 block<$block>\n";
2122                                         $allowed = 1;
2123                                 }
2124                         }
2125                         if ($level == 0 && $block =~ /^\s*\{/ && !$allowed) {
2126                                 my $herectx = $here . "\n";;
2127                                 my $end = $linenr + statement_rawlines($block) - 1;
2128
2129                                 for (my $ln = $linenr - 1; $ln < $end; $ln++) {
2130                                         $herectx .= $rawlines[$ln] . "\n";;
2131                                 }
2132
2133                                 WARN("braces {} are not necessary for single statement blocks\n" . $herectx);
2134                         }
2135                 }
2136
2137 # don't include deprecated include files (uses RAW line)
2138                 for my $inc (@dep_includes) {
2139                         if ($rawline =~ m@^.\s*\#\s*include\s*\<$inc>@) {
2140                                 ERROR("Don't use <$inc>: see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2141                         }
2142                 }
2143
2144 # don't use deprecated functions
2145                 for my $func (@dep_functions) {
2146                         if ($line =~ /\b$func\b/) {
2147                                 ERROR("Don't use $func(): see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2148                         }
2149                 }
2150
2151 # no volatiles please
2152                 my $asm_volatile = qr{\b(__asm__|asm)\s+(__volatile__|volatile)\b};
2153                 if ($line =~ /\bvolatile\b/ && $line !~ /$asm_volatile/) {
2154                         WARN("Use of volatile is usually wrong: see Documentation/volatile-considered-harmful.txt\n" . $herecurr);
2155                 }
2156
2157 # SPIN_LOCK_UNLOCKED & RW_LOCK_UNLOCKED are deprecated
2158                 if ($line =~ /\b(SPIN_LOCK_UNLOCKED|RW_LOCK_UNLOCKED)/) {
2159                         ERROR("Use of $1 is deprecated: see Documentation/spinlocks.txt\n" . $herecurr);
2160                 }
2161
2162 # warn about #if 0
2163                 if ($line =~ /^.\s*\#\s*if\s+0\b/) {
2164                         CHK("if this code is redundant consider removing it\n" .
2165                                 $herecurr);
2166                 }
2167
2168 # check for needless kfree() checks
2169                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2170                         my $expr = $1;
2171                         if ($line =~ /\bkfree\(\Q$expr\E\);/) {
2172                                 WARN("kfree(NULL) is safe this check is probably not required\n" . $hereprev);
2173                         }
2174                 }
2175 # check for needless usb_free_urb() checks
2176                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2177                         my $expr = $1;
2178                         if ($line =~ /\busb_free_urb\(\Q$expr\E\);/) {
2179                                 WARN("usb_free_urb(NULL) is safe this check is probably not required\n" . $hereprev);
2180                         }
2181                 }
2182
2183 # warn about #ifdefs in C files
2184 #               if ($line =~ /^.\s*\#\s*if(|n)def/ && ($realfile =~ /\.c$/)) {
2185 #                       print "#ifdef in C files should be avoided\n";
2186 #                       print "$herecurr";
2187 #                       $clean = 0;
2188 #               }
2189
2190 # warn about spacing in #ifdefs
2191                 if ($line =~ /^.\s*\#\s*(ifdef|ifndef|elif)\s\s+/) {
2192                         ERROR("exactly one space required after that #$1\n" . $herecurr);
2193                 }
2194
2195 # check for spinlock_t definitions without a comment.
2196                 if ($line =~ /^.\s*(struct\s+mutex|spinlock_t)\s+\S+;/ ||
2197                     $line =~ /^.\s*(DEFINE_MUTEX)\s*\(/) {
2198                         my $which = $1;
2199                         if (!ctx_has_comment($first_line, $linenr)) {
2200                                 CHK("$1 definition without comment\n" . $herecurr);
2201                         }
2202                 }
2203 # check for memory barriers without a comment.
2204                 if ($line =~ /\b(mb|rmb|wmb|read_barrier_depends|smp_mb|smp_rmb|smp_wmb|smp_read_barrier_depends)\(/) {
2205                         if (!ctx_has_comment($first_line, $linenr)) {
2206                                 CHK("memory barrier without comment\n" . $herecurr);
2207                         }
2208                 }
2209 # check of hardware specific defines
2210                 if ($line =~ m@^.\s*\#\s*if.*\b(__i386__|__powerpc64__|__sun__|__s390x__)\b@ && $realfile !~ m@include/asm-@) {
2211                         CHK("architecture specific defines should be avoided\n" .  $herecurr);
2212                 }
2213
2214 # check the location of the inline attribute, that it is between
2215 # storage class and type.
2216                 if ($line =~ /\b$Type\s+$Inline\b/ ||
2217                     $line =~ /\b$Inline\s+$Storage\b/) {
2218                         ERROR("inline keyword should sit between storage class and type\n" . $herecurr);
2219                 }
2220
2221 # Check for __inline__ and __inline, prefer inline
2222                 if ($line =~ /\b(__inline__|__inline)\b/) {
2223                         WARN("plain inline is preferred over $1\n" . $herecurr);
2224                 }
2225
2226 # check for new externs in .c files.
2227                 if ($realfile =~ /\.c$/ && defined $stat &&
2228                     $stat =~ /^.\s*(?:extern\s+)?$Type\s+($Ident)(\s*)\(/s)
2229                 {
2230                         my $function_name = $1;
2231                         my $paren_space = $2;
2232
2233                         my $s = $stat;
2234                         if (defined $cond) {
2235                                 substr($s, 0, length($cond), '');
2236                         }
2237                         if ($s =~ /^\s*;/ &&
2238                             $function_name ne 'uninitialized_var')
2239                         {
2240                                 WARN("externs should be avoided in .c files\n" .  $herecurr);
2241                         }
2242
2243                         if ($paren_space =~ /\n/) {
2244                                 WARN("arguments for function declarations should follow identifier\n" . $herecurr);
2245                         }
2246
2247                 } elsif ($realfile =~ /\.c$/ && defined $stat &&
2248                     $stat =~ /^.\s*extern\s+/)
2249                 {
2250                         WARN("externs should be avoided in .c files\n" .  $herecurr);
2251                 }
2252
2253 # checks for new __setup's
2254                 if ($rawline =~ /\b__setup\("([^"]*)"/) {
2255                         my $name = $1;
2256
2257                         if (!grep(/$name/, @setup_docs)) {
2258                                 CHK("__setup appears un-documented -- check Documentation/kernel-parameters.txt\n" . $herecurr);
2259                         }
2260                 }
2261
2262 # check for pointless casting of kmalloc return
2263                 if ($line =~ /\*\s*\)\s*k[czm]alloc\b/) {
2264                         WARN("unnecessary cast may hide bugs, see http://c-faq.com/malloc/mallocnocast.html\n" . $herecurr);
2265                 }
2266
2267 # check for gcc specific __FUNCTION__
2268                 if ($line =~ /__FUNCTION__/) {
2269                         WARN("__func__ should be used instead of gcc specific __FUNCTION__\n"  . $herecurr);
2270                 }
2271
2272 # check for semaphores used as mutexes
2273                 if ($line =~ /^.\s*(DECLARE_MUTEX|init_MUTEX)\s*\(/) {
2274                         WARN("mutexes are preferred for single holder semaphores\n" . $herecurr);
2275                 }
2276 # check for semaphores used as mutexes
2277                 if ($line =~ /^.\s*init_MUTEX_LOCKED\s*\(/) {
2278                         WARN("consider using a completion\n" . $herecurr);
2279                 }
2280 # recommend strict_strto* over simple_strto*
2281                 if ($line =~ /\bsimple_(strto.*?)\s*\(/) {
2282                         WARN("consider using strict_$1 in preference to simple_$1\n" . $herecurr);
2283                 }
2284 # check for __initcall(), use device_initcall() explicitly please
2285                 if ($line =~ /^.\s*__initcall\s*\(/) {
2286                         WARN("please use device_initcall() instead of __initcall()\n" . $herecurr);
2287                 }
2288
2289 # use of NR_CPUS is usually wrong
2290 # ignore definitions of NR_CPUS and usage to define arrays as likely right
2291                 if ($line =~ /\bNR_CPUS\b/ &&
2292                     $line !~ /^.\s*\s*#\s*if\b.*\bNR_CPUS\b/ &&
2293                     $line !~ /^.\s*\s*#\s*define\b.*\bNR_CPUS\b/ &&
2294                     $line !~ /^.\s*$Declare\s.*\[[^\]]*NR_CPUS[^\]]*\]/ &&
2295                     $line !~ /\[[^\]]*\.\.\.[^\]]*NR_CPUS[^\]]*\]/ &&
2296                     $line !~ /\[[^\]]*NR_CPUS[^\]]*\.\.\.[^\]]*\]/)
2297                 {
2298                         WARN("usage of NR_CPUS is often wrong - consider using cpu_possible(), num_possible_cpus(), for_each_possible_cpu(), etc\n" . $herecurr);
2299                 }
2300
2301 # check for %L{u,d,i} in strings
2302                 my $string;
2303                 while ($line =~ /(?:^|")([X\t]*)(?:"|$)/g) {
2304                         $string = substr($rawline, $-[1], $+[1] - $-[1]);
2305                         if ($string =~ /(?<!%)%L[udi]/) {
2306                                 WARN("\%Ld/%Lu are not-standard C, use %lld/%llu\n" . $herecurr);
2307                                 last;
2308                         }
2309                 }
2310         }
2311
2312         # If we have no input at all, then there is nothing to report on
2313         # so just keep quiet.
2314         if ($#rawlines == -1) {
2315                 exit(0);
2316         }
2317
2318         # In mailback mode only produce a report in the negative, for
2319         # things that appear to be patches.
2320         if ($mailback && ($clean == 1 || !$is_patch)) {
2321                 exit(0);
2322         }
2323
2324         # This is not a patch, and we are are in 'no-patch' mode so
2325         # just keep quiet.
2326         if (!$chk_patch && !$is_patch) {
2327                 exit(0);
2328         }
2329
2330         if (!$is_patch) {
2331                 ERROR("Does not appear to be a unified-diff format patch\n");
2332         }
2333         if ($is_patch && $chk_signoff && $signoff == 0) {
2334                 ERROR("Missing Signed-off-by: line(s)\n");
2335         }
2336
2337         print report_dump();
2338         if ($summary && !($clean == 1 && $quiet == 1)) {
2339                 print "$filename " if ($summary_file);
2340                 print "total: $cnt_error errors, $cnt_warn warnings, " .
2341                         (($check)? "$cnt_chk checks, " : "") .
2342                         "$cnt_lines lines checked\n";
2343                 print "\n" if ($quiet == 0);
2344         }
2345
2346         if ($clean == 1 && $quiet == 0) {
2347                 print "$vname has no obvious style problems and is ready for submission.\n"
2348         }
2349         if ($clean == 0 && $quiet == 0) {
2350                 print "$vname has style problems, please review.  If any of these errors\n";
2351                 print "are false positives report them to the maintainer, see\n";
2352                 print "CHECKPATCH in MAINTAINERS.\n";
2353         }
2354
2355         return $clean;
2356 }