TPS65911: Comparator: Add comparator driver
[linux-2.6.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU_SECTION(CACHELINE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      BSS_SECTION(0, 0, 0)
34  *      _end = .;
35  *
36  *      STABS_DEBUG
37  *      DWARF_DEBUG
38  *
39  *      DISCARDS                // must be the last
40  * }
41  *
42  * [__init_begin, __init_end] is the init section that may be freed after init
43  * [_stext, _etext] is the text section
44  * [_sdata, _edata] is the data section
45  *
46  * Some of the included output section have their own set of constants.
47  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48  *               [__nosave_begin, __nosave_end] for the nosave data
49  */
50
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
54
55 #ifndef SYMBOL_PREFIX
56 #define VMLINUX_SYMBOL(sym) sym
57 #else
58 #define PASTE2(x,y) x##y
59 #define PASTE(x,y) PASTE2(x,y)
60 #define VMLINUX_SYMBOL(sym) PASTE(SYMBOL_PREFIX, sym)
61 #endif
62
63 /* Align . to a 8 byte boundary equals to maximum function alignment. */
64 #define ALIGN_FUNCTION()  . = ALIGN(8)
65
66 /*
67  * Align to a 32 byte boundary equal to the
68  * alignment gcc 4.5 uses for a struct
69  */
70 #define STRUCT_ALIGNMENT 32
71 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
72
73 /* The actual configuration determine if the init/exit sections
74  * are handled as text/data or they can be discarded (which
75  * often happens at runtime)
76  */
77 #ifdef CONFIG_HOTPLUG
78 #define DEV_KEEP(sec)    *(.dev##sec)
79 #define DEV_DISCARD(sec)
80 #else
81 #define DEV_KEEP(sec)
82 #define DEV_DISCARD(sec) *(.dev##sec)
83 #endif
84
85 #ifdef CONFIG_HOTPLUG_CPU
86 #define CPU_KEEP(sec)    *(.cpu##sec)
87 #define CPU_DISCARD(sec)
88 #else
89 #define CPU_KEEP(sec)
90 #define CPU_DISCARD(sec) *(.cpu##sec)
91 #endif
92
93 #if defined(CONFIG_MEMORY_HOTPLUG)
94 #define MEM_KEEP(sec)    *(.mem##sec)
95 #define MEM_DISCARD(sec)
96 #else
97 #define MEM_KEEP(sec)
98 #define MEM_DISCARD(sec) *(.mem##sec)
99 #endif
100
101 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
102 #define MCOUNT_REC()    . = ALIGN(8);                           \
103                         VMLINUX_SYMBOL(__start_mcount_loc) = .; \
104                         *(__mcount_loc)                         \
105                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
106 #else
107 #define MCOUNT_REC()
108 #endif
109
110 #ifdef CONFIG_TRACE_BRANCH_PROFILING
111 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
112                                 *(_ftrace_annotated_branch)                           \
113                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
114 #else
115 #define LIKELY_PROFILE()
116 #endif
117
118 #ifdef CONFIG_PROFILE_ALL_BRANCHES
119 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
120                                 *(_ftrace_branch)                             \
121                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
122 #else
123 #define BRANCH_PROFILE()
124 #endif
125
126 #ifdef CONFIG_EVENT_TRACING
127 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
128                         VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
129                         *(_ftrace_events)                               \
130                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
137                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
138                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #else
140 #define TRACE_PRINTKS()
141 #endif
142
143 #ifdef CONFIG_FTRACE_SYSCALLS
144 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
145                          VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
146                          *(__syscalls_metadata)                         \
147                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
148 #else
149 #define TRACE_SYSCALLS()
150 #endif
151
152
153 #define KERNEL_DTB()                                                    \
154         STRUCT_ALIGN();                                                 \
155         VMLINUX_SYMBOL(__dtb_start) = .;                                \
156         *(.dtb.init.rodata)                                             \
157         VMLINUX_SYMBOL(__dtb_end) = .;
158
159 /* .data section */
160 #define DATA_DATA                                                       \
161         *(.data)                                                        \
162         *(.ref.data)                                                    \
163         *(.data..shared_aligned) /* percpu related */                   \
164         DEV_KEEP(init.data)                                             \
165         DEV_KEEP(exit.data)                                             \
166         CPU_KEEP(init.data)                                             \
167         CPU_KEEP(exit.data)                                             \
168         MEM_KEEP(init.data)                                             \
169         MEM_KEEP(exit.data)                                             \
170         STRUCT_ALIGN();                                                 \
171         *(__tracepoints)                                                \
172         /* implement dynamic printk debug */                            \
173         . = ALIGN(8);                                                   \
174         VMLINUX_SYMBOL(__start___jump_table) = .;                       \
175         *(__jump_table)                                                 \
176         VMLINUX_SYMBOL(__stop___jump_table) = .;                        \
177         . = ALIGN(8);                                                   \
178         VMLINUX_SYMBOL(__start___verbose) = .;                          \
179         *(__verbose)                                                    \
180         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
181         LIKELY_PROFILE()                                                \
182         BRANCH_PROFILE()                                                \
183         TRACE_PRINTKS()
184
185 /*
186  * Data section helpers
187  */
188 #define NOSAVE_DATA                                                     \
189         . = ALIGN(PAGE_SIZE);                                           \
190         VMLINUX_SYMBOL(__nosave_begin) = .;                             \
191         *(.data..nosave)                                                \
192         . = ALIGN(PAGE_SIZE);                                           \
193         VMLINUX_SYMBOL(__nosave_end) = .;
194
195 #define PAGE_ALIGNED_DATA(page_align)                                   \
196         . = ALIGN(page_align);                                          \
197         *(.data..page_aligned)
198
199 #define READ_MOSTLY_DATA(align)                                         \
200         . = ALIGN(align);                                               \
201         *(.data..read_mostly)                                           \
202         . = ALIGN(align);
203
204 #define CACHELINE_ALIGNED_DATA(align)                                   \
205         . = ALIGN(align);                                               \
206         *(.data..cacheline_aligned)
207
208 #define INIT_TASK_DATA(align)                                           \
209         . = ALIGN(align);                                               \
210         *(.data..init_task)
211
212 /*
213  * Read only Data
214  */
215 #define RO_DATA_SECTION(align)                                          \
216         . = ALIGN((align));                                             \
217         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
218                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
219                 *(.rodata) *(.rodata.*)                                 \
220                 *(__vermagic)           /* Kernel version magic */      \
221                 . = ALIGN(8);                                           \
222                 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .;         \
223                 *(__tracepoints_ptrs)   /* Tracepoints: pointer array */\
224                 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .;          \
225                 *(__markers_strings)    /* Markers: strings */          \
226                 *(__tracepoints_strings)/* Tracepoints: strings */      \
227         }                                                               \
228                                                                         \
229         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
230                 *(.rodata1)                                             \
231         }                                                               \
232                                                                         \
233         BUG_TABLE                                                       \
234                                                                         \
235         /* PCI quirks */                                                \
236         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
237                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
238                 *(.pci_fixup_early)                                     \
239                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
240                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
241                 *(.pci_fixup_header)                                    \
242                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
243                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
244                 *(.pci_fixup_final)                                     \
245                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
246                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
247                 *(.pci_fixup_enable)                                    \
248                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
249                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
250                 *(.pci_fixup_resume)                                    \
251                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
252                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
253                 *(.pci_fixup_resume_early)                              \
254                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
255                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
256                 *(.pci_fixup_suspend)                                   \
257                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
258         }                                                               \
259                                                                         \
260         /* Built-in firmware blobs */                                   \
261         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
262                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
263                 *(.builtin_fw)                                          \
264                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
265         }                                                               \
266                                                                         \
267         /* RapidIO route ops */                                         \
268         .rio_ops        : AT(ADDR(.rio_ops) - LOAD_OFFSET) {            \
269                 VMLINUX_SYMBOL(__start_rio_switch_ops) = .;             \
270                 *(.rio_switch_ops)                                      \
271                 VMLINUX_SYMBOL(__end_rio_switch_ops) = .;               \
272         }                                                               \
273                                                                         \
274         TRACEDATA                                                       \
275                                                                         \
276         /* Kernel symbol table: Normal symbols */                       \
277         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
278                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
279                 *(SORT(___ksymtab+*))                                   \
280                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
281         }                                                               \
282                                                                         \
283         /* Kernel symbol table: GPL-only symbols */                     \
284         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
285                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
286                 *(SORT(___ksymtab_gpl+*))                               \
287                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
288         }                                                               \
289                                                                         \
290         /* Kernel symbol table: Normal unused symbols */                \
291         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
292                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
293                 *(SORT(___ksymtab_unused+*))                            \
294                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
295         }                                                               \
296                                                                         \
297         /* Kernel symbol table: GPL-only unused symbols */              \
298         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
299                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
300                 *(SORT(___ksymtab_unused_gpl+*))                        \
301                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
302         }                                                               \
303                                                                         \
304         /* Kernel symbol table: GPL-future-only symbols */              \
305         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
306                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
307                 *(SORT(___ksymtab_gpl_future+*))                        \
308                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
309         }                                                               \
310                                                                         \
311         /* Kernel symbol table: Normal symbols */                       \
312         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
313                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
314                 *(SORT(___kcrctab+*))                                   \
315                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
316         }                                                               \
317                                                                         \
318         /* Kernel symbol table: GPL-only symbols */                     \
319         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
320                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
321                 *(SORT(___kcrctab_gpl+*))                               \
322                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
323         }                                                               \
324                                                                         \
325         /* Kernel symbol table: Normal unused symbols */                \
326         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
327                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
328                 *(SORT(___kcrctab_unused+*))                            \
329                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
330         }                                                               \
331                                                                         \
332         /* Kernel symbol table: GPL-only unused symbols */              \
333         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
334                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
335                 *(SORT(___kcrctab_unused_gpl+*))                        \
336                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
337         }                                                               \
338                                                                         \
339         /* Kernel symbol table: GPL-future-only symbols */              \
340         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
341                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
342                 *(SORT(___kcrctab_gpl_future+*))                        \
343                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
344         }                                                               \
345                                                                         \
346         /* Kernel symbol table: strings */                              \
347         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
348                 *(__ksymtab_strings)                                    \
349         }                                                               \
350                                                                         \
351         /* __*init sections */                                          \
352         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
353                 *(.ref.rodata)                                          \
354                 DEV_KEEP(init.rodata)                                   \
355                 DEV_KEEP(exit.rodata)                                   \
356                 CPU_KEEP(init.rodata)                                   \
357                 CPU_KEEP(exit.rodata)                                   \
358                 MEM_KEEP(init.rodata)                                   \
359                 MEM_KEEP(exit.rodata)                                   \
360         }                                                               \
361                                                                         \
362         /* Built-in module parameters. */                               \
363         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
364                 VMLINUX_SYMBOL(__start___param) = .;                    \
365                 *(__param)                                              \
366                 VMLINUX_SYMBOL(__stop___param) = .;                     \
367         }                                                               \
368                                                                         \
369         /* Built-in module versions. */                                 \
370         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
371                 VMLINUX_SYMBOL(__start___modver) = .;                   \
372                 *(__modver)                                             \
373                 VMLINUX_SYMBOL(__stop___modver) = .;                    \
374                 . = ALIGN((align));                                     \
375                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
376         }                                                               \
377         . = ALIGN((align));
378
379 /* RODATA & RO_DATA provided for backward compatibility.
380  * All archs are supposed to use RO_DATA() */
381 #define RODATA          RO_DATA_SECTION(4096)
382 #define RO_DATA(align)  RO_DATA_SECTION(align)
383
384 #define SECURITY_INIT                                                   \
385         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
386                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
387                 *(.security_initcall.init)                              \
388                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
389         }
390
391 /* .text section. Map to function alignment to avoid address changes
392  * during second ld run in second ld pass when generating System.map */
393 #define TEXT_TEXT                                                       \
394                 ALIGN_FUNCTION();                                       \
395                 *(.text.hot)                                            \
396                 *(.text)                                                \
397                 *(.ref.text)                                            \
398         DEV_KEEP(init.text)                                             \
399         DEV_KEEP(exit.text)                                             \
400         CPU_KEEP(init.text)                                             \
401         CPU_KEEP(exit.text)                                             \
402         MEM_KEEP(init.text)                                             \
403         MEM_KEEP(exit.text)                                             \
404                 *(.text.unlikely)
405
406
407 /* sched.text is aling to function alignment to secure we have same
408  * address even at second ld pass when generating System.map */
409 #define SCHED_TEXT                                                      \
410                 ALIGN_FUNCTION();                                       \
411                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
412                 *(.sched.text)                                          \
413                 VMLINUX_SYMBOL(__sched_text_end) = .;
414
415 /* spinlock.text is aling to function alignment to secure we have same
416  * address even at second ld pass when generating System.map */
417 #define LOCK_TEXT                                                       \
418                 ALIGN_FUNCTION();                                       \
419                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
420                 *(.spinlock.text)                                       \
421                 VMLINUX_SYMBOL(__lock_text_end) = .;
422
423 #define KPROBES_TEXT                                                    \
424                 ALIGN_FUNCTION();                                       \
425                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
426                 *(.kprobes.text)                                        \
427                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
428
429 #define ENTRY_TEXT                                                      \
430                 ALIGN_FUNCTION();                                       \
431                 VMLINUX_SYMBOL(__entry_text_start) = .;                 \
432                 *(.entry.text)                                          \
433                 VMLINUX_SYMBOL(__entry_text_end) = .;
434
435 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
436 #define IRQENTRY_TEXT                                                   \
437                 ALIGN_FUNCTION();                                       \
438                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
439                 *(.irqentry.text)                                       \
440                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
441 #else
442 #define IRQENTRY_TEXT
443 #endif
444
445 /* Section used for early init (in .S files) */
446 #define HEAD_TEXT  *(.head.text)
447
448 #define HEAD_TEXT_SECTION                                                       \
449         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
450                 HEAD_TEXT                                               \
451         }
452
453 /*
454  * Exception table
455  */
456 #define EXCEPTION_TABLE(align)                                          \
457         . = ALIGN(align);                                               \
458         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
459                 VMLINUX_SYMBOL(__start___ex_table) = .;                 \
460                 *(__ex_table)                                           \
461                 VMLINUX_SYMBOL(__stop___ex_table) = .;                  \
462         }
463
464 /*
465  * Init task
466  */
467 #define INIT_TASK_DATA_SECTION(align)                                   \
468         . = ALIGN(align);                                               \
469         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
470                 INIT_TASK_DATA(align)                                   \
471         }
472
473 #ifdef CONFIG_CONSTRUCTORS
474 #define KERNEL_CTORS()  . = ALIGN(8);                      \
475                         VMLINUX_SYMBOL(__ctors_start) = .; \
476                         *(.ctors)                          \
477                         VMLINUX_SYMBOL(__ctors_end) = .;
478 #else
479 #define KERNEL_CTORS()
480 #endif
481
482 /* init and exit section handling */
483 #define INIT_DATA                                                       \
484         *(.init.data)                                                   \
485         DEV_DISCARD(init.data)                                          \
486         CPU_DISCARD(init.data)                                          \
487         MEM_DISCARD(init.data)                                          \
488         KERNEL_CTORS()                                                  \
489         *(.init.rodata)                                                 \
490         MCOUNT_REC()                                                    \
491         FTRACE_EVENTS()                                                 \
492         TRACE_SYSCALLS()                                                \
493         DEV_DISCARD(init.rodata)                                        \
494         CPU_DISCARD(init.rodata)                                        \
495         MEM_DISCARD(init.rodata)                                        \
496         KERNEL_DTB()
497
498 #define INIT_TEXT                                                       \
499         *(.init.text)                                                   \
500         DEV_DISCARD(init.text)                                          \
501         CPU_DISCARD(init.text)                                          \
502         MEM_DISCARD(init.text)
503
504 #define EXIT_DATA                                                       \
505         *(.exit.data)                                                   \
506         DEV_DISCARD(exit.data)                                          \
507         DEV_DISCARD(exit.rodata)                                        \
508         CPU_DISCARD(exit.data)                                          \
509         CPU_DISCARD(exit.rodata)                                        \
510         MEM_DISCARD(exit.data)                                          \
511         MEM_DISCARD(exit.rodata)
512
513 #define EXIT_TEXT                                                       \
514         *(.exit.text)                                                   \
515         DEV_DISCARD(exit.text)                                          \
516         CPU_DISCARD(exit.text)                                          \
517         MEM_DISCARD(exit.text)
518
519 #define EXIT_CALL                                                       \
520         *(.exitcall.exit)
521
522 /*
523  * bss (Block Started by Symbol) - uninitialized data
524  * zeroed during startup
525  */
526 #define SBSS(sbss_align)                                                \
527         . = ALIGN(sbss_align);                                          \
528         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
529                 *(.sbss)                                                \
530                 *(.scommon)                                             \
531         }
532
533 #define BSS(bss_align)                                                  \
534         . = ALIGN(bss_align);                                           \
535         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
536                 *(.bss..page_aligned)                                   \
537                 *(.dynbss)                                              \
538                 *(.bss)                                                 \
539                 *(COMMON)                                               \
540         }
541
542 /*
543  * DWARF debug sections.
544  * Symbols in the DWARF debugging sections are relative to
545  * the beginning of the section so we begin them at 0.
546  */
547 #define DWARF_DEBUG                                                     \
548                 /* DWARF 1 */                                           \
549                 .debug          0 : { *(.debug) }                       \
550                 .line           0 : { *(.line) }                        \
551                 /* GNU DWARF 1 extensions */                            \
552                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
553                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
554                 /* DWARF 1.1 and DWARF 2 */                             \
555                 .debug_aranges  0 : { *(.debug_aranges) }               \
556                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
557                 /* DWARF 2 */                                           \
558                 .debug_info     0 : { *(.debug_info                     \
559                                 .gnu.linkonce.wi.*) }                   \
560                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
561                 .debug_line     0 : { *(.debug_line) }                  \
562                 .debug_frame    0 : { *(.debug_frame) }                 \
563                 .debug_str      0 : { *(.debug_str) }                   \
564                 .debug_loc      0 : { *(.debug_loc) }                   \
565                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
566                 /* SGI/MIPS DWARF 2 extensions */                       \
567                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
568                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
569                 .debug_typenames 0 : { *(.debug_typenames) }            \
570                 .debug_varnames  0 : { *(.debug_varnames) }             \
571
572                 /* Stabs debugging sections.  */
573 #define STABS_DEBUG                                                     \
574                 .stab 0 : { *(.stab) }                                  \
575                 .stabstr 0 : { *(.stabstr) }                            \
576                 .stab.excl 0 : { *(.stab.excl) }                        \
577                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
578                 .stab.index 0 : { *(.stab.index) }                      \
579                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
580                 .comment 0 : { *(.comment) }
581
582 #ifdef CONFIG_GENERIC_BUG
583 #define BUG_TABLE                                                       \
584         . = ALIGN(8);                                                   \
585         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
586                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
587                 *(__bug_table)                                          \
588                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
589         }
590 #else
591 #define BUG_TABLE
592 #endif
593
594 #ifdef CONFIG_PM_TRACE
595 #define TRACEDATA                                                       \
596         . = ALIGN(4);                                                   \
597         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
598                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
599                 *(.tracedata)                                           \
600                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
601         }
602 #else
603 #define TRACEDATA
604 #endif
605
606 #define NOTES                                                           \
607         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
608                 VMLINUX_SYMBOL(__start_notes) = .;                      \
609                 *(.note.*)                                              \
610                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
611         }
612
613 #define INIT_SETUP(initsetup_align)                                     \
614                 . = ALIGN(initsetup_align);                             \
615                 VMLINUX_SYMBOL(__setup_start) = .;                      \
616                 *(.init.setup)                                          \
617                 VMLINUX_SYMBOL(__setup_end) = .;
618
619 #define INITCALLS                                                       \
620         *(.initcallearly.init)                                          \
621         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
622         *(.initcall0.init)                                              \
623         *(.initcall0s.init)                                             \
624         *(.initcall1.init)                                              \
625         *(.initcall1s.init)                                             \
626         *(.initcall2.init)                                              \
627         *(.initcall2s.init)                                             \
628         *(.initcall3.init)                                              \
629         *(.initcall3s.init)                                             \
630         *(.initcall4.init)                                              \
631         *(.initcall4s.init)                                             \
632         *(.initcall5.init)                                              \
633         *(.initcall5s.init)                                             \
634         *(.initcallrootfs.init)                                         \
635         *(.initcall6.init)                                              \
636         *(.initcall6s.init)                                             \
637         *(.initcall7.init)                                              \
638         *(.initcall7s.init)
639
640 #define INIT_CALLS                                                      \
641                 VMLINUX_SYMBOL(__initcall_start) = .;                   \
642                 INITCALLS                                               \
643                 VMLINUX_SYMBOL(__initcall_end) = .;
644
645 #define CON_INITCALL                                                    \
646                 VMLINUX_SYMBOL(__con_initcall_start) = .;               \
647                 *(.con_initcall.init)                                   \
648                 VMLINUX_SYMBOL(__con_initcall_end) = .;
649
650 #define SECURITY_INITCALL                                               \
651                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
652                 *(.security_initcall.init)                              \
653                 VMLINUX_SYMBOL(__security_initcall_end) = .;
654
655 #ifdef CONFIG_BLK_DEV_INITRD
656 #define INIT_RAM_FS                                                     \
657         . = ALIGN(4);                                                   \
658         VMLINUX_SYMBOL(__initramfs_start) = .;                          \
659         *(.init.ramfs)                                                  \
660         . = ALIGN(8);                                                   \
661         *(.init.ramfs.info)
662 #else
663 #define INIT_RAM_FS
664 #endif
665
666 /*
667  * Default discarded sections.
668  *
669  * Some archs want to discard exit text/data at runtime rather than
670  * link time due to cross-section references such as alt instructions,
671  * bug table, eh_frame, etc.  DISCARDS must be the last of output
672  * section definitions so that such archs put those in earlier section
673  * definitions.
674  */
675 #define DISCARDS                                                        \
676         /DISCARD/ : {                                                   \
677         EXIT_TEXT                                                       \
678         EXIT_DATA                                                       \
679         EXIT_CALL                                                       \
680         *(.discard)                                                     \
681         *(.discard.*)                                                   \
682         }
683
684 /**
685  * PERCPU_INPUT - the percpu input sections
686  * @cacheline: cacheline size
687  *
688  * The core percpu section names and core symbols which do not rely
689  * directly upon load addresses.
690  *
691  * @cacheline is used to align subsections to avoid false cacheline
692  * sharing between subsections for different purposes.
693  */
694 #define PERCPU_INPUT(cacheline)                                         \
695         VMLINUX_SYMBOL(__per_cpu_start) = .;                            \
696         *(.data..percpu..first)                                         \
697         . = ALIGN(PAGE_SIZE);                                           \
698         *(.data..percpu..page_aligned)                                  \
699         . = ALIGN(cacheline);                                           \
700         *(.data..percpu..readmostly)                                    \
701         . = ALIGN(cacheline);                                           \
702         *(.data..percpu)                                                \
703         *(.data..percpu..shared_aligned)                                \
704         VMLINUX_SYMBOL(__per_cpu_end) = .;
705
706 /**
707  * PERCPU_VADDR - define output section for percpu area
708  * @cacheline: cacheline size
709  * @vaddr: explicit base address (optional)
710  * @phdr: destination PHDR (optional)
711  *
712  * Macro which expands to output section for percpu area.
713  *
714  * @cacheline is used to align subsections to avoid false cacheline
715  * sharing between subsections for different purposes.
716  *
717  * If @vaddr is not blank, it specifies explicit base address and all
718  * percpu symbols will be offset from the given address.  If blank,
719  * @vaddr always equals @laddr + LOAD_OFFSET.
720  *
721  * @phdr defines the output PHDR to use if not blank.  Be warned that
722  * output PHDR is sticky.  If @phdr is specified, the next output
723  * section in the linker script will go there too.  @phdr should have
724  * a leading colon.
725  *
726  * Note that this macros defines __per_cpu_load as an absolute symbol.
727  * If there is no need to put the percpu section at a predetermined
728  * address, use PERCPU_SECTION.
729  */
730 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
731         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
732         .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)         \
733                                 - LOAD_OFFSET) {                        \
734                 PERCPU_INPUT(cacheline)                                 \
735         } phdr                                                          \
736         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
737
738 /**
739  * PERCPU_SECTION - define output section for percpu area, simple version
740  * @cacheline: cacheline size
741  *
742  * Align to PAGE_SIZE and outputs output section for percpu area.  This
743  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
744  * __per_cpu_start will be identical.
745  *
746  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
747  * except that __per_cpu_load is defined as a relative symbol against
748  * .data..percpu which is required for relocatable x86_32 configuration.
749  */
750 #define PERCPU_SECTION(cacheline)                                       \
751         . = ALIGN(PAGE_SIZE);                                           \
752         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
753                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
754                 PERCPU_INPUT(cacheline)                                 \
755         }
756
757
758 /*
759  * Definition of the high level *_SECTION macros
760  * They will fit only a subset of the architectures
761  */
762
763
764 /*
765  * Writeable data.
766  * All sections are combined in a single .data section.
767  * The sections following CONSTRUCTORS are arranged so their
768  * typical alignment matches.
769  * A cacheline is typical/always less than a PAGE_SIZE so
770  * the sections that has this restriction (or similar)
771  * is located before the ones requiring PAGE_SIZE alignment.
772  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
773  * matches the requirement of PAGE_ALIGNED_DATA.
774  *
775  * use 0 as page_align if page_aligned data is not used */
776 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
777         . = ALIGN(PAGE_SIZE);                                           \
778         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
779                 INIT_TASK_DATA(inittask)                                \
780                 NOSAVE_DATA                                             \
781                 PAGE_ALIGNED_DATA(pagealigned)                          \
782                 CACHELINE_ALIGNED_DATA(cacheline)                       \
783                 READ_MOSTLY_DATA(cacheline)                             \
784                 DATA_DATA                                               \
785                 CONSTRUCTORS                                            \
786         }
787
788 #define INIT_TEXT_SECTION(inittext_align)                               \
789         . = ALIGN(inittext_align);                                      \
790         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
791                 VMLINUX_SYMBOL(_sinittext) = .;                         \
792                 INIT_TEXT                                               \
793                 VMLINUX_SYMBOL(_einittext) = .;                         \
794         }
795
796 #define INIT_DATA_SECTION(initsetup_align)                              \
797         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
798                 INIT_DATA                                               \
799                 INIT_SETUP(initsetup_align)                             \
800                 INIT_CALLS                                              \
801                 CON_INITCALL                                            \
802                 SECURITY_INITCALL                                       \
803                 INIT_RAM_FS                                             \
804         }
805
806 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
807         . = ALIGN(sbss_align);                                          \
808         VMLINUX_SYMBOL(__bss_start) = .;                                \
809         SBSS(sbss_align)                                                \
810         BSS(bss_align)                                                  \
811         . = ALIGN(stop_align);                                          \
812         VMLINUX_SYMBOL(__bss_stop) = .;