Merge branch 'x86/orig_ax' of git://git.kernel.org/pub/scm/linux/kernel/git/frob...
[linux-2.6.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU(PAGE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      BSS_SECTION(0, 0, 0)
34  *      _end = .;
35  *
36  *      STABS_DEBUG
37  *      DWARF_DEBUG
38  *
39  *      DISCARDS                // must be the last
40  * }
41  *
42  * [__init_begin, __init_end] is the init section that may be freed after init
43  * [_stext, _etext] is the text section
44  * [_sdata, _edata] is the data section
45  *
46  * Some of the included output section have their own set of constants.
47  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48  *               [__nosave_begin, __nosave_end] for the nosave data
49  */
50
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
54
55 #ifndef VMLINUX_SYMBOL
56 #define VMLINUX_SYMBOL(_sym_) _sym_
57 #endif
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION()  . = ALIGN(8)
61
62 /* The actual configuration determine if the init/exit sections
63  * are handled as text/data or they can be discarded (which
64  * often happens at runtime)
65  */
66 #ifdef CONFIG_HOTPLUG
67 #define DEV_KEEP(sec)    *(.dev##sec)
68 #define DEV_DISCARD(sec)
69 #else
70 #define DEV_KEEP(sec)
71 #define DEV_DISCARD(sec) *(.dev##sec)
72 #endif
73
74 #ifdef CONFIG_HOTPLUG_CPU
75 #define CPU_KEEP(sec)    *(.cpu##sec)
76 #define CPU_DISCARD(sec)
77 #else
78 #define CPU_KEEP(sec)
79 #define CPU_DISCARD(sec) *(.cpu##sec)
80 #endif
81
82 #if defined(CONFIG_MEMORY_HOTPLUG)
83 #define MEM_KEEP(sec)    *(.mem##sec)
84 #define MEM_DISCARD(sec)
85 #else
86 #define MEM_KEEP(sec)
87 #define MEM_DISCARD(sec) *(.mem##sec)
88 #endif
89
90 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
91 #define MCOUNT_REC()    . = ALIGN(8);                           \
92                         VMLINUX_SYMBOL(__start_mcount_loc) = .; \
93                         *(__mcount_loc)                         \
94                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
95 #else
96 #define MCOUNT_REC()
97 #endif
98
99 #ifdef CONFIG_TRACE_BRANCH_PROFILING
100 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
101                                 *(_ftrace_annotated_branch)                           \
102                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
103 #else
104 #define LIKELY_PROFILE()
105 #endif
106
107 #ifdef CONFIG_PROFILE_ALL_BRANCHES
108 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
109                                 *(_ftrace_branch)                             \
110                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
111 #else
112 #define BRANCH_PROFILE()
113 #endif
114
115 #ifdef CONFIG_EVENT_TRACING
116 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
117                         *(_ftrace_events)                               \
118                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
119 #else
120 #define FTRACE_EVENTS()
121 #endif
122
123 #ifdef CONFIG_TRACING
124 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
125                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
126                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
127 #else
128 #define TRACE_PRINTKS()
129 #endif
130
131 #ifdef CONFIG_FTRACE_SYSCALLS
132 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
133                          *(__syscalls_metadata)                         \
134                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
135 #else
136 #define TRACE_SYSCALLS()
137 #endif
138
139 /* .data section */
140 #define DATA_DATA                                                       \
141         *(.data)                                                        \
142         *(.ref.data)                                                    \
143         DEV_KEEP(init.data)                                             \
144         DEV_KEEP(exit.data)                                             \
145         CPU_KEEP(init.data)                                             \
146         CPU_KEEP(exit.data)                                             \
147         MEM_KEEP(init.data)                                             \
148         MEM_KEEP(exit.data)                                             \
149         . = ALIGN(8);                                                   \
150         VMLINUX_SYMBOL(__start___markers) = .;                          \
151         *(__markers)                                                    \
152         VMLINUX_SYMBOL(__stop___markers) = .;                           \
153         . = ALIGN(32);                                                  \
154         VMLINUX_SYMBOL(__start___tracepoints) = .;                      \
155         *(__tracepoints)                                                \
156         VMLINUX_SYMBOL(__stop___tracepoints) = .;                       \
157         /* implement dynamic printk debug */                            \
158         . = ALIGN(8);                                                   \
159         VMLINUX_SYMBOL(__start___verbose) = .;                          \
160         *(__verbose)                                                    \
161         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
162         LIKELY_PROFILE()                                                \
163         BRANCH_PROFILE()                                                \
164         TRACE_PRINTKS()                                                 \
165         FTRACE_EVENTS()                                                 \
166         TRACE_SYSCALLS()
167
168 /*
169  * Data section helpers
170  */
171 #define NOSAVE_DATA                                                     \
172         . = ALIGN(PAGE_SIZE);                                           \
173         VMLINUX_SYMBOL(__nosave_begin) = .;                             \
174         *(.data.nosave)                                                 \
175         . = ALIGN(PAGE_SIZE);                                           \
176         VMLINUX_SYMBOL(__nosave_end) = .;
177
178 #define PAGE_ALIGNED_DATA(page_align)                                   \
179         . = ALIGN(page_align);                                          \
180         *(.data.page_aligned)
181
182 #define READ_MOSTLY_DATA(align)                                         \
183         . = ALIGN(align);                                               \
184         *(.data.read_mostly)
185
186 #define CACHELINE_ALIGNED_DATA(align)                                   \
187         . = ALIGN(align);                                               \
188         *(.data.cacheline_aligned)
189
190 #define INIT_TASK_DATA(align)                                           \
191         . = ALIGN(align);                                               \
192         *(.data.init_task)
193
194 /*
195  * Read only Data
196  */
197 #define RO_DATA_SECTION(align)                                          \
198         . = ALIGN((align));                                             \
199         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
200                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
201                 *(.rodata) *(.rodata.*)                                 \
202                 *(__vermagic)           /* Kernel version magic */      \
203                 *(__markers_strings)    /* Markers: strings */          \
204                 *(__tracepoints_strings)/* Tracepoints: strings */      \
205         }                                                               \
206                                                                         \
207         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
208                 *(.rodata1)                                             \
209         }                                                               \
210                                                                         \
211         BUG_TABLE                                                       \
212                                                                         \
213         /* PCI quirks */                                                \
214         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
215                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
216                 *(.pci_fixup_early)                                     \
217                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
218                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
219                 *(.pci_fixup_header)                                    \
220                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
221                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
222                 *(.pci_fixup_final)                                     \
223                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
224                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
225                 *(.pci_fixup_enable)                                    \
226                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
227                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
228                 *(.pci_fixup_resume)                                    \
229                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
230                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
231                 *(.pci_fixup_resume_early)                              \
232                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
233                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
234                 *(.pci_fixup_suspend)                                   \
235                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
236         }                                                               \
237                                                                         \
238         /* Built-in firmware blobs */                                   \
239         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
240                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
241                 *(.builtin_fw)                                          \
242                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
243         }                                                               \
244                                                                         \
245         /* RapidIO route ops */                                         \
246         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
247                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
248                 *(.rio_route_ops)                                       \
249                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
250         }                                                               \
251                                                                         \
252         TRACEDATA                                                       \
253                                                                         \
254         /* Kernel symbol table: Normal symbols */                       \
255         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
256                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
257                 *(__ksymtab)                                            \
258                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
259         }                                                               \
260                                                                         \
261         /* Kernel symbol table: GPL-only symbols */                     \
262         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
263                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
264                 *(__ksymtab_gpl)                                        \
265                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
266         }                                                               \
267                                                                         \
268         /* Kernel symbol table: Normal unused symbols */                \
269         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
270                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
271                 *(__ksymtab_unused)                                     \
272                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
273         }                                                               \
274                                                                         \
275         /* Kernel symbol table: GPL-only unused symbols */              \
276         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
277                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
278                 *(__ksymtab_unused_gpl)                                 \
279                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
280         }                                                               \
281                                                                         \
282         /* Kernel symbol table: GPL-future-only symbols */              \
283         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
284                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
285                 *(__ksymtab_gpl_future)                                 \
286                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
287         }                                                               \
288                                                                         \
289         /* Kernel symbol table: Normal symbols */                       \
290         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
291                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
292                 *(__kcrctab)                                            \
293                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
294         }                                                               \
295                                                                         \
296         /* Kernel symbol table: GPL-only symbols */                     \
297         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
298                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
299                 *(__kcrctab_gpl)                                        \
300                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
301         }                                                               \
302                                                                         \
303         /* Kernel symbol table: Normal unused symbols */                \
304         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
305                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
306                 *(__kcrctab_unused)                                     \
307                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
308         }                                                               \
309                                                                         \
310         /* Kernel symbol table: GPL-only unused symbols */              \
311         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
312                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
313                 *(__kcrctab_unused_gpl)                                 \
314                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
315         }                                                               \
316                                                                         \
317         /* Kernel symbol table: GPL-future-only symbols */              \
318         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
319                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
320                 *(__kcrctab_gpl_future)                                 \
321                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
322         }                                                               \
323                                                                         \
324         /* Kernel symbol table: strings */                              \
325         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
326                 *(__ksymtab_strings)                                    \
327         }                                                               \
328                                                                         \
329         /* __*init sections */                                          \
330         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
331                 *(.ref.rodata)                                          \
332                 DEV_KEEP(init.rodata)                                   \
333                 DEV_KEEP(exit.rodata)                                   \
334                 CPU_KEEP(init.rodata)                                   \
335                 CPU_KEEP(exit.rodata)                                   \
336                 MEM_KEEP(init.rodata)                                   \
337                 MEM_KEEP(exit.rodata)                                   \
338         }                                                               \
339                                                                         \
340         /* Built-in module parameters. */                               \
341         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
342                 VMLINUX_SYMBOL(__start___param) = .;                    \
343                 *(__param)                                              \
344                 VMLINUX_SYMBOL(__stop___param) = .;                     \
345                 . = ALIGN((align));                                     \
346                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
347         }                                                               \
348         . = ALIGN((align));
349
350 /* RODATA & RO_DATA provided for backward compatibility.
351  * All archs are supposed to use RO_DATA() */
352 #define RODATA          RO_DATA_SECTION(4096)
353 #define RO_DATA(align)  RO_DATA_SECTION(align)
354
355 #define SECURITY_INIT                                                   \
356         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
357                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
358                 *(.security_initcall.init)                              \
359                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
360         }
361
362 /* .text section. Map to function alignment to avoid address changes
363  * during second ld run in second ld pass when generating System.map */
364 #define TEXT_TEXT                                                       \
365                 ALIGN_FUNCTION();                                       \
366                 *(.text.hot)                                            \
367                 *(.text)                                                \
368                 *(.ref.text)                                            \
369         DEV_KEEP(init.text)                                             \
370         DEV_KEEP(exit.text)                                             \
371         CPU_KEEP(init.text)                                             \
372         CPU_KEEP(exit.text)                                             \
373         MEM_KEEP(init.text)                                             \
374         MEM_KEEP(exit.text)                                             \
375                 *(.text.unlikely)
376
377
378 /* sched.text is aling to function alignment to secure we have same
379  * address even at second ld pass when generating System.map */
380 #define SCHED_TEXT                                                      \
381                 ALIGN_FUNCTION();                                       \
382                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
383                 *(.sched.text)                                          \
384                 VMLINUX_SYMBOL(__sched_text_end) = .;
385
386 /* spinlock.text is aling to function alignment to secure we have same
387  * address even at second ld pass when generating System.map */
388 #define LOCK_TEXT                                                       \
389                 ALIGN_FUNCTION();                                       \
390                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
391                 *(.spinlock.text)                                       \
392                 VMLINUX_SYMBOL(__lock_text_end) = .;
393
394 #define KPROBES_TEXT                                                    \
395                 ALIGN_FUNCTION();                                       \
396                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
397                 *(.kprobes.text)                                        \
398                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
399
400 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
401 #define IRQENTRY_TEXT                                                   \
402                 ALIGN_FUNCTION();                                       \
403                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
404                 *(.irqentry.text)                                       \
405                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
406 #else
407 #define IRQENTRY_TEXT
408 #endif
409
410 /* Section used for early init (in .S files) */
411 #define HEAD_TEXT  *(.head.text)
412
413 #define HEAD_TEXT_SECTION                                                       \
414         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
415                 HEAD_TEXT                                               \
416         }
417
418 /*
419  * Exception table
420  */
421 #define EXCEPTION_TABLE(align)                                          \
422         . = ALIGN(align);                                               \
423         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
424                 VMLINUX_SYMBOL(__start___ex_table) = .;                 \
425                 *(__ex_table)                                           \
426                 VMLINUX_SYMBOL(__stop___ex_table) = .;                  \
427         }
428
429 /*
430  * Init task
431  */
432 #define INIT_TASK_DATA_SECTION(align)                                   \
433         . = ALIGN(align);                                               \
434         .data.init_task : {                                             \
435                 INIT_TASK_DATA(align)                                   \
436         }
437
438 #ifdef CONFIG_CONSTRUCTORS
439 #define KERNEL_CTORS()  . = ALIGN(8);                      \
440                         VMLINUX_SYMBOL(__ctors_start) = .; \
441                         *(.ctors)                          \
442                         VMLINUX_SYMBOL(__ctors_end) = .;
443 #else
444 #define KERNEL_CTORS()
445 #endif
446
447 /* init and exit section handling */
448 #define INIT_DATA                                                       \
449         *(.init.data)                                                   \
450         DEV_DISCARD(init.data)                                          \
451         CPU_DISCARD(init.data)                                          \
452         MEM_DISCARD(init.data)                                          \
453         KERNEL_CTORS()                                                  \
454         *(.init.rodata)                                                 \
455         MCOUNT_REC()                                                    \
456         DEV_DISCARD(init.rodata)                                        \
457         CPU_DISCARD(init.rodata)                                        \
458         MEM_DISCARD(init.rodata)
459
460 #define INIT_TEXT                                                       \
461         *(.init.text)                                                   \
462         DEV_DISCARD(init.text)                                          \
463         CPU_DISCARD(init.text)                                          \
464         MEM_DISCARD(init.text)
465
466 #define EXIT_DATA                                                       \
467         *(.exit.data)                                                   \
468         DEV_DISCARD(exit.data)                                          \
469         DEV_DISCARD(exit.rodata)                                        \
470         CPU_DISCARD(exit.data)                                          \
471         CPU_DISCARD(exit.rodata)                                        \
472         MEM_DISCARD(exit.data)                                          \
473         MEM_DISCARD(exit.rodata)
474
475 #define EXIT_TEXT                                                       \
476         *(.exit.text)                                                   \
477         DEV_DISCARD(exit.text)                                          \
478         CPU_DISCARD(exit.text)                                          \
479         MEM_DISCARD(exit.text)
480
481 #define EXIT_CALL                                                       \
482         *(.exitcall.exit)
483
484 /*
485  * bss (Block Started by Symbol) - uninitialized data
486  * zeroed during startup
487  */
488 #define SBSS(sbss_align)                                                \
489         . = ALIGN(sbss_align);                                          \
490         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
491                 *(.sbss)                                                \
492                 *(.scommon)                                             \
493         }
494
495 #define BSS(bss_align)                                                  \
496         . = ALIGN(bss_align);                                           \
497         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
498                 *(.bss.page_aligned)                                    \
499                 *(.dynbss)                                              \
500                 *(.bss)                                                 \
501                 *(COMMON)                                               \
502         }
503
504 /*
505  * DWARF debug sections.
506  * Symbols in the DWARF debugging sections are relative to
507  * the beginning of the section so we begin them at 0.
508  */
509 #define DWARF_DEBUG                                                     \
510                 /* DWARF 1 */                                           \
511                 .debug          0 : { *(.debug) }                       \
512                 .line           0 : { *(.line) }                        \
513                 /* GNU DWARF 1 extensions */                            \
514                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
515                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
516                 /* DWARF 1.1 and DWARF 2 */                             \
517                 .debug_aranges  0 : { *(.debug_aranges) }               \
518                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
519                 /* DWARF 2 */                                           \
520                 .debug_info     0 : { *(.debug_info                     \
521                                 .gnu.linkonce.wi.*) }                   \
522                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
523                 .debug_line     0 : { *(.debug_line) }                  \
524                 .debug_frame    0 : { *(.debug_frame) }                 \
525                 .debug_str      0 : { *(.debug_str) }                   \
526                 .debug_loc      0 : { *(.debug_loc) }                   \
527                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
528                 /* SGI/MIPS DWARF 2 extensions */                       \
529                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
530                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
531                 .debug_typenames 0 : { *(.debug_typenames) }            \
532                 .debug_varnames  0 : { *(.debug_varnames) }             \
533
534                 /* Stabs debugging sections.  */
535 #define STABS_DEBUG                                                     \
536                 .stab 0 : { *(.stab) }                                  \
537                 .stabstr 0 : { *(.stabstr) }                            \
538                 .stab.excl 0 : { *(.stab.excl) }                        \
539                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
540                 .stab.index 0 : { *(.stab.index) }                      \
541                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
542                 .comment 0 : { *(.comment) }
543
544 #ifdef CONFIG_GENERIC_BUG
545 #define BUG_TABLE                                                       \
546         . = ALIGN(8);                                                   \
547         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
548                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
549                 *(__bug_table)                                          \
550                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
551         }
552 #else
553 #define BUG_TABLE
554 #endif
555
556 #ifdef CONFIG_PM_TRACE
557 #define TRACEDATA                                                       \
558         . = ALIGN(4);                                                   \
559         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
560                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
561                 *(.tracedata)                                           \
562                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
563         }
564 #else
565 #define TRACEDATA
566 #endif
567
568 #define NOTES                                                           \
569         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
570                 VMLINUX_SYMBOL(__start_notes) = .;                      \
571                 *(.note.*)                                              \
572                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
573         }
574
575 #define INIT_SETUP(initsetup_align)                                     \
576                 . = ALIGN(initsetup_align);                             \
577                 VMLINUX_SYMBOL(__setup_start) = .;                      \
578                 *(.init.setup)                                          \
579                 VMLINUX_SYMBOL(__setup_end) = .;
580
581 #define INITCALLS                                                       \
582         *(.initcallearly.init)                                          \
583         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
584         *(.initcall0.init)                                              \
585         *(.initcall0s.init)                                             \
586         *(.initcall1.init)                                              \
587         *(.initcall1s.init)                                             \
588         *(.initcall2.init)                                              \
589         *(.initcall2s.init)                                             \
590         *(.initcall3.init)                                              \
591         *(.initcall3s.init)                                             \
592         *(.initcall4.init)                                              \
593         *(.initcall4s.init)                                             \
594         *(.initcall5.init)                                              \
595         *(.initcall5s.init)                                             \
596         *(.initcallrootfs.init)                                         \
597         *(.initcall6.init)                                              \
598         *(.initcall6s.init)                                             \
599         *(.initcall7.init)                                              \
600         *(.initcall7s.init)
601
602 #define INIT_CALLS                                                      \
603                 VMLINUX_SYMBOL(__initcall_start) = .;                   \
604                 INITCALLS                                               \
605                 VMLINUX_SYMBOL(__initcall_end) = .;
606
607 #define CON_INITCALL                                                    \
608                 VMLINUX_SYMBOL(__con_initcall_start) = .;               \
609                 *(.con_initcall.init)                                   \
610                 VMLINUX_SYMBOL(__con_initcall_end) = .;
611
612 #define SECURITY_INITCALL                                               \
613                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
614                 *(.security_initcall.init)                              \
615                 VMLINUX_SYMBOL(__security_initcall_end) = .;
616
617 #ifdef CONFIG_BLK_DEV_INITRD
618 #define INIT_RAM_FS                                                     \
619         . = ALIGN(PAGE_SIZE);                                           \
620         VMLINUX_SYMBOL(__initramfs_start) = .;                          \
621         *(.init.ramfs)                                                  \
622         VMLINUX_SYMBOL(__initramfs_end) = .;
623 #else
624 #define INIT_RAM_FS
625 #endif
626
627 /*
628  * Default discarded sections.
629  *
630  * Some archs want to discard exit text/data at runtime rather than
631  * link time due to cross-section references such as alt instructions,
632  * bug table, eh_frame, etc.  DISCARDS must be the last of output
633  * section definitions so that such archs put those in earlier section
634  * definitions.
635  */
636 #define DISCARDS                                                        \
637         /DISCARD/ : {                                                   \
638         EXIT_TEXT                                                       \
639         EXIT_DATA                                                       \
640         EXIT_CALL                                                       \
641         *(.discard)                                                     \
642         }
643
644 /**
645  * PERCPU_VADDR - define output section for percpu area
646  * @vaddr: explicit base address (optional)
647  * @phdr: destination PHDR (optional)
648  *
649  * Macro which expands to output section for percpu area.  If @vaddr
650  * is not blank, it specifies explicit base address and all percpu
651  * symbols will be offset from the given address.  If blank, @vaddr
652  * always equals @laddr + LOAD_OFFSET.
653  *
654  * @phdr defines the output PHDR to use if not blank.  Be warned that
655  * output PHDR is sticky.  If @phdr is specified, the next output
656  * section in the linker script will go there too.  @phdr should have
657  * a leading colon.
658  *
659  * Note that this macros defines __per_cpu_load as an absolute symbol.
660  * If there is no need to put the percpu section at a predetermined
661  * address, use PERCPU().
662  */
663 #define PERCPU_VADDR(vaddr, phdr)                                       \
664         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
665         .data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)          \
666                                 - LOAD_OFFSET) {                        \
667                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
668                 *(.data.percpu.first)                                   \
669                 *(.data.percpu.page_aligned)                            \
670                 *(.data.percpu)                                         \
671                 *(.data.percpu.shared_aligned)                          \
672                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
673         } phdr                                                          \
674         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);
675
676 /**
677  * PERCPU - define output section for percpu area, simple version
678  * @align: required alignment
679  *
680  * Align to @align and outputs output section for percpu area.  This
681  * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
682  * __per_cpu_start will be identical.
683  *
684  * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
685  * that __per_cpu_load is defined as a relative symbol against
686  * .data.percpu which is required for relocatable x86_32
687  * configuration.
688  */
689 #define PERCPU(align)                                                   \
690         . = ALIGN(align);                                               \
691         .data.percpu    : AT(ADDR(.data.percpu) - LOAD_OFFSET) {        \
692                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
693                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
694                 *(.data.percpu.first)                                   \
695                 *(.data.percpu.page_aligned)                            \
696                 *(.data.percpu)                                         \
697                 *(.data.percpu.shared_aligned)                          \
698                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
699         }
700
701
702 /*
703  * Definition of the high level *_SECTION macros
704  * They will fit only a subset of the architectures
705  */
706
707
708 /*
709  * Writeable data.
710  * All sections are combined in a single .data section.
711  * The sections following CONSTRUCTORS are arranged so their
712  * typical alignment matches.
713  * A cacheline is typical/always less than a PAGE_SIZE so
714  * the sections that has this restriction (or similar)
715  * is located before the ones requiring PAGE_SIZE alignment.
716  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
717  * matches the requirment of PAGE_ALIGNED_DATA.
718  *
719  * use 0 as page_align if page_aligned data is not used */
720 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
721         . = ALIGN(PAGE_SIZE);                                           \
722         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
723                 INIT_TASK_DATA(inittask)                                \
724                 CACHELINE_ALIGNED_DATA(cacheline)                       \
725                 READ_MOSTLY_DATA(cacheline)                             \
726                 DATA_DATA                                               \
727                 CONSTRUCTORS                                            \
728                 NOSAVE_DATA                                             \
729                 PAGE_ALIGNED_DATA(pagealigned)                          \
730         }
731
732 #define INIT_TEXT_SECTION(inittext_align)                               \
733         . = ALIGN(inittext_align);                                      \
734         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
735                 VMLINUX_SYMBOL(_sinittext) = .;                         \
736                 INIT_TEXT                                               \
737                 VMLINUX_SYMBOL(_einittext) = .;                         \
738         }
739
740 #define INIT_DATA_SECTION(initsetup_align)                              \
741         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
742                 INIT_DATA                                               \
743                 INIT_SETUP(initsetup_align)                             \
744                 INIT_CALLS                                              \
745                 CON_INITCALL                                            \
746                 SECURITY_INITCALL                                       \
747                 INIT_RAM_FS                                             \
748         }
749
750 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
751         . = ALIGN(sbss_align);                                          \
752         VMLINUX_SYMBOL(__bss_start) = .;                                \
753         SBSS(sbss_align)                                                \
754         BSS(bss_align)                                                  \
755         . = ALIGN(stop_align);                                          \
756         VMLINUX_SYMBOL(__bss_stop) = .;