[POWERPC] Use PAGE_OFFSET to tell if an address is user/kernel in SW TLB handlers
[linux-2.6.git] / arch / x86_64 / vdso / vdso.lds.S
1 /*
2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
3  * object prelinked to its virtual address, and with only one read-only
4  * segment (that fits in one page).  This script controls its layout.
5  */
6 #include <asm/asm-offsets.h>
7 #include "voffset.h"
8
9 #define VDSO_PRELINK 0xffffffffff700000
10
11 SECTIONS
12 {
13   . = VDSO_PRELINK + SIZEOF_HEADERS;
14
15   .hash           : { *(.hash) }                :text
16   .gnu.hash       : { *(.gnu.hash) }
17   .dynsym         : { *(.dynsym) }
18   .dynstr         : { *(.dynstr) }
19   .gnu.version    : { *(.gnu.version) }
20   .gnu.version_d  : { *(.gnu.version_d) }
21   .gnu.version_r  : { *(.gnu.version_r) }
22
23   /* This linker script is used both with -r and with -shared.
24      For the layouts to match, we need to skip more than enough
25      space for the dynamic symbol table et al.  If this amount
26      is insufficient, ld -shared will barf.  Just increase it here.  */
27   . = VDSO_PRELINK + VDSO_TEXT_OFFSET;
28
29   .text           : { *(.text) }                :text
30   .text.ptr       : { *(.text.ptr) }            :text
31   . = VDSO_PRELINK + 0x900;
32   .data           : { *(.data) }                :text
33   .bss            : { *(.bss) }                 :text
34
35   .altinstructions : { *(.altinstructions) }                    :text
36   .altinstr_replacement  : { *(.altinstr_replacement) } :text
37
38   .note           : { *(.note.*) }              :text :note
39   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
40   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
41   .dynamic        : { *(.dynamic) }             :text :dynamic
42   .useless        : {
43         *(.got.plt) *(.got)
44         *(.gnu.linkonce.d.*)
45         *(.dynbss)
46         *(.gnu.linkonce.b.*)
47   }                                             :text
48 }
49
50 /*
51  * We must supply the ELF program headers explicitly to get just one
52  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
53  */
54 PHDRS
55 {
56   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
57   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
58   note PT_NOTE FLAGS(4); /* PF_R */
59   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
60 }
61
62 /*
63  * This controls what symbols we export from the DSO.
64  */
65 VERSION
66 {
67   LINUX_2.6 {
68     global:
69         clock_gettime;
70         __vdso_clock_gettime;
71         gettimeofday;
72         __vdso_gettimeofday;
73         getcpu;
74         __vdso_getcpu;
75     local: *;
76   };
77 }