Merge git://git.kernel.org/pub/scm/linux/kernel/git/davem/sparc-2.6
[linux-2.6.git] / arch / x86 / kernel / trampoline_32.S
1 /*
2  *
3  *      Trampoline.S    Derived from Setup.S by Linus Torvalds
4  *
5  *      4 Jan 1997 Michael Chastain: changed to gnu as.
6  *
7  *      This is only used for booting secondary CPUs in SMP machine
8  *
9  *      Entry: CS:IP point to the start of our code, we are 
10  *      in real mode with no stack, but the rest of the 
11  *      trampoline page to make our stack and everything else
12  *      is a mystery.
13  *
14  *      We jump into arch/x86/kernel/head_32.S.
15  *
16  *      On entry to trampoline_data, the processor is in real mode
17  *      with 16-bit addressing and 16-bit data.  CS has some value
18  *      and IP is zero.  Thus, data addresses need to be absolute
19  *      (no relocation) and are taken with regard to r_base.
20  *
21  *      If you work on this file, check the object module with
22  *      objdump --reloc to make sure there are no relocation
23  *      entries except for:
24  *
25  *      TYPE              VALUE
26  *      R_386_32          startup_32_smp
27  *      R_386_32          boot_gdt
28  */
29
30 #include <linux/linkage.h>
31 #include <linux/init.h>
32 #include <asm/segment.h>
33 #include <asm/page_types.h>
34
35 /* We can free up trampoline after bootup if cpu hotplug is not supported. */
36 __CPUINITRODATA
37 .code16
38
39 ENTRY(trampoline_data)
40 r_base = .
41         wbinvd                  # Needed for NUMA-Q should be harmless for others
42         mov     %cs, %ax        # Code and data in the same place
43         mov     %ax, %ds
44
45         cli                     # We should be safe anyway
46
47         movl    $0xA5A5A5A5, trampoline_data - r_base
48                                 # write marker for master knows we're running
49
50         /* GDT tables in non default location kernel can be beyond 16MB and
51          * lgdt will not be able to load the address as in real mode default
52          * operand size is 16bit. Use lgdtl instead to force operand size
53          * to 32 bit.
54          */
55
56         lidtl   boot_idt_descr - r_base # load idt with 0, 0
57         lgdtl   boot_gdt_descr - r_base # load gdt with whatever is appropriate
58
59         xor     %ax, %ax
60         inc     %ax             # protected mode (PE) bit
61         lmsw    %ax             # into protected mode
62         # flush prefetch and jump to startup_32_smp in arch/i386/kernel/head.S
63         ljmpl   $__BOOT_CS, $(startup_32_smp-__PAGE_OFFSET)
64
65         # These need to be in the same 64K segment as the above;
66         # hence we don't use the boot_gdt_descr defined in head.S
67 boot_gdt_descr:
68         .word   __BOOT_DS + 7                   # gdt limit
69         .long   boot_gdt - __PAGE_OFFSET        # gdt base
70
71 boot_idt_descr:
72         .word   0                               # idt limit = 0
73         .long   0                               # idt base = 0L
74
75 .globl trampoline_end
76 trampoline_end: