[S390] add kprobes annotations
[linux-2.6.git] / arch / s390 / kernel / entry64.S
1 /*
2  *  arch/s390/kernel/entry64.S
3  *    S390 low-level entry points.
4  *
5  *    Copyright (C) IBM Corp. 1999,2010
6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
7  *               Hartmut Penner (hp@de.ibm.com),
8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
10  */
11
12 #include <linux/linkage.h>
13 #include <linux/init.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21
22 /*
23  * Stack layout for the system_call stack entry.
24  * The first few entries are identical to the user_regs_struct.
25  */
26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
46 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
47 SP_SVCNR      = STACK_FRAME_OVERHEAD + __PT_SVCNR
48 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
49
50 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
51 STACK_SIZE  = 1 << STACK_SHIFT
52
53 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
54                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
55 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
56                  _TIF_MCCK_PENDING)
57 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
58                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
59
60 #define BASED(name) name-system_call(%r13)
61
62         .macro  HANDLE_SIE_INTERCEPT
63 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
64         lg      %r3,__LC_SIE_HOOK
65         ltgr    %r3,%r3
66         jz      0f
67         basr    %r14,%r3
68 0:
69 #endif
70         .endm
71
72 #ifdef CONFIG_TRACE_IRQFLAGS
73         .macro  TRACE_IRQS_ON
74         basr    %r2,%r0
75         brasl   %r14,trace_hardirqs_on_caller
76         .endm
77
78         .macro  TRACE_IRQS_OFF
79         basr    %r2,%r0
80         brasl   %r14,trace_hardirqs_off_caller
81         .endm
82 #else
83 #define TRACE_IRQS_ON
84 #define TRACE_IRQS_OFF
85 #endif
86
87 #ifdef CONFIG_LOCKDEP
88         .macro  LOCKDEP_SYS_EXIT
89         tm      SP_PSW+1(%r15),0x01     # returning to user ?
90         jz      0f
91         brasl   %r14,lockdep_sys_exit
92 0:
93         .endm
94 #else
95 #define LOCKDEP_SYS_EXIT
96 #endif
97
98         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
99         lg      %r10,\lc_from
100         slg     %r10,\lc_to
101         alg     %r10,\lc_sum
102         stg     %r10,\lc_sum
103         .endm
104
105 /*
106  * Register usage in interrupt handlers:
107  *    R9  - pointer to current task structure
108  *    R13 - pointer to literal pool
109  *    R14 - return register for function calls
110  *    R15 - kernel stack pointer
111  */
112
113         .macro  SAVE_ALL_SVC psworg,savearea
114         stmg    %r11,%r15,\savearea
115         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
116         aghi    %r15,-SP_SIZE           # make room for registers & psw
117         lg      %r11,__LC_LAST_BREAK
118         .endm
119
120         .macro  SAVE_ALL_PGM psworg,savearea
121         stmg    %r11,%r15,\savearea
122         tm      \psworg+1,0x01          # test problem state bit
123 #ifdef CONFIG_CHECK_STACK
124         jnz     1f
125         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
126         jnz     2f
127         la      %r12,\psworg
128         j       stack_overflow
129 #else
130         jz      2f
131 #endif
132 1:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
133 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
134         larl    %r13,system_call
135         lg      %r11,__LC_LAST_BREAK
136         .endm
137
138         .macro  SAVE_ALL_ASYNC psworg,savearea
139         stmg    %r11,%r15,\savearea
140         larl    %r13,system_call
141         lg      %r11,__LC_LAST_BREAK
142         la      %r12,\psworg
143         tm      \psworg+1,0x01          # test problem state bit
144         jnz     1f                      # from user -> load kernel stack
145         clc     \psworg+8(8),BASED(.Lcritical_end)
146         jhe     0f
147         clc     \psworg+8(8),BASED(.Lcritical_start)
148         jl      0f
149         brasl   %r14,cleanup_critical
150         tm      1(%r12),0x01            # retest problem state after cleanup
151         jnz     1f
152 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
153         slgr    %r14,%r15
154         srag    %r14,%r14,STACK_SHIFT
155 #ifdef CONFIG_CHECK_STACK
156         jnz     1f
157         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
158         jnz     2f
159         j       stack_overflow
160 #else
161         jz      2f
162 #endif
163 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
164 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
165         .endm
166
167         .macro  CREATE_STACK_FRAME savearea
168         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
169         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
170         mvc     SP_R11(40,%r15),\savearea # move %r11-%r15 to stack
171         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
172         .endm
173
174         .macro  RESTORE_ALL psworg,sync
175         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
176         .if !\sync
177         ni      \psworg+1,0xfd          # clear wait state bit
178         .endif
179         lg      %r14,__LC_VDSO_PER_CPU
180         lmg     %r0,%r13,SP_R0(%r15)    # load gprs 0-13 of user
181         stpt    __LC_EXIT_TIMER
182         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
183         lmg     %r14,%r15,SP_R14(%r15)  # load grps 14-15 of user
184         lpswe   \psworg                 # back to caller
185         .endm
186
187         .macro  LAST_BREAK
188         srag    %r10,%r11,23
189         jz      0f
190         stg     %r11,__TI_last_break(%r12)
191 0:
192         .endm
193
194         .macro REENABLE_IRQS
195         mvc     __SF_EMPTY(1,%r15),SP_PSW(%r15)
196         ni      __SF_EMPTY(%r15),0xbf
197         ssm     __SF_EMPTY(%r15)
198         .endm
199
200         .section .kprobes.text, "ax"
201
202 /*
203  * Scheduler resume function, called by switch_to
204  *  gpr2 = (task_struct *) prev
205  *  gpr3 = (task_struct *) next
206  * Returns:
207  *  gpr2 = prev
208  */
209         .globl  __switch_to
210 __switch_to:
211         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
212         jz      __switch_to_noper               # if not we're fine
213         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
214         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
215         je      __switch_to_noper            # we got away without bashing TLB's
216         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
217 __switch_to_noper:
218         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
219         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
220         jz      __switch_to_no_mcck
221         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
222         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
223         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
224 __switch_to_no_mcck:
225         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
226         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
227         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
228         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
229         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
230         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
231         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
232         stg     %r3,__LC_THREAD_INFO
233         aghi    %r3,STACK_SIZE
234         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
235         br      %r14
236
237 __critical_start:
238 /*
239  * SVC interrupt handler routine. System calls are synchronous events and
240  * are executed with interrupts enabled.
241  */
242
243         .globl  system_call
244 system_call:
245         stpt    __LC_SYNC_ENTER_TIMER
246 sysc_saveall:
247         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
248         CREATE_STACK_FRAME __LC_SAVE_AREA
249         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
250         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
251         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
252 sysc_vtime:
253         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
254 sysc_stime:
255         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
256 sysc_update:
257         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
258         LAST_BREAK
259 sysc_do_svc:
260         llgh    %r7,SP_SVCNR(%r15)
261         slag    %r7,%r7,2       # shift and test for svc 0
262         jnz     sysc_nr_ok
263         # svc 0: system call number in %r1
264         llgfr   %r1,%r1         # clear high word in r1
265         cghi    %r1,NR_syscalls
266         jnl     sysc_nr_ok
267         sth     %r1,SP_SVCNR(%r15)
268         slag    %r7,%r1,2       # shift and test for svc 0
269 sysc_nr_ok:
270         larl    %r10,sys_call_table
271 #ifdef CONFIG_COMPAT
272         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)  # running in 31 bit mode ?
273         jno     sysc_noemu
274         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
275 sysc_noemu:
276 #endif
277         tm      __TI_flags+6(%r12),_TIF_SYSCALL
278         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
279         lgf     %r8,0(%r7,%r10) # load address of system call routine
280         jnz     sysc_tracesys
281         basr    %r14,%r8        # call sys_xxxx
282         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
283
284 sysc_return:
285         LOCKDEP_SYS_EXIT
286 sysc_tif:
287         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
288         jnz     sysc_work       # there is work to do (signals etc.)
289 sysc_restore:
290         RESTORE_ALL __LC_RETURN_PSW,1
291 sysc_done:
292
293 #
294 # There is work to do, but first we need to check if we return to userspace.
295 #
296 sysc_work:
297         tm      SP_PSW+1(%r15),0x01     # returning to user ?
298         jno     sysc_restore
299
300 #
301 # One of the work bits is on. Find out which one.
302 #
303 sysc_work_tif:
304         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
305         jo      sysc_mcck_pending
306         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
307         jo      sysc_reschedule
308         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
309         jo      sysc_sigpending
310         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
311         jo      sysc_notify_resume
312         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
313         jo      sysc_restart
314         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
315         jo      sysc_singlestep
316         j       sysc_return             # beware of critical section cleanup
317
318 #
319 # _TIF_NEED_RESCHED is set, call schedule
320 #
321 sysc_reschedule:
322         larl    %r14,sysc_return
323         jg      schedule                # return point is sysc_return
324
325 #
326 # _TIF_MCCK_PENDING is set, call handler
327 #
328 sysc_mcck_pending:
329         larl    %r14,sysc_return
330         jg      s390_handle_mcck        # TIF bit will be cleared by handler
331
332 #
333 # _TIF_SIGPENDING is set, call do_signal
334 #
335 sysc_sigpending:
336         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
337         la      %r2,SP_PTREGS(%r15)     # load pt_regs
338         brasl   %r14,do_signal          # call do_signal
339         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
340         jo      sysc_restart
341         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
342         jo      sysc_singlestep
343         j       sysc_return
344
345 #
346 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
347 #
348 sysc_notify_resume:
349         la      %r2,SP_PTREGS(%r15)     # load pt_regs
350         larl    %r14,sysc_return
351         jg      do_notify_resume        # call do_notify_resume
352
353 #
354 # _TIF_RESTART_SVC is set, set up registers and restart svc
355 #
356 sysc_restart:
357         ni      __TI_flags+7(%r12),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
358         lg      %r7,SP_R2(%r15)         # load new svc number
359         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
360         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
361         sth     %r7,SP_SVCNR(%r15)
362         slag    %r7,%r7,2
363         j       sysc_nr_ok              # restart svc
364
365 #
366 # _TIF_SINGLE_STEP is set, call do_single_step
367 #
368 sysc_singlestep:
369         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
370         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
371         la      %r2,SP_PTREGS(%r15)     # address of register-save area
372         larl    %r14,sysc_return        # load adr. of system return
373         jg      do_single_step          # branch to do_sigtrap
374
375 #
376 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
377 # and after the system call
378 #
379 sysc_tracesys:
380         la      %r2,SP_PTREGS(%r15)     # load pt_regs
381         la      %r3,0
382         llgh    %r0,SP_SVCNR(%r15)
383         stg     %r0,SP_R2(%r15)
384         brasl   %r14,do_syscall_trace_enter
385         lghi    %r0,NR_syscalls
386         clgr    %r0,%r2
387         jnh     sysc_tracenogo
388         sllg    %r7,%r2,2               # svc number *4
389         lgf     %r8,0(%r7,%r10)
390 sysc_tracego:
391         lmg     %r3,%r6,SP_R3(%r15)
392         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
393         lg      %r2,SP_ORIG_R2(%r15)
394         basr    %r14,%r8                # call sys_xxx
395         stg     %r2,SP_R2(%r15)         # store return value
396 sysc_tracenogo:
397         tm      __TI_flags+6(%r12),_TIF_SYSCALL
398         jz      sysc_return
399         la      %r2,SP_PTREGS(%r15)     # load pt_regs
400         larl    %r14,sysc_return        # return point is sysc_return
401         jg      do_syscall_trace_exit
402
403 #
404 # a new process exits the kernel with ret_from_fork
405 #
406         .globl  ret_from_fork
407 ret_from_fork:
408         lg      %r13,__LC_SVC_NEW_PSW+8
409         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
410         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
411         jo      0f
412         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
413 0:      brasl   %r14,schedule_tail
414         TRACE_IRQS_ON
415         stosm   24(%r15),0x03           # reenable interrupts
416         j       sysc_tracenogo
417
418 #
419 # kernel_execve function needs to deal with pt_regs that is not
420 # at the usual place
421 #
422         .globl  kernel_execve
423 kernel_execve:
424         stmg    %r12,%r15,96(%r15)
425         lgr     %r14,%r15
426         aghi    %r15,-SP_SIZE
427         stg     %r14,__SF_BACKCHAIN(%r15)
428         la      %r12,SP_PTREGS(%r15)
429         xc      0(__PT_SIZE,%r12),0(%r12)
430         lgr     %r5,%r12
431         brasl   %r14,do_execve
432         ltgfr   %r2,%r2
433         je      0f
434         aghi    %r15,SP_SIZE
435         lmg     %r12,%r15,96(%r15)
436         br      %r14
437         # execve succeeded.
438 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
439         lg      %r15,__LC_KERNEL_STACK  # load ksp
440         aghi    %r15,-SP_SIZE           # make room for registers & psw
441         lg      %r13,__LC_SVC_NEW_PSW+8
442         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
443         lg      %r12,__LC_THREAD_INFO
444         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
445         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
446         brasl   %r14,execve_tail
447         j       sysc_return
448
449 /*
450  * Program check handler routine
451  */
452
453         .globl  pgm_check_handler
454 pgm_check_handler:
455 /*
456  * First we need to check for a special case:
457  * Single stepping an instruction that disables the PER event mask will
458  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
459  * For a single stepped SVC the program check handler gets control after
460  * the SVC new PSW has been loaded. But we want to execute the SVC first and
461  * then handle the PER event. Therefore we update the SVC old PSW to point
462  * to the pgm_check_handler and branch to the SVC handler after we checked
463  * if we have to load the kernel stack register.
464  * For every other possible cause for PER event without the PER mask set
465  * we just ignore the PER event (FIXME: is there anything we have to do
466  * for LPSW?).
467  */
468         stpt    __LC_SYNC_ENTER_TIMER
469         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
470         jnz     pgm_per                  # got per exception -> special case
471         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
472         CREATE_STACK_FRAME __LC_SAVE_AREA
473         xc      SP_ILC(4,%r15),SP_ILC(%r15)
474         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
475         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
476         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
477         jz      pgm_no_vtime
478         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
479         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
480         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
481         LAST_BREAK
482 pgm_no_vtime:
483         HANDLE_SIE_INTERCEPT
484         stg     %r11,SP_ARGS(%r15)
485         lgf     %r3,__LC_PGM_ILC        # load program interruption code
486         lg      %r4,__LC_TRANS_EXC_CODE
487         REENABLE_IRQS
488         lghi    %r8,0x7f
489         ngr     %r8,%r3
490         sll     %r8,3
491         larl    %r1,pgm_check_table
492         lg      %r1,0(%r8,%r1)          # load address of handler routine
493         la      %r2,SP_PTREGS(%r15)     # address of register-save area
494         basr    %r14,%r1                # branch to interrupt-handler
495 pgm_exit:
496         j       sysc_return
497
498 #
499 # handle per exception
500 #
501 pgm_per:
502         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
503         jnz     pgm_per_std             # ok, normal per event from user space
504 # ok its one of the special cases, now we need to find out which one
505         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
506         je      pgm_svcper
507 # no interesting special case, ignore PER event
508         lpswe   __LC_PGM_OLD_PSW
509
510 #
511 # Normal per exception
512 #
513 pgm_per_std:
514         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
515         CREATE_STACK_FRAME __LC_SAVE_AREA
516         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
517         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
518         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
519         jz      pgm_no_vtime2
520         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
521         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
522         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
523         LAST_BREAK
524 pgm_no_vtime2:
525         HANDLE_SIE_INTERCEPT
526         lg      %r1,__TI_task(%r12)
527         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
528         jz      kernel_per
529         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
530         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
531         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
532         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
533         lgf     %r3,__LC_PGM_ILC        # load program interruption code
534         lg      %r4,__LC_TRANS_EXC_CODE
535         REENABLE_IRQS
536         lghi    %r8,0x7f
537         ngr     %r8,%r3                 # clear per-event-bit and ilc
538         je      pgm_exit2
539         sll     %r8,3
540         larl    %r1,pgm_check_table
541         lg      %r1,0(%r8,%r1)          # load address of handler routine
542         la      %r2,SP_PTREGS(%r15)     # address of register-save area
543         basr    %r14,%r1                # branch to interrupt-handler
544 pgm_exit2:
545         j       sysc_return
546
547 #
548 # it was a single stepped SVC that is causing all the trouble
549 #
550 pgm_svcper:
551         SAVE_ALL_PGM __LC_SVC_OLD_PSW,__LC_SAVE_AREA
552         CREATE_STACK_FRAME __LC_SAVE_AREA
553         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
554         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
555         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
556         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
557         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
558         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
559         LAST_BREAK
560         lg      %r8,__TI_task(%r12)
561         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
562         mvc     __THREAD_per+__PER_address(8,%r8),__LC_PER_ADDRESS
563         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
564         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
565         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
566         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
567         j       sysc_do_svc
568
569 #
570 # per was called from kernel, must be kprobes
571 #
572 kernel_per:
573         REENABLE_IRQS
574         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15) # clear svc number
575         la      %r2,SP_PTREGS(%r15)     # address of register-save area
576         brasl   %r14,do_single_step
577         j       pgm_exit
578
579 /*
580  * IO interrupt handler routine
581  */
582         .globl io_int_handler
583 io_int_handler:
584         stck    __LC_INT_CLOCK
585         stpt    __LC_ASYNC_ENTER_TIMER
586         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+40
587         CREATE_STACK_FRAME __LC_SAVE_AREA+40
588         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
589         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
590         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
591         jz      io_no_vtime
592         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
593         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
594         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
595         LAST_BREAK
596 io_no_vtime:
597         HANDLE_SIE_INTERCEPT
598         TRACE_IRQS_OFF
599         la      %r2,SP_PTREGS(%r15)     # address of register-save area
600         brasl   %r14,do_IRQ             # call standard irq handler
601 io_return:
602         LOCKDEP_SYS_EXIT
603         TRACE_IRQS_ON
604 io_tif:
605         tm      __TI_flags+7(%r12),_TIF_WORK_INT
606         jnz     io_work                 # there is work to do (signals etc.)
607 io_restore:
608         RESTORE_ALL __LC_RETURN_PSW,0
609 io_done:
610
611 #
612 # There is work todo, find out in which context we have been interrupted:
613 # 1) if we return to user space we can do all _TIF_WORK_INT work
614 # 2) if we return to kernel code and kvm is enabled check if we need to
615 #    modify the psw to leave SIE
616 # 3) if we return to kernel code and preemptive scheduling is enabled check
617 #    the preemption counter and if it is zero call preempt_schedule_irq
618 # Before any work can be done, a switch to the kernel stack is required.
619 #
620 io_work:
621         tm      SP_PSW+1(%r15),0x01     # returning to user ?
622         jo      io_work_user            # yes -> do resched & signal
623 #ifdef CONFIG_PREEMPT
624         # check for preemptive scheduling
625         icm     %r0,15,__TI_precount(%r12)
626         jnz     io_restore              # preemption is disabled
627         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
628         jno     io_restore
629         # switch to kernel stack
630         lg      %r1,SP_R15(%r15)
631         aghi    %r1,-SP_SIZE
632         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
633         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
634         lgr     %r15,%r1
635         # TRACE_IRQS_ON already done at io_return, call
636         # TRACE_IRQS_OFF to keep things symmetrical
637         TRACE_IRQS_OFF
638         brasl   %r14,preempt_schedule_irq
639         j       io_return
640 #else
641         j       io_restore
642 #endif
643
644 #
645 # Need to do work before returning to userspace, switch to kernel stack
646 #
647 io_work_user:
648         lg      %r1,__LC_KERNEL_STACK
649         aghi    %r1,-SP_SIZE
650         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
651         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
652         lgr     %r15,%r1
653
654 #
655 # One of the work bits is on. Find out which one.
656 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
657 #              and _TIF_MCCK_PENDING
658 #
659 io_work_tif:
660         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
661         jo      io_mcck_pending
662         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
663         jo      io_reschedule
664         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
665         jo      io_sigpending
666         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
667         jo      io_notify_resume
668         j       io_return               # beware of critical section cleanup
669
670 #
671 # _TIF_MCCK_PENDING is set, call handler
672 #
673 io_mcck_pending:
674         # TRACE_IRQS_ON already done at io_return
675         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
676         TRACE_IRQS_OFF
677         j       io_return
678
679 #
680 # _TIF_NEED_RESCHED is set, call schedule
681 #
682 io_reschedule:
683         # TRACE_IRQS_ON already done at io_return
684         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
685         brasl   %r14,schedule           # call scheduler
686         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
687         TRACE_IRQS_OFF
688         j       io_return
689
690 #
691 # _TIF_SIGPENDING or is set, call do_signal
692 #
693 io_sigpending:
694         # TRACE_IRQS_ON already done at io_return
695         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
696         la      %r2,SP_PTREGS(%r15)     # load pt_regs
697         brasl   %r14,do_signal          # call do_signal
698         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
699         TRACE_IRQS_OFF
700         j       io_return
701
702 #
703 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
704 #
705 io_notify_resume:
706         # TRACE_IRQS_ON already done at io_return
707         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
708         la      %r2,SP_PTREGS(%r15)     # load pt_regs
709         brasl   %r14,do_notify_resume   # call do_notify_resume
710         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
711         TRACE_IRQS_OFF
712         j       io_return
713
714 /*
715  * External interrupt handler routine
716  */
717         .globl  ext_int_handler
718 ext_int_handler:
719         stck    __LC_INT_CLOCK
720         stpt    __LC_ASYNC_ENTER_TIMER
721         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+40
722         CREATE_STACK_FRAME __LC_SAVE_AREA+40
723         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
724         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
725         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
726         jz      ext_no_vtime
727         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
728         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
729         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
730         LAST_BREAK
731 ext_no_vtime:
732         HANDLE_SIE_INTERCEPT
733         TRACE_IRQS_OFF
734         lghi    %r1,4096
735         la      %r2,SP_PTREGS(%r15)     # address of register-save area
736         llgf    %r3,__LC_CPU_ADDRESS    # get cpu address + interruption code
737         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
738         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
739         brasl   %r14,do_extint
740         j       io_return
741
742 __critical_end:
743
744 /*
745  * Machine check handler routines
746  */
747         .globl mcck_int_handler
748 mcck_int_handler:
749         stck    __LC_MCCK_CLOCK
750         la      %r1,4095                # revalidate r1
751         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
752         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
753         stmg    %r11,%r15,__LC_SAVE_AREA+80
754         larl    %r13,system_call
755         lg      %r11,__LC_LAST_BREAK
756         la      %r12,__LC_MCK_OLD_PSW
757         tm      __LC_MCCK_CODE,0x80     # system damage?
758         jo      mcck_int_main           # yes -> rest of mcck code invalid
759         la      %r14,4095
760         mvc     __LC_MCCK_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
761         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
762         jo      1f
763         la      %r14,__LC_SYNC_ENTER_TIMER
764         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
765         jl      0f
766         la      %r14,__LC_ASYNC_ENTER_TIMER
767 0:      clc     0(8,%r14),__LC_EXIT_TIMER
768         jl      0f
769         la      %r14,__LC_EXIT_TIMER
770 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
771         jl      0f
772         la      %r14,__LC_LAST_UPDATE_TIMER
773 0:      spt     0(%r14)
774         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
775 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
776         jno     mcck_int_main           # no -> skip cleanup critical
777         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
778         jnz     mcck_int_main           # from user -> load kernel stack
779         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
780         jhe     mcck_int_main
781         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
782         jl      mcck_int_main
783         brasl   %r14,cleanup_critical
784 mcck_int_main:
785         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
786         slgr    %r14,%r15
787         srag    %r14,%r14,PAGE_SHIFT
788         jz      0f
789         lg      %r15,__LC_PANIC_STACK   # load panic stack
790 0:      aghi    %r15,-SP_SIZE           # make room for registers & psw
791         CREATE_STACK_FRAME __LC_SAVE_AREA+80
792         mvc     SP_PSW(16,%r15),0(%r12)
793         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
794         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
795         jno     mcck_no_vtime           # no -> no timer update
796         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
797         jz      mcck_no_vtime
798         UPDATE_VTIME __LC_EXIT_TIMER,__LC_MCCK_ENTER_TIMER,__LC_USER_TIMER
799         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
800         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_MCCK_ENTER_TIMER
801         LAST_BREAK
802 mcck_no_vtime:
803         la      %r2,SP_PTREGS(%r15)     # load pt_regs
804         brasl   %r14,s390_do_machine_check
805         tm      SP_PSW+1(%r15),0x01     # returning to user ?
806         jno     mcck_return
807         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
808         aghi    %r1,-SP_SIZE
809         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
810         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
811         lgr     %r15,%r1
812         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
813         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
814         jno     mcck_return
815         HANDLE_SIE_INTERCEPT
816         TRACE_IRQS_OFF
817         brasl   %r14,s390_handle_mcck
818         TRACE_IRQS_ON
819 mcck_return:
820         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
821         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
822         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
823         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
824         jno     0f
825         stpt    __LC_EXIT_TIMER
826 0:      lpswe   __LC_RETURN_MCCK_PSW    # back to caller
827 mcck_done:
828
829 /*
830  * Restart interruption handler, kick starter for additional CPUs
831  */
832 #ifdef CONFIG_SMP
833         __CPUINIT
834         .globl restart_int_handler
835 restart_int_handler:
836         basr    %r1,0
837 restart_base:
838         spt     restart_vtime-restart_base(%r1)
839         stck    __LC_LAST_UPDATE_CLOCK
840         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
841         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
842         lg      %r15,__LC_SAVE_AREA+120 # load ksp
843         lghi    %r10,__LC_CREGS_SAVE_AREA
844         lctlg   %c0,%c15,0(%r10) # get new ctl regs
845         lghi    %r10,__LC_AREGS_SAVE_AREA
846         lam     %a0,%a15,0(%r10)
847         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
848         lg      %r1,__LC_THREAD_INFO
849         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
850         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
851         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
852         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
853         jg      start_secondary
854         .align  8
855 restart_vtime:
856         .long   0x7fffffff,0xffffffff
857         .previous
858 #else
859 /*
860  * If we do not run with SMP enabled, let the new CPU crash ...
861  */
862         .globl restart_int_handler
863 restart_int_handler:
864         basr    %r1,0
865 restart_base:
866         lpswe   restart_crash-restart_base(%r1)
867         .align 8
868 restart_crash:
869         .long  0x000a0000,0x00000000,0x00000000,0x00000000
870 restart_go:
871 #endif
872
873         .section .kprobes.text, "ax"
874
875 #ifdef CONFIG_CHECK_STACK
876 /*
877  * The synchronous or the asynchronous stack overflowed. We are dead.
878  * No need to properly save the registers, we are going to panic anyway.
879  * Setup a pt_regs so that show_trace can provide a good call trace.
880  */
881 stack_overflow:
882         lg      %r15,__LC_PANIC_STACK   # change to panic stack
883         aghi    %r15,-SP_SIZE
884         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
885         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
886         la      %r1,__LC_SAVE_AREA
887         chi     %r12,__LC_SVC_OLD_PSW
888         je      0f
889         chi     %r12,__LC_PGM_OLD_PSW
890         je      0f
891         la      %r1,__LC_SAVE_AREA+40
892 0:      mvc     SP_R11(40,%r15),0(%r1)  # move %r11-%r15 to stack
893         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
894         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
895         la      %r2,SP_PTREGS(%r15)     # load pt_regs
896         jg      kernel_stack_overflow
897 #endif
898
899 cleanup_table_system_call:
900         .quad   system_call, sysc_do_svc
901 cleanup_table_sysc_tif:
902         .quad   sysc_tif, sysc_restore
903 cleanup_table_sysc_restore:
904         .quad   sysc_restore, sysc_done
905 cleanup_table_io_tif:
906         .quad   io_tif, io_restore
907 cleanup_table_io_restore:
908         .quad   io_restore, io_done
909
910 cleanup_critical:
911         clc     8(8,%r12),BASED(cleanup_table_system_call)
912         jl      0f
913         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
914         jl      cleanup_system_call
915 0:
916         clc     8(8,%r12),BASED(cleanup_table_sysc_tif)
917         jl      0f
918         clc     8(8,%r12),BASED(cleanup_table_sysc_tif+8)
919         jl      cleanup_sysc_tif
920 0:
921         clc     8(8,%r12),BASED(cleanup_table_sysc_restore)
922         jl      0f
923         clc     8(8,%r12),BASED(cleanup_table_sysc_restore+8)
924         jl      cleanup_sysc_restore
925 0:
926         clc     8(8,%r12),BASED(cleanup_table_io_tif)
927         jl      0f
928         clc     8(8,%r12),BASED(cleanup_table_io_tif+8)
929         jl      cleanup_io_tif
930 0:
931         clc     8(8,%r12),BASED(cleanup_table_io_restore)
932         jl      0f
933         clc     8(8,%r12),BASED(cleanup_table_io_restore+8)
934         jl      cleanup_io_restore
935 0:
936         br      %r14
937
938 cleanup_system_call:
939         mvc     __LC_RETURN_PSW(16),0(%r12)
940         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
941         jh      0f
942         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
943         cghi    %r12,__LC_MCK_OLD_PSW
944         je      0f
945         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
946 0:      cghi    %r12,__LC_MCK_OLD_PSW
947         la      %r12,__LC_SAVE_AREA+80
948         je      0f
949         la      %r12,__LC_SAVE_AREA+40
950 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
951         jhe     cleanup_vtime
952         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
953         jh      0f
954         mvc     __LC_SAVE_AREA(40),0(%r12)
955 0:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
956         aghi    %r15,-SP_SIZE           # make room for registers & psw
957         stg     %r15,32(%r12)
958         stg     %r11,0(%r12)
959         CREATE_STACK_FRAME __LC_SAVE_AREA
960         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
961         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
962         mvc     8(8,%r12),__LC_THREAD_INFO
963 cleanup_vtime:
964         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
965         jhe     cleanup_stime
966         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
967 cleanup_stime:
968         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
969         jh      cleanup_update
970         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
971 cleanup_update:
972         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
973         srag    %r12,%r11,23
974         lg      %r12,__LC_THREAD_INFO
975         jz      0f
976         stg     %r11,__TI_last_break(%r12)
977 0:      mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
978         la      %r12,__LC_RETURN_PSW
979         br      %r14
980 cleanup_system_call_insn:
981         .quad   sysc_saveall
982         .quad   system_call
983         .quad   sysc_vtime
984         .quad   sysc_stime
985         .quad   sysc_update
986
987 cleanup_sysc_tif:
988         mvc     __LC_RETURN_PSW(8),0(%r12)
989         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_tif)
990         la      %r12,__LC_RETURN_PSW
991         br      %r14
992
993 cleanup_sysc_restore:
994         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn)
995         je      2f
996         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn+8)
997         jhe     0f
998         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
999         cghi    %r12,__LC_MCK_OLD_PSW
1000         je      0f
1001         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1002 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1003         cghi    %r12,__LC_MCK_OLD_PSW
1004         la      %r12,__LC_SAVE_AREA+80
1005         je      1f
1006         la      %r12,__LC_SAVE_AREA+40
1007 1:      mvc     0(40,%r12),SP_R11(%r15)
1008         lmg     %r0,%r10,SP_R0(%r15)
1009         lg      %r15,SP_R15(%r15)
1010 2:      la      %r12,__LC_RETURN_PSW
1011         br      %r14
1012 cleanup_sysc_restore_insn:
1013         .quad   sysc_done - 4
1014         .quad   sysc_done - 16
1015
1016 cleanup_io_tif:
1017         mvc     __LC_RETURN_PSW(8),0(%r12)
1018         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_tif)
1019         la      %r12,__LC_RETURN_PSW
1020         br      %r14
1021
1022 cleanup_io_restore:
1023         clc     8(8,%r12),BASED(cleanup_io_restore_insn)
1024         je      1f
1025         clc     8(8,%r12),BASED(cleanup_io_restore_insn+8)
1026         jhe     0f
1027         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1028 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1029         mvc     __LC_SAVE_AREA+80(40),SP_R11(%r15)
1030         lmg     %r0,%r10,SP_R0(%r15)
1031         lg      %r15,SP_R15(%r15)
1032 1:      la      %r12,__LC_RETURN_PSW
1033         br      %r14
1034 cleanup_io_restore_insn:
1035         .quad   io_done - 4
1036         .quad   io_done - 16
1037
1038 /*
1039  * Integer constants
1040  */
1041                 .align  4
1042 .Lcritical_start:
1043                 .quad   __critical_start
1044 .Lcritical_end:
1045                 .quad   __critical_end
1046
1047                 .section .rodata, "a"
1048 #define SYSCALL(esa,esame,emu)  .long esame
1049         .globl  sys_call_table
1050 sys_call_table:
1051 #include "syscalls.S"
1052 #undef SYSCALL
1053
1054 #ifdef CONFIG_COMPAT
1055
1056 #define SYSCALL(esa,esame,emu)  .long emu
1057 sys_call_table_emu:
1058 #include "syscalls.S"
1059 #undef SYSCALL
1060 #endif