powerpc: In HV mode, use HSPRG0 for PACA
[linux-2.6.git] / arch / powerpc / kvm / book3s_rmhandlers.S
1 /*
2  * This program is free software; you can redistribute it and/or modify
3  * it under the terms of the GNU General Public License, version 2, as
4  * published by the Free Software Foundation.
5  *
6  * This program is distributed in the hope that it will be useful,
7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
9  * GNU General Public License for more details.
10  *
11  * You should have received a copy of the GNU General Public License
12  * along with this program; if not, write to the Free Software
13  * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
14  *
15  * Copyright SUSE Linux Products GmbH 2009
16  *
17  * Authors: Alexander Graf <agraf@suse.de>
18  */
19
20 #include <asm/ppc_asm.h>
21 #include <asm/kvm_asm.h>
22 #include <asm/reg.h>
23 #include <asm/page.h>
24 #include <asm/asm-offsets.h>
25
26 #ifdef CONFIG_PPC_BOOK3S_64
27 #include <asm/exception-64s.h>
28 #endif
29
30 /*****************************************************************************
31  *                                                                           *
32  *        Real Mode handlers that need to be in low physical memory          *
33  *                                                                           *
34  ****************************************************************************/
35
36 #if defined(CONFIG_PPC_BOOK3S_64)
37
38 #define LOAD_SHADOW_VCPU(reg)   GET_PACA(reg)                                   
39 #define SHADOW_VCPU_OFF         PACA_KVM_SVCPU
40 #define MSR_NOIRQ               MSR_KERNEL & ~(MSR_IR | MSR_DR)
41 #define FUNC(name)              GLUE(.,name)
42
43 #elif defined(CONFIG_PPC_BOOK3S_32)
44
45 #define LOAD_SHADOW_VCPU(reg)                                           \
46         mfspr   reg, SPRN_SPRG_THREAD;                                  \
47         lwz     reg, THREAD_KVM_SVCPU(reg);                             \
48         /* PPC32 can have a NULL pointer - let's check for that */      \
49         mtspr   SPRN_SPRG_SCRATCH1, r12;        /* Save r12 */          \
50         mfcr    r12;                                                    \
51         cmpwi   reg, 0;                                                 \
52         bne     1f;                                                     \
53         mfspr   reg, SPRN_SPRG_SCRATCH0;                                \
54         mtcr    r12;                                                    \
55         mfspr   r12, SPRN_SPRG_SCRATCH1;                                \
56         b       kvmppc_resume_\intno;                                   \
57 1:;                                                                     \
58         mtcr    r12;                                                    \
59         mfspr   r12, SPRN_SPRG_SCRATCH1;                                \
60         tophys(reg, reg)
61
62 #define SHADOW_VCPU_OFF         0
63 #define MSR_NOIRQ               MSR_KERNEL
64 #define FUNC(name)              name
65
66 #endif
67
68 .macro INTERRUPT_TRAMPOLINE intno
69
70 .global kvmppc_trampoline_\intno
71 kvmppc_trampoline_\intno:
72
73         mtspr   SPRN_SPRG_SCRATCH0, r13         /* Save r13 */
74
75         /*
76          * First thing to do is to find out if we're coming
77          * from a KVM guest or a Linux process.
78          *
79          * To distinguish, we check a magic byte in the PACA/current
80          */
81         LOAD_SHADOW_VCPU(r13)
82         PPC_STL r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
83         mfcr    r12
84         stw     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
85         lbz     r12, (SHADOW_VCPU_OFF + SVCPU_IN_GUEST)(r13)
86         cmpwi   r12, KVM_GUEST_MODE_NONE
87         bne     ..kvmppc_handler_hasmagic_\intno
88         /* No KVM guest? Then jump back to the Linux handler! */
89         lwz     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
90         mtcr    r12
91         PPC_LL  r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
92         mfspr   r13, SPRN_SPRG_SCRATCH0         /* r13 = original r13 */
93         b       kvmppc_resume_\intno            /* Get back original handler */
94
95         /* Now we know we're handling a KVM guest */
96 ..kvmppc_handler_hasmagic_\intno:
97
98         /* Should we just skip the faulting instruction? */
99         cmpwi   r12, KVM_GUEST_MODE_SKIP
100         beq     kvmppc_handler_skip_ins
101
102         /* Let's store which interrupt we're handling */
103         li      r12, \intno
104
105         /* Jump into the SLB exit code that goes to the highmem handler */
106         b       kvmppc_handler_trampoline_exit
107
108 .endm
109
110 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_SYSTEM_RESET
111 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_MACHINE_CHECK
112 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DATA_STORAGE
113 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_INST_STORAGE
114 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_EXTERNAL
115 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_ALIGNMENT
116 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_PROGRAM
117 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_FP_UNAVAIL
118 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DECREMENTER
119 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_SYSCALL
120 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_TRACE
121 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_PERFMON
122 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_ALTIVEC
123
124 /* Those are only available on 64 bit machines */
125
126 #ifdef CONFIG_PPC_BOOK3S_64
127 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DATA_SEGMENT
128 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_INST_SEGMENT
129 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_VSX
130 #endif
131
132 /*
133  * Bring us back to the faulting code, but skip the
134  * faulting instruction.
135  *
136  * This is a generic exit path from the interrupt
137  * trampolines above.
138  *
139  * Input Registers:
140  *
141  * R12            = free
142  * R13            = Shadow VCPU (PACA)
143  * SVCPU.SCRATCH0 = guest R12
144  * SVCPU.SCRATCH1 = guest CR
145  * SPRG_SCRATCH0  = guest R13
146  *
147  */
148 kvmppc_handler_skip_ins:
149
150         /* Patch the IP to the next instruction */
151         mfsrr0  r12
152         addi    r12, r12, 4
153         mtsrr0  r12
154
155         /* Clean up all state */
156         lwz     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
157         mtcr    r12
158         PPC_LL  r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
159         mfspr   r13, SPRN_SPRG_SCRATCH0
160
161         /* And get back into the code */
162         RFI
163
164 /*
165  * This trampoline brings us back to a real mode handler
166  *
167  * Input Registers:
168  *
169  * R5 = SRR0
170  * R6 = SRR1
171  * LR = real-mode IP
172  *
173  */
174 .global kvmppc_handler_lowmem_trampoline
175 kvmppc_handler_lowmem_trampoline:
176
177         mtsrr0  r5
178         mtsrr1  r6
179         blr
180 kvmppc_handler_lowmem_trampoline_end:
181
182 /*
183  * Call a function in real mode
184  *
185  * Input Registers:
186  *
187  * R3 = function
188  * R4 = MSR
189  * R5 = scratch register
190  *
191  */
192 _GLOBAL(kvmppc_rmcall)
193         LOAD_REG_IMMEDIATE(r5, MSR_NOIRQ)
194         mtmsr   r5              /* Disable relocation and interrupts, so mtsrr
195                                    doesn't get interrupted */
196         sync
197         mtsrr0  r3
198         mtsrr1  r4
199         RFI
200
201 #if defined(CONFIG_PPC_BOOK3S_32)
202 #define STACK_LR        INT_FRAME_SIZE+4
203
204 /* load_up_xxx have to run with MSR_DR=0 on Book3S_32 */
205 #define MSR_EXT_START                                           \
206         PPC_STL r20, _NIP(r1);                                  \
207         mfmsr   r20;                                            \
208         LOAD_REG_IMMEDIATE(r3, MSR_DR|MSR_EE);                  \
209         andc    r3,r20,r3;              /* Disable DR,EE */     \
210         mtmsr   r3;                                             \
211         sync
212
213 #define MSR_EXT_END                                             \
214         mtmsr   r20;                    /* Enable DR,EE */      \
215         sync;                                                   \
216         PPC_LL  r20, _NIP(r1)
217
218 #elif defined(CONFIG_PPC_BOOK3S_64)
219 #define STACK_LR        _LINK
220 #define MSR_EXT_START
221 #define MSR_EXT_END
222 #endif
223
224 /*
225  * Activate current's external feature (FPU/Altivec/VSX)
226  */
227 #define define_load_up(what)                                    \
228                                                                 \
229 _GLOBAL(kvmppc_load_up_ ## what);                               \
230         PPC_STLU r1, -INT_FRAME_SIZE(r1);                       \
231         mflr    r3;                                             \
232         PPC_STL r3, STACK_LR(r1);                               \
233         MSR_EXT_START;                                          \
234                                                                 \
235         bl      FUNC(load_up_ ## what);                         \
236                                                                 \
237         MSR_EXT_END;                                            \
238         PPC_LL  r3, STACK_LR(r1);                               \
239         mtlr    r3;                                             \
240         addi    r1, r1, INT_FRAME_SIZE;                         \
241         blr
242
243 define_load_up(fpu)
244 #ifdef CONFIG_ALTIVEC
245 define_load_up(altivec)
246 #endif
247 #ifdef CONFIG_VSX
248 define_load_up(vsx)
249 #endif
250
251 .global kvmppc_trampoline_lowmem
252 kvmppc_trampoline_lowmem:
253         PPC_LONG kvmppc_handler_lowmem_trampoline - CONFIG_KERNEL_START
254
255 .global kvmppc_trampoline_enter
256 kvmppc_trampoline_enter:
257         PPC_LONG kvmppc_handler_trampoline_enter - CONFIG_KERNEL_START
258
259 #include "book3s_segment.S"