KVM: PPC: Allocate RMAs (Real Mode Areas) at boot for use by guests
[linux-2.6.git] / arch / powerpc / kvm / book3s_hv_rmhandlers.S
1 /*
2  * This program is free software; you can redistribute it and/or modify
3  * it under the terms of the GNU General Public License, version 2, as
4  * published by the Free Software Foundation.
5  *
6  * This program is distributed in the hope that it will be useful,
7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
9  * GNU General Public License for more details.
10  *
11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
12  *
13  * Derived from book3s_rmhandlers.S and other files, which are:
14  *
15  * Copyright SUSE Linux Products GmbH 2009
16  *
17  * Authors: Alexander Graf <agraf@suse.de>
18  */
19
20 #include <asm/ppc_asm.h>
21 #include <asm/kvm_asm.h>
22 #include <asm/reg.h>
23 #include <asm/page.h>
24 #include <asm/asm-offsets.h>
25 #include <asm/exception-64s.h>
26
27 /*****************************************************************************
28  *                                                                           *
29  *        Real Mode handlers that need to be in the linear mapping           *
30  *                                                                           *
31  ****************************************************************************/
32
33         .globl  kvmppc_skip_interrupt
34 kvmppc_skip_interrupt:
35         mfspr   r13,SPRN_SRR0
36         addi    r13,r13,4
37         mtspr   SPRN_SRR0,r13
38         GET_SCRATCH0(r13)
39         rfid
40         b       .
41
42         .globl  kvmppc_skip_Hinterrupt
43 kvmppc_skip_Hinterrupt:
44         mfspr   r13,SPRN_HSRR0
45         addi    r13,r13,4
46         mtspr   SPRN_HSRR0,r13
47         GET_SCRATCH0(r13)
48         hrfid
49         b       .
50
51 /*
52  * Call kvmppc_handler_trampoline_enter in real mode.
53  * Must be called with interrupts hard-disabled.
54  *
55  * Input Registers:
56  *
57  * LR = return address to continue at after eventually re-enabling MMU
58  */
59 _GLOBAL(kvmppc_hv_entry_trampoline)
60         mfmsr   r10
61         LOAD_REG_ADDR(r5, kvmppc_hv_entry)
62         li      r0,MSR_RI
63         andc    r0,r10,r0
64         li      r6,MSR_IR | MSR_DR
65         andc    r6,r10,r6
66         mtmsrd  r0,1            /* clear RI in MSR */
67         mtsrr0  r5
68         mtsrr1  r6
69         RFI
70
71 #define ULONG_SIZE              8
72 #define VCPU_GPR(n)             (VCPU_GPRS + (n * ULONG_SIZE))
73
74 /******************************************************************************
75  *                                                                            *
76  *                               Entry code                                   *
77  *                                                                            *
78  *****************************************************************************/
79
80 #define XICS_XIRR               4
81 #define XICS_QIRR               0xc
82
83 /*
84  * We come in here when wakened from nap mode on a secondary hw thread.
85  * Relocation is off and most register values are lost.
86  * r13 points to the PACA.
87  */
88         .globl  kvm_start_guest
89 kvm_start_guest:
90         ld      r1,PACAEMERGSP(r13)
91         subi    r1,r1,STACK_FRAME_OVERHEAD
92
93         /* get vcpu pointer */
94         ld      r4, HSTATE_KVM_VCPU(r13)
95
96         /* We got here with an IPI; clear it */
97         ld      r5, HSTATE_XICS_PHYS(r13)
98         li      r0, 0xff
99         li      r6, XICS_QIRR
100         li      r7, XICS_XIRR
101         lwzcix  r8, r5, r7              /* ack the interrupt */
102         sync
103         stbcix  r0, r5, r6              /* clear it */
104         stwcix  r8, r5, r7              /* EOI it */
105
106 .global kvmppc_hv_entry
107 kvmppc_hv_entry:
108
109         /* Required state:
110          *
111          * R4 = vcpu pointer
112          * MSR = ~IR|DR
113          * R13 = PACA
114          * R1 = host R1
115          * all other volatile GPRS = free
116          */
117         mflr    r0
118         std     r0, HSTATE_VMHANDLER(r13)
119
120         ld      r14, VCPU_GPR(r14)(r4)
121         ld      r15, VCPU_GPR(r15)(r4)
122         ld      r16, VCPU_GPR(r16)(r4)
123         ld      r17, VCPU_GPR(r17)(r4)
124         ld      r18, VCPU_GPR(r18)(r4)
125         ld      r19, VCPU_GPR(r19)(r4)
126         ld      r20, VCPU_GPR(r20)(r4)
127         ld      r21, VCPU_GPR(r21)(r4)
128         ld      r22, VCPU_GPR(r22)(r4)
129         ld      r23, VCPU_GPR(r23)(r4)
130         ld      r24, VCPU_GPR(r24)(r4)
131         ld      r25, VCPU_GPR(r25)(r4)
132         ld      r26, VCPU_GPR(r26)(r4)
133         ld      r27, VCPU_GPR(r27)(r4)
134         ld      r28, VCPU_GPR(r28)(r4)
135         ld      r29, VCPU_GPR(r29)(r4)
136         ld      r30, VCPU_GPR(r30)(r4)
137         ld      r31, VCPU_GPR(r31)(r4)
138
139         /* Load guest PMU registers */
140         /* R4 is live here (vcpu pointer) */
141         li      r3, 1
142         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
143         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
144         isync
145         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
146         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
147         lwz     r6, VCPU_PMC + 8(r4)
148         lwz     r7, VCPU_PMC + 12(r4)
149         lwz     r8, VCPU_PMC + 16(r4)
150         lwz     r9, VCPU_PMC + 20(r4)
151         mtspr   SPRN_PMC1, r3
152         mtspr   SPRN_PMC2, r5
153         mtspr   SPRN_PMC3, r6
154         mtspr   SPRN_PMC4, r7
155         mtspr   SPRN_PMC5, r8
156         mtspr   SPRN_PMC6, r9
157         ld      r3, VCPU_MMCR(r4)
158         ld      r5, VCPU_MMCR + 8(r4)
159         ld      r6, VCPU_MMCR + 16(r4)
160         mtspr   SPRN_MMCR1, r5
161         mtspr   SPRN_MMCRA, r6
162         mtspr   SPRN_MMCR0, r3
163         isync
164
165         /* Load up FP, VMX and VSX registers */
166         bl      kvmppc_load_fp
167
168         /* Switch DSCR to guest value */
169         ld      r5, VCPU_DSCR(r4)
170         mtspr   SPRN_DSCR, r5
171
172         /*
173          * Set the decrementer to the guest decrementer.
174          */
175         ld      r8,VCPU_DEC_EXPIRES(r4)
176         mftb    r7
177         subf    r3,r7,r8
178         mtspr   SPRN_DEC,r3
179         stw     r3,VCPU_DEC(r4)
180
181         ld      r5, VCPU_SPRG0(r4)
182         ld      r6, VCPU_SPRG1(r4)
183         ld      r7, VCPU_SPRG2(r4)
184         ld      r8, VCPU_SPRG3(r4)
185         mtspr   SPRN_SPRG0, r5
186         mtspr   SPRN_SPRG1, r6
187         mtspr   SPRN_SPRG2, r7
188         mtspr   SPRN_SPRG3, r8
189
190         /* Save R1 in the PACA */
191         std     r1, HSTATE_HOST_R1(r13)
192
193         /* Increment yield count if they have a VPA */
194         ld      r3, VCPU_VPA(r4)
195         cmpdi   r3, 0
196         beq     25f
197         lwz     r5, LPPACA_YIELDCOUNT(r3)
198         addi    r5, r5, 1
199         stw     r5, LPPACA_YIELDCOUNT(r3)
200 25:
201         /* Load up DAR and DSISR */
202         ld      r5, VCPU_DAR(r4)
203         lwz     r6, VCPU_DSISR(r4)
204         mtspr   SPRN_DAR, r5
205         mtspr   SPRN_DSISR, r6
206
207         /* Set partition DABR */
208         li      r5,3
209         ld      r6,VCPU_DABR(r4)
210         mtspr   SPRN_DABRX,r5
211         mtspr   SPRN_DABR,r6
212
213         /* Restore AMR and UAMOR, set AMOR to all 1s */
214         ld      r5,VCPU_AMR(r4)
215         ld      r6,VCPU_UAMOR(r4)
216         li      r7,-1
217         mtspr   SPRN_AMR,r5
218         mtspr   SPRN_UAMOR,r6
219         mtspr   SPRN_AMOR,r7
220
221         /* Clear out SLB */
222         li      r6,0
223         slbmte  r6,r6
224         slbia
225         ptesync
226
227         /* Increment entry count iff exit count is zero. */
228         ld      r5,HSTATE_KVM_VCORE(r13)
229         addi    r9,r5,VCORE_ENTRY_EXIT
230 21:     lwarx   r3,0,r9
231         cmpwi   r3,0x100                /* any threads starting to exit? */
232         bge     secondary_too_late      /* if so we're too late to the party */
233         addi    r3,r3,1
234         stwcx.  r3,0,r9
235         bne     21b
236
237         /* Primary thread switches to guest partition. */
238         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
239         lwz     r6,VCPU_PTID(r4)
240         cmpwi   r6,0
241         bne     20f
242         ld      r6,KVM_SDR1(r9)
243         lwz     r7,KVM_LPID(r9)
244         li      r0,LPID_RSVD            /* switch to reserved LPID */
245         mtspr   SPRN_LPID,r0
246         ptesync
247         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
248         mtspr   SPRN_LPID,r7
249         isync
250         li      r0,1
251         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
252         b       10f
253
254         /* Secondary threads wait for primary to have done partition switch */
255 20:     lbz     r0,VCORE_IN_GUEST(r5)
256         cmpwi   r0,0
257         beq     20b
258
259         /* Set LPCR.  Set the MER bit if there is a pending external irq. */
260 10:     ld      r8,KVM_LPCR(r9)
261         ld      r0,VCPU_PENDING_EXC(r4)
262         li      r7,(1 << BOOK3S_IRQPRIO_EXTERNAL)
263         oris    r7,r7,(1 << BOOK3S_IRQPRIO_EXTERNAL_LEVEL)@h
264         and.    r0,r0,r7
265         beq     11f
266         ori     r8,r8,LPCR_MER
267 11:     mtspr   SPRN_LPCR,r8
268         ld      r8,KVM_RMOR(r9)
269         mtspr   SPRN_RMOR,r8
270         isync
271
272         /* Check if HDEC expires soon */
273         mfspr   r3,SPRN_HDEC
274         cmpwi   r3,10
275         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
276         mr      r9,r4
277         blt     hdec_soon
278
279         /*
280          * Invalidate the TLB if we could possibly have stale TLB
281          * entries for this partition on this core due to the use
282          * of tlbiel.
283          * XXX maybe only need this on primary thread?
284          */
285         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
286         lwz     r5,VCPU_VCPUID(r4)
287         lhz     r6,PACAPACAINDEX(r13)
288         rldimi  r6,r5,0,62              /* XXX map as if threads 1:1 p:v */
289         lhz     r8,VCPU_LAST_CPU(r4)
290         sldi    r7,r6,1                 /* see if this is the same vcpu */
291         add     r7,r7,r9                /* as last ran on this pcpu */
292         lhz     r0,KVM_LAST_VCPU(r7)
293         cmpw    r6,r8                   /* on the same cpu core as last time? */
294         bne     3f
295         cmpw    r0,r5                   /* same vcpu as this core last ran? */
296         beq     1f
297 3:      sth     r6,VCPU_LAST_CPU(r4)    /* if not, invalidate partition TLB */
298         sth     r5,KVM_LAST_VCPU(r7)
299         li      r6,128
300         mtctr   r6
301         li      r7,0x800                /* IS field = 0b10 */
302         ptesync
303 2:      tlbiel  r7
304         addi    r7,r7,0x1000
305         bdnz    2b
306         ptesync
307 1:
308
309         /* Save purr/spurr */
310         mfspr   r5,SPRN_PURR
311         mfspr   r6,SPRN_SPURR
312         std     r5,HSTATE_PURR(r13)
313         std     r6,HSTATE_SPURR(r13)
314         ld      r7,VCPU_PURR(r4)
315         ld      r8,VCPU_SPURR(r4)
316         mtspr   SPRN_PURR,r7
317         mtspr   SPRN_SPURR,r8
318
319         /* Load up guest SLB entries */
320         lwz     r5,VCPU_SLB_MAX(r4)
321         cmpwi   r5,0
322         beq     9f
323         mtctr   r5
324         addi    r6,r4,VCPU_SLB
325 1:      ld      r8,VCPU_SLB_E(r6)
326         ld      r9,VCPU_SLB_V(r6)
327         slbmte  r9,r8
328         addi    r6,r6,VCPU_SLB_SIZE
329         bdnz    1b
330 9:
331
332         /* Restore state of CTRL run bit; assume 1 on entry */
333         lwz     r5,VCPU_CTRL(r4)
334         andi.   r5,r5,1
335         bne     4f
336         mfspr   r6,SPRN_CTRLF
337         clrrdi  r6,r6,1
338         mtspr   SPRN_CTRLT,r6
339 4:
340         ld      r6, VCPU_CTR(r4)
341         lwz     r7, VCPU_XER(r4)
342
343         mtctr   r6
344         mtxer   r7
345
346         /* Move SRR0 and SRR1 into the respective regs */
347         ld      r6, VCPU_SRR0(r4)
348         ld      r7, VCPU_SRR1(r4)
349         mtspr   SPRN_SRR0, r6
350         mtspr   SPRN_SRR1, r7
351
352         ld      r10, VCPU_PC(r4)
353
354         ld      r11, VCPU_MSR(r4)       /* r10 = vcpu->arch.msr & ~MSR_HV */
355         rldicl  r11, r11, 63 - MSR_HV_LG, 1
356         rotldi  r11, r11, 1 + MSR_HV_LG
357         ori     r11, r11, MSR_ME
358
359 fast_guest_return:
360         mtspr   SPRN_HSRR0,r10
361         mtspr   SPRN_HSRR1,r11
362
363         /* Activate guest mode, so faults get handled by KVM */
364         li      r9, KVM_GUEST_MODE_GUEST
365         stb     r9, HSTATE_IN_GUEST(r13)
366
367         /* Enter guest */
368
369         ld      r5, VCPU_LR(r4)
370         lwz     r6, VCPU_CR(r4)
371         mtlr    r5
372         mtcr    r6
373
374         ld      r0, VCPU_GPR(r0)(r4)
375         ld      r1, VCPU_GPR(r1)(r4)
376         ld      r2, VCPU_GPR(r2)(r4)
377         ld      r3, VCPU_GPR(r3)(r4)
378         ld      r5, VCPU_GPR(r5)(r4)
379         ld      r6, VCPU_GPR(r6)(r4)
380         ld      r7, VCPU_GPR(r7)(r4)
381         ld      r8, VCPU_GPR(r8)(r4)
382         ld      r9, VCPU_GPR(r9)(r4)
383         ld      r10, VCPU_GPR(r10)(r4)
384         ld      r11, VCPU_GPR(r11)(r4)
385         ld      r12, VCPU_GPR(r12)(r4)
386         ld      r13, VCPU_GPR(r13)(r4)
387
388         ld      r4, VCPU_GPR(r4)(r4)
389
390         hrfid
391         b       .
392
393 /******************************************************************************
394  *                                                                            *
395  *                               Exit code                                    *
396  *                                                                            *
397  *****************************************************************************/
398
399 /*
400  * We come here from the first-level interrupt handlers.
401  */
402         .globl  kvmppc_interrupt
403 kvmppc_interrupt:
404         /*
405          * Register contents:
406          * R12          = interrupt vector
407          * R13          = PACA
408          * guest CR, R12 saved in shadow VCPU SCRATCH1/0
409          * guest R13 saved in SPRN_SCRATCH0
410          */
411         /* abuse host_r2 as third scratch area; we get r2 from PACATOC(r13) */
412         std     r9, HSTATE_HOST_R2(r13)
413         ld      r9, HSTATE_KVM_VCPU(r13)
414
415         /* Save registers */
416
417         std     r0, VCPU_GPR(r0)(r9)
418         std     r1, VCPU_GPR(r1)(r9)
419         std     r2, VCPU_GPR(r2)(r9)
420         std     r3, VCPU_GPR(r3)(r9)
421         std     r4, VCPU_GPR(r4)(r9)
422         std     r5, VCPU_GPR(r5)(r9)
423         std     r6, VCPU_GPR(r6)(r9)
424         std     r7, VCPU_GPR(r7)(r9)
425         std     r8, VCPU_GPR(r8)(r9)
426         ld      r0, HSTATE_HOST_R2(r13)
427         std     r0, VCPU_GPR(r9)(r9)
428         std     r10, VCPU_GPR(r10)(r9)
429         std     r11, VCPU_GPR(r11)(r9)
430         ld      r3, HSTATE_SCRATCH0(r13)
431         lwz     r4, HSTATE_SCRATCH1(r13)
432         std     r3, VCPU_GPR(r12)(r9)
433         stw     r4, VCPU_CR(r9)
434
435         /* Restore R1/R2 so we can handle faults */
436         ld      r1, HSTATE_HOST_R1(r13)
437         ld      r2, PACATOC(r13)
438
439         mfspr   r10, SPRN_SRR0
440         mfspr   r11, SPRN_SRR1
441         std     r10, VCPU_SRR0(r9)
442         std     r11, VCPU_SRR1(r9)
443         andi.   r0, r12, 2              /* need to read HSRR0/1? */
444         beq     1f
445         mfspr   r10, SPRN_HSRR0
446         mfspr   r11, SPRN_HSRR1
447         clrrdi  r12, r12, 2
448 1:      std     r10, VCPU_PC(r9)
449         std     r11, VCPU_MSR(r9)
450
451         GET_SCRATCH0(r3)
452         mflr    r4
453         std     r3, VCPU_GPR(r13)(r9)
454         std     r4, VCPU_LR(r9)
455
456         /* Unset guest mode */
457         li      r0, KVM_GUEST_MODE_NONE
458         stb     r0, HSTATE_IN_GUEST(r13)
459
460         stw     r12,VCPU_TRAP(r9)
461
462         /* See if this is a leftover HDEC interrupt */
463         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
464         bne     2f
465         mfspr   r3,SPRN_HDEC
466         cmpwi   r3,0
467         bge     ignore_hdec
468 2:
469         /* See if this is something we can handle in real mode */
470         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
471         beq     hcall_try_real_mode
472 hcall_real_cont:
473
474         /* Check for mediated interrupts (could be done earlier really ...) */
475         cmpwi   r12,BOOK3S_INTERRUPT_EXTERNAL
476         bne+    1f
477         ld      r5,VCPU_KVM(r9)
478         ld      r5,KVM_LPCR(r5)
479         andi.   r0,r11,MSR_EE
480         beq     1f
481         andi.   r0,r5,LPCR_MER
482         bne     bounce_ext_interrupt
483 1:
484
485         /* Save DEC */
486         mfspr   r5,SPRN_DEC
487         mftb    r6
488         extsw   r5,r5
489         add     r5,r5,r6
490         std     r5,VCPU_DEC_EXPIRES(r9)
491
492         /* Save HEIR (HV emulation assist reg) in last_inst
493            if this is an HEI (HV emulation interrupt, e40) */
494         li      r3,-1
495         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
496         bne     11f
497         mfspr   r3,SPRN_HEIR
498 11:     stw     r3,VCPU_LAST_INST(r9)
499
500         /* Save more register state  */
501         mfxer   r5
502         mfdar   r6
503         mfdsisr r7
504         mfctr   r8
505
506         stw     r5, VCPU_XER(r9)
507         std     r6, VCPU_DAR(r9)
508         stw     r7, VCPU_DSISR(r9)
509         std     r8, VCPU_CTR(r9)
510         /* grab HDAR & HDSISR if HV data storage interrupt (HDSI) */
511         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
512         beq     6f
513 7:      std     r6, VCPU_FAULT_DAR(r9)
514         stw     r7, VCPU_FAULT_DSISR(r9)
515
516         /* Save guest CTRL register, set runlatch to 1 */
517         mfspr   r6,SPRN_CTRLF
518         stw     r6,VCPU_CTRL(r9)
519         andi.   r0,r6,1
520         bne     4f
521         ori     r6,r6,1
522         mtspr   SPRN_CTRLT,r6
523 4:
524         /* Read the guest SLB and save it away */
525         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
526         mtctr   r0
527         li      r6,0
528         addi    r7,r9,VCPU_SLB
529         li      r5,0
530 1:      slbmfee r8,r6
531         andis.  r0,r8,SLB_ESID_V@h
532         beq     2f
533         add     r8,r8,r6                /* put index in */
534         slbmfev r3,r6
535         std     r8,VCPU_SLB_E(r7)
536         std     r3,VCPU_SLB_V(r7)
537         addi    r7,r7,VCPU_SLB_SIZE
538         addi    r5,r5,1
539 2:      addi    r6,r6,1
540         bdnz    1b
541         stw     r5,VCPU_SLB_MAX(r9)
542
543         /*
544          * Save the guest PURR/SPURR
545          */
546         mfspr   r5,SPRN_PURR
547         mfspr   r6,SPRN_SPURR
548         ld      r7,VCPU_PURR(r9)
549         ld      r8,VCPU_SPURR(r9)
550         std     r5,VCPU_PURR(r9)
551         std     r6,VCPU_SPURR(r9)
552         subf    r5,r7,r5
553         subf    r6,r8,r6
554
555         /*
556          * Restore host PURR/SPURR and add guest times
557          * so that the time in the guest gets accounted.
558          */
559         ld      r3,HSTATE_PURR(r13)
560         ld      r4,HSTATE_SPURR(r13)
561         add     r3,r3,r5
562         add     r4,r4,r6
563         mtspr   SPRN_PURR,r3
564         mtspr   SPRN_SPURR,r4
565
566         /* Clear out SLB */
567         li      r5,0
568         slbmte  r5,r5
569         slbia
570         ptesync
571
572 hdec_soon:
573         /* Increment the threads-exiting-guest count in the 0xff00
574            bits of vcore->entry_exit_count */
575         lwsync
576         ld      r5,HSTATE_KVM_VCORE(r13)
577         addi    r6,r5,VCORE_ENTRY_EXIT
578 41:     lwarx   r3,0,r6
579         addi    r0,r3,0x100
580         stwcx.  r0,0,r6
581         bne     41b
582
583         /*
584          * At this point we have an interrupt that we have to pass
585          * up to the kernel or qemu; we can't handle it in real mode.
586          * Thus we have to do a partition switch, so we have to
587          * collect the other threads, if we are the first thread
588          * to take an interrupt.  To do this, we set the HDEC to 0,
589          * which causes an HDEC interrupt in all threads within 2ns
590          * because the HDEC register is shared between all 4 threads.
591          * However, we don't need to bother if this is an HDEC
592          * interrupt, since the other threads will already be on their
593          * way here in that case.
594          */
595         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
596         beq     40f
597         cmpwi   r3,0x100        /* Are we the first here? */
598         bge     40f
599         cmpwi   r3,1
600         ble     40f
601         li      r0,0
602         mtspr   SPRN_HDEC,r0
603 40:
604
605         /* Secondary threads wait for primary to do partition switch */
606         ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
607         ld      r5,HSTATE_KVM_VCORE(r13)
608         lwz     r3,VCPU_PTID(r9)
609         cmpwi   r3,0
610         beq     15f
611         HMT_LOW
612 13:     lbz     r3,VCORE_IN_GUEST(r5)
613         cmpwi   r3,0
614         bne     13b
615         HMT_MEDIUM
616         b       16f
617
618         /* Primary thread waits for all the secondaries to exit guest */
619 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
620         srwi    r0,r3,8
621         clrldi  r3,r3,56
622         cmpw    r3,r0
623         bne     15b
624         isync
625
626         /* Primary thread switches back to host partition */
627         ld      r6,KVM_HOST_SDR1(r4)
628         lwz     r7,KVM_HOST_LPID(r4)
629         li      r8,LPID_RSVD            /* switch to reserved LPID */
630         mtspr   SPRN_LPID,r8
631         ptesync
632         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
633         mtspr   SPRN_LPID,r7
634         isync
635         li      r0,0
636         stb     r0,VCORE_IN_GUEST(r5)
637         lis     r8,0x7fff               /* MAX_INT@h */
638         mtspr   SPRN_HDEC,r8
639
640 16:     ld      r8,KVM_HOST_LPCR(r4)
641         mtspr   SPRN_LPCR,r8
642         isync
643
644         /* load host SLB entries */
645         ld      r8,PACA_SLBSHADOWPTR(r13)
646
647         .rept   SLB_NUM_BOLTED
648         ld      r5,SLBSHADOW_SAVEAREA(r8)
649         ld      r6,SLBSHADOW_SAVEAREA+8(r8)
650         andis.  r7,r5,SLB_ESID_V@h
651         beq     1f
652         slbmte  r6,r5
653 1:      addi    r8,r8,16
654         .endr
655
656         /* Save and reset AMR and UAMOR before turning on the MMU */
657         mfspr   r5,SPRN_AMR
658         mfspr   r6,SPRN_UAMOR
659         std     r5,VCPU_AMR(r9)
660         std     r6,VCPU_UAMOR(r9)
661         li      r6,0
662         mtspr   SPRN_AMR,r6
663
664         /* Restore host DABR and DABRX */
665         ld      r5,HSTATE_DABR(r13)
666         li      r6,7
667         mtspr   SPRN_DABR,r5
668         mtspr   SPRN_DABRX,r6
669
670         /* Switch DSCR back to host value */
671         mfspr   r8, SPRN_DSCR
672         ld      r7, HSTATE_DSCR(r13)
673         std     r8, VCPU_DSCR(r7)
674         mtspr   SPRN_DSCR, r7
675
676         /* Save non-volatile GPRs */
677         std     r14, VCPU_GPR(r14)(r9)
678         std     r15, VCPU_GPR(r15)(r9)
679         std     r16, VCPU_GPR(r16)(r9)
680         std     r17, VCPU_GPR(r17)(r9)
681         std     r18, VCPU_GPR(r18)(r9)
682         std     r19, VCPU_GPR(r19)(r9)
683         std     r20, VCPU_GPR(r20)(r9)
684         std     r21, VCPU_GPR(r21)(r9)
685         std     r22, VCPU_GPR(r22)(r9)
686         std     r23, VCPU_GPR(r23)(r9)
687         std     r24, VCPU_GPR(r24)(r9)
688         std     r25, VCPU_GPR(r25)(r9)
689         std     r26, VCPU_GPR(r26)(r9)
690         std     r27, VCPU_GPR(r27)(r9)
691         std     r28, VCPU_GPR(r28)(r9)
692         std     r29, VCPU_GPR(r29)(r9)
693         std     r30, VCPU_GPR(r30)(r9)
694         std     r31, VCPU_GPR(r31)(r9)
695
696         /* Save SPRGs */
697         mfspr   r3, SPRN_SPRG0
698         mfspr   r4, SPRN_SPRG1
699         mfspr   r5, SPRN_SPRG2
700         mfspr   r6, SPRN_SPRG3
701         std     r3, VCPU_SPRG0(r9)
702         std     r4, VCPU_SPRG1(r9)
703         std     r5, VCPU_SPRG2(r9)
704         std     r6, VCPU_SPRG3(r9)
705
706         /* Increment yield count if they have a VPA */
707         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
708         cmpdi   r8, 0
709         beq     25f
710         lwz     r3, LPPACA_YIELDCOUNT(r8)
711         addi    r3, r3, 1
712         stw     r3, LPPACA_YIELDCOUNT(r8)
713 25:
714         /* Save PMU registers if requested */
715         /* r8 and cr0.eq are live here */
716         li      r3, 1
717         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
718         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
719         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
720         isync
721         beq     21f                     /* if no VPA, save PMU stuff anyway */
722         lbz     r7, LPPACA_PMCINUSE(r8)
723         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
724         bne     21f
725         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
726         b       22f
727 21:     mfspr   r5, SPRN_MMCR1
728         mfspr   r6, SPRN_MMCRA
729         std     r4, VCPU_MMCR(r9)
730         std     r5, VCPU_MMCR + 8(r9)
731         std     r6, VCPU_MMCR + 16(r9)
732         mfspr   r3, SPRN_PMC1
733         mfspr   r4, SPRN_PMC2
734         mfspr   r5, SPRN_PMC3
735         mfspr   r6, SPRN_PMC4
736         mfspr   r7, SPRN_PMC5
737         mfspr   r8, SPRN_PMC6
738         stw     r3, VCPU_PMC(r9)
739         stw     r4, VCPU_PMC + 4(r9)
740         stw     r5, VCPU_PMC + 8(r9)
741         stw     r6, VCPU_PMC + 12(r9)
742         stw     r7, VCPU_PMC + 16(r9)
743         stw     r8, VCPU_PMC + 20(r9)
744 22:
745         /* save FP state */
746         mr      r3, r9
747         bl      .kvmppc_save_fp
748
749         /* Secondary threads go off to take a nap */
750         lwz     r0,VCPU_PTID(r3)
751         cmpwi   r0,0
752         bne     secondary_nap
753
754         /*
755          * Reload DEC.  HDEC interrupts were disabled when
756          * we reloaded the host's LPCR value.
757          */
758         ld      r3, HSTATE_DECEXP(r13)
759         mftb    r4
760         subf    r4, r4, r3
761         mtspr   SPRN_DEC, r4
762
763         /* Reload the host's PMU registers */
764         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
765         lbz     r4, LPPACA_PMCINUSE(r3)
766         cmpwi   r4, 0
767         beq     23f                     /* skip if not */
768         lwz     r3, HSTATE_PMC(r13)
769         lwz     r4, HSTATE_PMC + 4(r13)
770         lwz     r5, HSTATE_PMC + 8(r13)
771         lwz     r6, HSTATE_PMC + 12(r13)
772         lwz     r8, HSTATE_PMC + 16(r13)
773         lwz     r9, HSTATE_PMC + 20(r13)
774         mtspr   SPRN_PMC1, r3
775         mtspr   SPRN_PMC2, r4
776         mtspr   SPRN_PMC3, r5
777         mtspr   SPRN_PMC4, r6
778         mtspr   SPRN_PMC5, r8
779         mtspr   SPRN_PMC6, r9
780         ld      r3, HSTATE_MMCR(r13)
781         ld      r4, HSTATE_MMCR + 8(r13)
782         ld      r5, HSTATE_MMCR + 16(r13)
783         mtspr   SPRN_MMCR1, r4
784         mtspr   SPRN_MMCRA, r5
785         mtspr   SPRN_MMCR0, r3
786         isync
787 23:
788         /*
789          * For external and machine check interrupts, we need
790          * to call the Linux handler to process the interrupt.
791          * We do that by jumping to the interrupt vector address
792          * which we have in r12.  The [h]rfid at the end of the
793          * handler will return to the book3s_hv_interrupts.S code.
794          * For other interrupts we do the rfid to get back
795          * to the book3s_interrupts.S code here.
796          */
797         ld      r8, HSTATE_VMHANDLER(r13)
798         ld      r7, HSTATE_HOST_MSR(r13)
799
800         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
801         beq     11f
802         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
803
804         /* RFI into the highmem handler, or branch to interrupt handler */
805         mfmsr   r6
806         mtctr   r12
807         li      r0, MSR_RI
808         andc    r6, r6, r0
809         mtmsrd  r6, 1                   /* Clear RI in MSR */
810         mtsrr0  r8
811         mtsrr1  r7
812         beqctr
813         RFI
814
815 11:     mtspr   SPRN_HSRR0, r8
816         mtspr   SPRN_HSRR1, r7
817         ba      0x500
818
819 6:      mfspr   r6,SPRN_HDAR
820         mfspr   r7,SPRN_HDSISR
821         b       7b
822
823 /*
824  * Try to handle an hcall in real mode.
825  * Returns to the guest if we handle it, or continues on up to
826  * the kernel if we can't (i.e. if we don't have a handler for
827  * it, or if the handler returns H_TOO_HARD).
828  */
829         .globl  hcall_try_real_mode
830 hcall_try_real_mode:
831         ld      r3,VCPU_GPR(r3)(r9)
832         andi.   r0,r11,MSR_PR
833         bne     hcall_real_cont
834         clrrdi  r3,r3,2
835         cmpldi  r3,hcall_real_table_end - hcall_real_table
836         bge     hcall_real_cont
837         LOAD_REG_ADDR(r4, hcall_real_table)
838         lwzx    r3,r3,r4
839         cmpwi   r3,0
840         beq     hcall_real_cont
841         add     r3,r3,r4
842         mtctr   r3
843         mr      r3,r9           /* get vcpu pointer */
844         ld      r4,VCPU_GPR(r4)(r9)
845         bctrl
846         cmpdi   r3,H_TOO_HARD
847         beq     hcall_real_fallback
848         ld      r4,HSTATE_KVM_VCPU(r13)
849         std     r3,VCPU_GPR(r3)(r4)
850         ld      r10,VCPU_PC(r4)
851         ld      r11,VCPU_MSR(r4)
852         b       fast_guest_return
853
854         /* We've attempted a real mode hcall, but it's punted it back
855          * to userspace.  We need to restore some clobbered volatiles
856          * before resuming the pass-it-to-qemu path */
857 hcall_real_fallback:
858         li      r12,BOOK3S_INTERRUPT_SYSCALL
859         ld      r9, HSTATE_KVM_VCPU(r13)
860         ld      r11, VCPU_MSR(r9)
861
862         b       hcall_real_cont
863
864         .globl  hcall_real_table
865 hcall_real_table:
866         .long   0               /* 0 - unused */
867         .long   .kvmppc_h_remove - hcall_real_table
868         .long   .kvmppc_h_enter - hcall_real_table
869         .long   .kvmppc_h_read - hcall_real_table
870         .long   0               /* 0x10 - H_CLEAR_MOD */
871         .long   0               /* 0x14 - H_CLEAR_REF */
872         .long   .kvmppc_h_protect - hcall_real_table
873         .long   0               /* 0x1c - H_GET_TCE */
874         .long   .kvmppc_h_put_tce - hcall_real_table
875         .long   0               /* 0x24 - H_SET_SPRG0 */
876         .long   .kvmppc_h_set_dabr - hcall_real_table
877         .long   0               /* 0x2c */
878         .long   0               /* 0x30 */
879         .long   0               /* 0x34 */
880         .long   0               /* 0x38 */
881         .long   0               /* 0x3c */
882         .long   0               /* 0x40 */
883         .long   0               /* 0x44 */
884         .long   0               /* 0x48 */
885         .long   0               /* 0x4c */
886         .long   0               /* 0x50 */
887         .long   0               /* 0x54 */
888         .long   0               /* 0x58 */
889         .long   0               /* 0x5c */
890         .long   0               /* 0x60 */
891         .long   0               /* 0x64 */
892         .long   0               /* 0x68 */
893         .long   0               /* 0x6c */
894         .long   0               /* 0x70 */
895         .long   0               /* 0x74 */
896         .long   0               /* 0x78 */
897         .long   0               /* 0x7c */
898         .long   0               /* 0x80 */
899         .long   0               /* 0x84 */
900         .long   0               /* 0x88 */
901         .long   0               /* 0x8c */
902         .long   0               /* 0x90 */
903         .long   0               /* 0x94 */
904         .long   0               /* 0x98 */
905         .long   0               /* 0x9c */
906         .long   0               /* 0xa0 */
907         .long   0               /* 0xa4 */
908         .long   0               /* 0xa8 */
909         .long   0               /* 0xac */
910         .long   0               /* 0xb0 */
911         .long   0               /* 0xb4 */
912         .long   0               /* 0xb8 */
913         .long   0               /* 0xbc */
914         .long   0               /* 0xc0 */
915         .long   0               /* 0xc4 */
916         .long   0               /* 0xc8 */
917         .long   0               /* 0xcc */
918         .long   0               /* 0xd0 */
919         .long   0               /* 0xd4 */
920         .long   0               /* 0xd8 */
921         .long   0               /* 0xdc */
922         .long   0               /* 0xe0 */
923         .long   0               /* 0xe4 */
924         .long   0               /* 0xe8 */
925         .long   0               /* 0xec */
926         .long   0               /* 0xf0 */
927         .long   0               /* 0xf4 */
928         .long   0               /* 0xf8 */
929         .long   0               /* 0xfc */
930         .long   0               /* 0x100 */
931         .long   0               /* 0x104 */
932         .long   0               /* 0x108 */
933         .long   0               /* 0x10c */
934         .long   0               /* 0x110 */
935         .long   0               /* 0x114 */
936         .long   0               /* 0x118 */
937         .long   0               /* 0x11c */
938         .long   0               /* 0x120 */
939         .long   .kvmppc_h_bulk_remove - hcall_real_table
940 hcall_real_table_end:
941
942 ignore_hdec:
943         mr      r4,r9
944         b       fast_guest_return
945
946 bounce_ext_interrupt:
947         mr      r4,r9
948         mtspr   SPRN_SRR0,r10
949         mtspr   SPRN_SRR1,r11
950         li      r10,BOOK3S_INTERRUPT_EXTERNAL
951         LOAD_REG_IMMEDIATE(r11,MSR_SF | MSR_ME);
952         b       fast_guest_return
953
954 _GLOBAL(kvmppc_h_set_dabr)
955         std     r4,VCPU_DABR(r3)
956         mtspr   SPRN_DABR,r4
957         li      r3,0
958         blr
959
960 secondary_too_late:
961         ld      r5,HSTATE_KVM_VCORE(r13)
962         HMT_LOW
963 13:     lbz     r3,VCORE_IN_GUEST(r5)
964         cmpwi   r3,0
965         bne     13b
966         HMT_MEDIUM
967         ld      r11,PACA_SLBSHADOWPTR(r13)
968
969         .rept   SLB_NUM_BOLTED
970         ld      r5,SLBSHADOW_SAVEAREA(r11)
971         ld      r6,SLBSHADOW_SAVEAREA+8(r11)
972         andis.  r7,r5,SLB_ESID_V@h
973         beq     1f
974         slbmte  r6,r5
975 1:      addi    r11,r11,16
976         .endr
977         b       50f
978
979 secondary_nap:
980         /* Clear any pending IPI */
981 50:     ld      r5, HSTATE_XICS_PHYS(r13)
982         li      r0, 0xff
983         li      r6, XICS_QIRR
984         stbcix  r0, r5, r6
985
986         /* increment the nap count and then go to nap mode */
987         ld      r4, HSTATE_KVM_VCORE(r13)
988         addi    r4, r4, VCORE_NAP_COUNT
989         lwsync                          /* make previous updates visible */
990 51:     lwarx   r3, 0, r4
991         addi    r3, r3, 1
992         stwcx.  r3, 0, r4
993         bne     51b
994         isync
995
996         mfspr   r4, SPRN_LPCR
997         li      r0, LPCR_PECE
998         andc    r4, r4, r0
999         ori     r4, r4, LPCR_PECE0      /* exit nap on interrupt */
1000         mtspr   SPRN_LPCR, r4
1001         li      r0, 0
1002         std     r0, HSTATE_SCRATCH0(r13)
1003         ptesync
1004         ld      r0, HSTATE_SCRATCH0(r13)
1005 1:      cmpd    r0, r0
1006         bne     1b
1007         nap
1008         b       .
1009
1010 /*
1011  * Save away FP, VMX and VSX registers.
1012  * r3 = vcpu pointer
1013  */
1014 _GLOBAL(kvmppc_save_fp)
1015         mfmsr   r9
1016         ori     r8,r9,MSR_FP
1017 #ifdef CONFIG_ALTIVEC
1018 BEGIN_FTR_SECTION
1019         oris    r8,r8,MSR_VEC@h
1020 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1021 #endif
1022 #ifdef CONFIG_VSX
1023 BEGIN_FTR_SECTION
1024         oris    r8,r8,MSR_VSX@h
1025 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1026 #endif
1027         mtmsrd  r8
1028         isync
1029 #ifdef CONFIG_VSX
1030 BEGIN_FTR_SECTION
1031         reg = 0
1032         .rept   32
1033         li      r6,reg*16+VCPU_VSRS
1034         stxvd2x reg,r6,r3
1035         reg = reg + 1
1036         .endr
1037 FTR_SECTION_ELSE
1038 #endif
1039         reg = 0
1040         .rept   32
1041         stfd    reg,reg*8+VCPU_FPRS(r3)
1042         reg = reg + 1
1043         .endr
1044 #ifdef CONFIG_VSX
1045 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1046 #endif
1047         mffs    fr0
1048         stfd    fr0,VCPU_FPSCR(r3)
1049
1050 #ifdef CONFIG_ALTIVEC
1051 BEGIN_FTR_SECTION
1052         reg = 0
1053         .rept   32
1054         li      r6,reg*16+VCPU_VRS
1055         stvx    reg,r6,r3
1056         reg = reg + 1
1057         .endr
1058         mfvscr  vr0
1059         li      r6,VCPU_VSCR
1060         stvx    vr0,r6,r3
1061 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1062 #endif
1063         mfspr   r6,SPRN_VRSAVE
1064         stw     r6,VCPU_VRSAVE(r3)
1065         mtmsrd  r9
1066         isync
1067         blr
1068
1069 /*
1070  * Load up FP, VMX and VSX registers
1071  * r4 = vcpu pointer
1072  */
1073         .globl  kvmppc_load_fp
1074 kvmppc_load_fp:
1075         mfmsr   r9
1076         ori     r8,r9,MSR_FP
1077 #ifdef CONFIG_ALTIVEC
1078 BEGIN_FTR_SECTION
1079         oris    r8,r8,MSR_VEC@h
1080 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1081 #endif
1082 #ifdef CONFIG_VSX
1083 BEGIN_FTR_SECTION
1084         oris    r8,r8,MSR_VSX@h
1085 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1086 #endif
1087         mtmsrd  r8
1088         isync
1089         lfd     fr0,VCPU_FPSCR(r4)
1090         MTFSF_L(fr0)
1091 #ifdef CONFIG_VSX
1092 BEGIN_FTR_SECTION
1093         reg = 0
1094         .rept   32
1095         li      r7,reg*16+VCPU_VSRS
1096         lxvd2x  reg,r7,r4
1097         reg = reg + 1
1098         .endr
1099 FTR_SECTION_ELSE
1100 #endif
1101         reg = 0
1102         .rept   32
1103         lfd     reg,reg*8+VCPU_FPRS(r4)
1104         reg = reg + 1
1105         .endr
1106 #ifdef CONFIG_VSX
1107 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1108 #endif
1109
1110 #ifdef CONFIG_ALTIVEC
1111 BEGIN_FTR_SECTION
1112         li      r7,VCPU_VSCR
1113         lvx     vr0,r7,r4
1114         mtvscr  vr0
1115         reg = 0
1116         .rept   32
1117         li      r7,reg*16+VCPU_VRS
1118         lvx     reg,r7,r4
1119         reg = reg + 1
1120         .endr
1121 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1122 #endif
1123         lwz     r7,VCPU_VRSAVE(r4)
1124         mtspr   SPRN_VRSAVE,r7
1125         blr