KVM: PPC: Allow book3s_hv guests to use SMT processor modes
[linux-2.6.git] / arch / powerpc / kvm / book3s_hv_rmhandlers.S
1 /*
2  * This program is free software; you can redistribute it and/or modify
3  * it under the terms of the GNU General Public License, version 2, as
4  * published by the Free Software Foundation.
5  *
6  * This program is distributed in the hope that it will be useful,
7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
9  * GNU General Public License for more details.
10  *
11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
12  *
13  * Derived from book3s_rmhandlers.S and other files, which are:
14  *
15  * Copyright SUSE Linux Products GmbH 2009
16  *
17  * Authors: Alexander Graf <agraf@suse.de>
18  */
19
20 #include <asm/ppc_asm.h>
21 #include <asm/kvm_asm.h>
22 #include <asm/reg.h>
23 #include <asm/page.h>
24 #include <asm/asm-offsets.h>
25 #include <asm/exception-64s.h>
26
27 /*****************************************************************************
28  *                                                                           *
29  *        Real Mode handlers that need to be in the linear mapping           *
30  *                                                                           *
31  ****************************************************************************/
32
33         .globl  kvmppc_skip_interrupt
34 kvmppc_skip_interrupt:
35         mfspr   r13,SPRN_SRR0
36         addi    r13,r13,4
37         mtspr   SPRN_SRR0,r13
38         GET_SCRATCH0(r13)
39         rfid
40         b       .
41
42         .globl  kvmppc_skip_Hinterrupt
43 kvmppc_skip_Hinterrupt:
44         mfspr   r13,SPRN_HSRR0
45         addi    r13,r13,4
46         mtspr   SPRN_HSRR0,r13
47         GET_SCRATCH0(r13)
48         hrfid
49         b       .
50
51 /*
52  * Call kvmppc_handler_trampoline_enter in real mode.
53  * Must be called with interrupts hard-disabled.
54  *
55  * Input Registers:
56  *
57  * LR = return address to continue at after eventually re-enabling MMU
58  */
59 _GLOBAL(kvmppc_hv_entry_trampoline)
60         mfmsr   r10
61         LOAD_REG_ADDR(r5, kvmppc_hv_entry)
62         li      r0,MSR_RI
63         andc    r0,r10,r0
64         li      r6,MSR_IR | MSR_DR
65         andc    r6,r10,r6
66         mtmsrd  r0,1            /* clear RI in MSR */
67         mtsrr0  r5
68         mtsrr1  r6
69         RFI
70
71 #define ULONG_SIZE              8
72 #define VCPU_GPR(n)             (VCPU_GPRS + (n * ULONG_SIZE))
73
74 /******************************************************************************
75  *                                                                            *
76  *                               Entry code                                   *
77  *                                                                            *
78  *****************************************************************************/
79
80 #define XICS_XIRR               4
81 #define XICS_QIRR               0xc
82
83 /*
84  * We come in here when wakened from nap mode on a secondary hw thread.
85  * Relocation is off and most register values are lost.
86  * r13 points to the PACA.
87  */
88         .globl  kvm_start_guest
89 kvm_start_guest:
90         ld      r1,PACAEMERGSP(r13)
91         subi    r1,r1,STACK_FRAME_OVERHEAD
92
93         /* get vcpu pointer */
94         ld      r4, HSTATE_KVM_VCPU(r13)
95
96         /* We got here with an IPI; clear it */
97         ld      r5, HSTATE_XICS_PHYS(r13)
98         li      r0, 0xff
99         li      r6, XICS_QIRR
100         li      r7, XICS_XIRR
101         lwzcix  r8, r5, r7              /* ack the interrupt */
102         sync
103         stbcix  r0, r5, r6              /* clear it */
104         stwcix  r8, r5, r7              /* EOI it */
105
106 .global kvmppc_hv_entry
107 kvmppc_hv_entry:
108
109         /* Required state:
110          *
111          * R4 = vcpu pointer
112          * MSR = ~IR|DR
113          * R13 = PACA
114          * R1 = host R1
115          * all other volatile GPRS = free
116          */
117         mflr    r0
118         std     r0, HSTATE_VMHANDLER(r13)
119
120         ld      r14, VCPU_GPR(r14)(r4)
121         ld      r15, VCPU_GPR(r15)(r4)
122         ld      r16, VCPU_GPR(r16)(r4)
123         ld      r17, VCPU_GPR(r17)(r4)
124         ld      r18, VCPU_GPR(r18)(r4)
125         ld      r19, VCPU_GPR(r19)(r4)
126         ld      r20, VCPU_GPR(r20)(r4)
127         ld      r21, VCPU_GPR(r21)(r4)
128         ld      r22, VCPU_GPR(r22)(r4)
129         ld      r23, VCPU_GPR(r23)(r4)
130         ld      r24, VCPU_GPR(r24)(r4)
131         ld      r25, VCPU_GPR(r25)(r4)
132         ld      r26, VCPU_GPR(r26)(r4)
133         ld      r27, VCPU_GPR(r27)(r4)
134         ld      r28, VCPU_GPR(r28)(r4)
135         ld      r29, VCPU_GPR(r29)(r4)
136         ld      r30, VCPU_GPR(r30)(r4)
137         ld      r31, VCPU_GPR(r31)(r4)
138
139         /* Load guest PMU registers */
140         /* R4 is live here (vcpu pointer) */
141         li      r3, 1
142         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
143         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
144         isync
145         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
146         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
147         lwz     r6, VCPU_PMC + 8(r4)
148         lwz     r7, VCPU_PMC + 12(r4)
149         lwz     r8, VCPU_PMC + 16(r4)
150         lwz     r9, VCPU_PMC + 20(r4)
151         mtspr   SPRN_PMC1, r3
152         mtspr   SPRN_PMC2, r5
153         mtspr   SPRN_PMC3, r6
154         mtspr   SPRN_PMC4, r7
155         mtspr   SPRN_PMC5, r8
156         mtspr   SPRN_PMC6, r9
157         ld      r3, VCPU_MMCR(r4)
158         ld      r5, VCPU_MMCR + 8(r4)
159         ld      r6, VCPU_MMCR + 16(r4)
160         mtspr   SPRN_MMCR1, r5
161         mtspr   SPRN_MMCRA, r6
162         mtspr   SPRN_MMCR0, r3
163         isync
164
165         /* Load up FP, VMX and VSX registers */
166         bl      kvmppc_load_fp
167
168         /* Switch DSCR to guest value */
169         ld      r5, VCPU_DSCR(r4)
170         mtspr   SPRN_DSCR, r5
171
172         /*
173          * Set the decrementer to the guest decrementer.
174          */
175         ld      r8,VCPU_DEC_EXPIRES(r4)
176         mftb    r7
177         subf    r3,r7,r8
178         mtspr   SPRN_DEC,r3
179         stw     r3,VCPU_DEC(r4)
180
181         ld      r5, VCPU_SPRG0(r4)
182         ld      r6, VCPU_SPRG1(r4)
183         ld      r7, VCPU_SPRG2(r4)
184         ld      r8, VCPU_SPRG3(r4)
185         mtspr   SPRN_SPRG0, r5
186         mtspr   SPRN_SPRG1, r6
187         mtspr   SPRN_SPRG2, r7
188         mtspr   SPRN_SPRG3, r8
189
190         /* Save R1 in the PACA */
191         std     r1, HSTATE_HOST_R1(r13)
192
193         /* Increment yield count if they have a VPA */
194         ld      r3, VCPU_VPA(r4)
195         cmpdi   r3, 0
196         beq     25f
197         lwz     r5, LPPACA_YIELDCOUNT(r3)
198         addi    r5, r5, 1
199         stw     r5, LPPACA_YIELDCOUNT(r3)
200 25:
201         /* Load up DAR and DSISR */
202         ld      r5, VCPU_DAR(r4)
203         lwz     r6, VCPU_DSISR(r4)
204         mtspr   SPRN_DAR, r5
205         mtspr   SPRN_DSISR, r6
206
207         /* Set partition DABR */
208         li      r5,3
209         ld      r6,VCPU_DABR(r4)
210         mtspr   SPRN_DABRX,r5
211         mtspr   SPRN_DABR,r6
212
213         /* Restore AMR and UAMOR, set AMOR to all 1s */
214         ld      r5,VCPU_AMR(r4)
215         ld      r6,VCPU_UAMOR(r4)
216         li      r7,-1
217         mtspr   SPRN_AMR,r5
218         mtspr   SPRN_UAMOR,r6
219         mtspr   SPRN_AMOR,r7
220
221         /* Clear out SLB */
222         li      r6,0
223         slbmte  r6,r6
224         slbia
225         ptesync
226
227         /* Increment entry count iff exit count is zero. */
228         ld      r5,HSTATE_KVM_VCORE(r13)
229         addi    r9,r5,VCORE_ENTRY_EXIT
230 21:     lwarx   r3,0,r9
231         cmpwi   r3,0x100                /* any threads starting to exit? */
232         bge     secondary_too_late      /* if so we're too late to the party */
233         addi    r3,r3,1
234         stwcx.  r3,0,r9
235         bne     21b
236
237         /* Primary thread switches to guest partition. */
238         lwz     r6,VCPU_PTID(r4)
239         cmpwi   r6,0
240         bne     20f
241         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
242         ld      r6,KVM_SDR1(r9)
243         lwz     r7,KVM_LPID(r9)
244         li      r0,LPID_RSVD            /* switch to reserved LPID */
245         mtspr   SPRN_LPID,r0
246         ptesync
247         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
248         mtspr   SPRN_LPID,r7
249         isync
250         li      r0,1
251         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
252         b       10f
253
254         /* Secondary threads wait for primary to have done partition switch */
255 20:     lbz     r0,VCORE_IN_GUEST(r5)
256         cmpwi   r0,0
257         beq     20b
258 10:     ld      r8,VCPU_LPCR(r4)
259         mtspr   SPRN_LPCR,r8
260         isync
261
262         /* Check if HDEC expires soon */
263         mfspr   r3,SPRN_HDEC
264         cmpwi   r3,10
265         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
266         mr      r9,r4
267         blt     hdec_soon
268
269         /*
270          * Invalidate the TLB if we could possibly have stale TLB
271          * entries for this partition on this core due to the use
272          * of tlbiel.
273          * XXX maybe only need this on primary thread?
274          */
275         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
276         lwz     r5,VCPU_VCPUID(r4)
277         lhz     r6,PACAPACAINDEX(r13)
278         rldimi  r6,r5,0,62              /* XXX map as if threads 1:1 p:v */
279         lhz     r8,VCPU_LAST_CPU(r4)
280         sldi    r7,r6,1                 /* see if this is the same vcpu */
281         add     r7,r7,r9                /* as last ran on this pcpu */
282         lhz     r0,KVM_LAST_VCPU(r7)
283         cmpw    r6,r8                   /* on the same cpu core as last time? */
284         bne     3f
285         cmpw    r0,r5                   /* same vcpu as this core last ran? */
286         beq     1f
287 3:      sth     r6,VCPU_LAST_CPU(r4)    /* if not, invalidate partition TLB */
288         sth     r5,KVM_LAST_VCPU(r7)
289         li      r6,128
290         mtctr   r6
291         li      r7,0x800                /* IS field = 0b10 */
292         ptesync
293 2:      tlbiel  r7
294         addi    r7,r7,0x1000
295         bdnz    2b
296         ptesync
297 1:
298
299         /* Save purr/spurr */
300         mfspr   r5,SPRN_PURR
301         mfspr   r6,SPRN_SPURR
302         std     r5,HSTATE_PURR(r13)
303         std     r6,HSTATE_SPURR(r13)
304         ld      r7,VCPU_PURR(r4)
305         ld      r8,VCPU_SPURR(r4)
306         mtspr   SPRN_PURR,r7
307         mtspr   SPRN_SPURR,r8
308
309         /* Load up guest SLB entries */
310         lwz     r5,VCPU_SLB_MAX(r4)
311         cmpwi   r5,0
312         beq     9f
313         mtctr   r5
314         addi    r6,r4,VCPU_SLB
315 1:      ld      r8,VCPU_SLB_E(r6)
316         ld      r9,VCPU_SLB_V(r6)
317         slbmte  r9,r8
318         addi    r6,r6,VCPU_SLB_SIZE
319         bdnz    1b
320 9:
321
322         /* Restore state of CTRL run bit; assume 1 on entry */
323         lwz     r5,VCPU_CTRL(r4)
324         andi.   r5,r5,1
325         bne     4f
326         mfspr   r6,SPRN_CTRLF
327         clrrdi  r6,r6,1
328         mtspr   SPRN_CTRLT,r6
329 4:
330         ld      r6, VCPU_CTR(r4)
331         lwz     r7, VCPU_XER(r4)
332
333         mtctr   r6
334         mtxer   r7
335
336         /* Move SRR0 and SRR1 into the respective regs */
337         ld      r6, VCPU_SRR0(r4)
338         ld      r7, VCPU_SRR1(r4)
339         mtspr   SPRN_SRR0, r6
340         mtspr   SPRN_SRR1, r7
341
342         ld      r10, VCPU_PC(r4)
343
344         ld      r11, VCPU_MSR(r4)       /* r10 = vcpu->arch.msr & ~MSR_HV */
345         rldicl  r11, r11, 63 - MSR_HV_LG, 1
346         rotldi  r11, r11, 1 + MSR_HV_LG
347         ori     r11, r11, MSR_ME
348
349 fast_guest_return:
350         mtspr   SPRN_HSRR0,r10
351         mtspr   SPRN_HSRR1,r11
352
353         /* Activate guest mode, so faults get handled by KVM */
354         li      r9, KVM_GUEST_MODE_GUEST
355         stb     r9, HSTATE_IN_GUEST(r13)
356
357         /* Enter guest */
358
359         ld      r5, VCPU_LR(r4)
360         lwz     r6, VCPU_CR(r4)
361         mtlr    r5
362         mtcr    r6
363
364         ld      r0, VCPU_GPR(r0)(r4)
365         ld      r1, VCPU_GPR(r1)(r4)
366         ld      r2, VCPU_GPR(r2)(r4)
367         ld      r3, VCPU_GPR(r3)(r4)
368         ld      r5, VCPU_GPR(r5)(r4)
369         ld      r6, VCPU_GPR(r6)(r4)
370         ld      r7, VCPU_GPR(r7)(r4)
371         ld      r8, VCPU_GPR(r8)(r4)
372         ld      r9, VCPU_GPR(r9)(r4)
373         ld      r10, VCPU_GPR(r10)(r4)
374         ld      r11, VCPU_GPR(r11)(r4)
375         ld      r12, VCPU_GPR(r12)(r4)
376         ld      r13, VCPU_GPR(r13)(r4)
377
378         ld      r4, VCPU_GPR(r4)(r4)
379
380         hrfid
381         b       .
382
383 /******************************************************************************
384  *                                                                            *
385  *                               Exit code                                    *
386  *                                                                            *
387  *****************************************************************************/
388
389 /*
390  * We come here from the first-level interrupt handlers.
391  */
392         .globl  kvmppc_interrupt
393 kvmppc_interrupt:
394         /*
395          * Register contents:
396          * R12          = interrupt vector
397          * R13          = PACA
398          * guest CR, R12 saved in shadow VCPU SCRATCH1/0
399          * guest R13 saved in SPRN_SCRATCH0
400          */
401         /* abuse host_r2 as third scratch area; we get r2 from PACATOC(r13) */
402         std     r9, HSTATE_HOST_R2(r13)
403         ld      r9, HSTATE_KVM_VCPU(r13)
404
405         /* Save registers */
406
407         std     r0, VCPU_GPR(r0)(r9)
408         std     r1, VCPU_GPR(r1)(r9)
409         std     r2, VCPU_GPR(r2)(r9)
410         std     r3, VCPU_GPR(r3)(r9)
411         std     r4, VCPU_GPR(r4)(r9)
412         std     r5, VCPU_GPR(r5)(r9)
413         std     r6, VCPU_GPR(r6)(r9)
414         std     r7, VCPU_GPR(r7)(r9)
415         std     r8, VCPU_GPR(r8)(r9)
416         ld      r0, HSTATE_HOST_R2(r13)
417         std     r0, VCPU_GPR(r9)(r9)
418         std     r10, VCPU_GPR(r10)(r9)
419         std     r11, VCPU_GPR(r11)(r9)
420         ld      r3, HSTATE_SCRATCH0(r13)
421         lwz     r4, HSTATE_SCRATCH1(r13)
422         std     r3, VCPU_GPR(r12)(r9)
423         stw     r4, VCPU_CR(r9)
424
425         /* Restore R1/R2 so we can handle faults */
426         ld      r1, HSTATE_HOST_R1(r13)
427         ld      r2, PACATOC(r13)
428
429         mfspr   r10, SPRN_SRR0
430         mfspr   r11, SPRN_SRR1
431         std     r10, VCPU_SRR0(r9)
432         std     r11, VCPU_SRR1(r9)
433         andi.   r0, r12, 2              /* need to read HSRR0/1? */
434         beq     1f
435         mfspr   r10, SPRN_HSRR0
436         mfspr   r11, SPRN_HSRR1
437         clrrdi  r12, r12, 2
438 1:      std     r10, VCPU_PC(r9)
439         std     r11, VCPU_MSR(r9)
440
441         GET_SCRATCH0(r3)
442         mflr    r4
443         std     r3, VCPU_GPR(r13)(r9)
444         std     r4, VCPU_LR(r9)
445
446         /* Unset guest mode */
447         li      r0, KVM_GUEST_MODE_NONE
448         stb     r0, HSTATE_IN_GUEST(r13)
449
450         stw     r12,VCPU_TRAP(r9)
451
452         /* See if this is a leftover HDEC interrupt */
453         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
454         bne     2f
455         mfspr   r3,SPRN_HDEC
456         cmpwi   r3,0
457         bge     ignore_hdec
458 2:
459         /* See if this is something we can handle in real mode */
460         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
461         beq     hcall_try_real_mode
462 hcall_real_cont:
463
464         /* Check for mediated interrupts (could be done earlier really ...) */
465         cmpwi   r12,BOOK3S_INTERRUPT_EXTERNAL
466         bne+    1f
467         ld      r5,VCPU_LPCR(r9)
468         andi.   r0,r11,MSR_EE
469         beq     1f
470         andi.   r0,r5,LPCR_MER
471         bne     bounce_ext_interrupt
472 1:
473
474         /* Save DEC */
475         mfspr   r5,SPRN_DEC
476         mftb    r6
477         extsw   r5,r5
478         add     r5,r5,r6
479         std     r5,VCPU_DEC_EXPIRES(r9)
480
481         /* Save HEIR (HV emulation assist reg) in last_inst
482            if this is an HEI (HV emulation interrupt, e40) */
483         li      r3,-1
484         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
485         bne     11f
486         mfspr   r3,SPRN_HEIR
487 11:     stw     r3,VCPU_LAST_INST(r9)
488
489         /* Save more register state  */
490         mfxer   r5
491         mfdar   r6
492         mfdsisr r7
493         mfctr   r8
494
495         stw     r5, VCPU_XER(r9)
496         std     r6, VCPU_DAR(r9)
497         stw     r7, VCPU_DSISR(r9)
498         std     r8, VCPU_CTR(r9)
499         /* grab HDAR & HDSISR if HV data storage interrupt (HDSI) */
500         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
501         beq     6f
502 7:      std     r6, VCPU_FAULT_DAR(r9)
503         stw     r7, VCPU_FAULT_DSISR(r9)
504
505         /* Save guest CTRL register, set runlatch to 1 */
506         mfspr   r6,SPRN_CTRLF
507         stw     r6,VCPU_CTRL(r9)
508         andi.   r0,r6,1
509         bne     4f
510         ori     r6,r6,1
511         mtspr   SPRN_CTRLT,r6
512 4:
513         /* Read the guest SLB and save it away */
514         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
515         mtctr   r0
516         li      r6,0
517         addi    r7,r9,VCPU_SLB
518         li      r5,0
519 1:      slbmfee r8,r6
520         andis.  r0,r8,SLB_ESID_V@h
521         beq     2f
522         add     r8,r8,r6                /* put index in */
523         slbmfev r3,r6
524         std     r8,VCPU_SLB_E(r7)
525         std     r3,VCPU_SLB_V(r7)
526         addi    r7,r7,VCPU_SLB_SIZE
527         addi    r5,r5,1
528 2:      addi    r6,r6,1
529         bdnz    1b
530         stw     r5,VCPU_SLB_MAX(r9)
531
532         /*
533          * Save the guest PURR/SPURR
534          */
535         mfspr   r5,SPRN_PURR
536         mfspr   r6,SPRN_SPURR
537         ld      r7,VCPU_PURR(r9)
538         ld      r8,VCPU_SPURR(r9)
539         std     r5,VCPU_PURR(r9)
540         std     r6,VCPU_SPURR(r9)
541         subf    r5,r7,r5
542         subf    r6,r8,r6
543
544         /*
545          * Restore host PURR/SPURR and add guest times
546          * so that the time in the guest gets accounted.
547          */
548         ld      r3,HSTATE_PURR(r13)
549         ld      r4,HSTATE_SPURR(r13)
550         add     r3,r3,r5
551         add     r4,r4,r6
552         mtspr   SPRN_PURR,r3
553         mtspr   SPRN_SPURR,r4
554
555         /* Clear out SLB */
556         li      r5,0
557         slbmte  r5,r5
558         slbia
559         ptesync
560
561 hdec_soon:
562         /* Increment the threads-exiting-guest count in the 0xff00
563            bits of vcore->entry_exit_count */
564         lwsync
565         ld      r5,HSTATE_KVM_VCORE(r13)
566         addi    r6,r5,VCORE_ENTRY_EXIT
567 41:     lwarx   r3,0,r6
568         addi    r0,r3,0x100
569         stwcx.  r0,0,r6
570         bne     41b
571
572         /*
573          * At this point we have an interrupt that we have to pass
574          * up to the kernel or qemu; we can't handle it in real mode.
575          * Thus we have to do a partition switch, so we have to
576          * collect the other threads, if we are the first thread
577          * to take an interrupt.  To do this, we set the HDEC to 0,
578          * which causes an HDEC interrupt in all threads within 2ns
579          * because the HDEC register is shared between all 4 threads.
580          * However, we don't need to bother if this is an HDEC
581          * interrupt, since the other threads will already be on their
582          * way here in that case.
583          */
584         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
585         beq     40f
586         cmpwi   r3,0x100        /* Are we the first here? */
587         bge     40f
588         cmpwi   r3,1
589         ble     40f
590         li      r0,0
591         mtspr   SPRN_HDEC,r0
592 40:
593
594         /* Secondary threads wait for primary to do partition switch */
595         ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
596         ld      r5,HSTATE_KVM_VCORE(r13)
597         lwz     r3,VCPU_PTID(r9)
598         cmpwi   r3,0
599         beq     15f
600         HMT_LOW
601 13:     lbz     r3,VCORE_IN_GUEST(r5)
602         cmpwi   r3,0
603         bne     13b
604         HMT_MEDIUM
605         b       16f
606
607         /* Primary thread waits for all the secondaries to exit guest */
608 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
609         srwi    r0,r3,8
610         clrldi  r3,r3,56
611         cmpw    r3,r0
612         bne     15b
613         isync
614
615         /* Primary thread switches back to host partition */
616         ld      r6,KVM_HOST_SDR1(r4)
617         lwz     r7,KVM_HOST_LPID(r4)
618         li      r8,LPID_RSVD            /* switch to reserved LPID */
619         mtspr   SPRN_LPID,r8
620         ptesync
621         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
622         mtspr   SPRN_LPID,r7
623         isync
624         li      r0,0
625         stb     r0,VCORE_IN_GUEST(r5)
626         lis     r8,0x7fff               /* MAX_INT@h */
627         mtspr   SPRN_HDEC,r8
628
629 16:     ld      r8,KVM_HOST_LPCR(r4)
630         mtspr   SPRN_LPCR,r8
631         isync
632
633         /* load host SLB entries */
634         ld      r8,PACA_SLBSHADOWPTR(r13)
635
636         .rept   SLB_NUM_BOLTED
637         ld      r5,SLBSHADOW_SAVEAREA(r8)
638         ld      r6,SLBSHADOW_SAVEAREA+8(r8)
639         andis.  r7,r5,SLB_ESID_V@h
640         beq     1f
641         slbmte  r6,r5
642 1:      addi    r8,r8,16
643         .endr
644
645         /* Save and reset AMR and UAMOR before turning on the MMU */
646         mfspr   r5,SPRN_AMR
647         mfspr   r6,SPRN_UAMOR
648         std     r5,VCPU_AMR(r9)
649         std     r6,VCPU_UAMOR(r9)
650         li      r6,0
651         mtspr   SPRN_AMR,r6
652
653         /* Restore host DABR and DABRX */
654         ld      r5,HSTATE_DABR(r13)
655         li      r6,7
656         mtspr   SPRN_DABR,r5
657         mtspr   SPRN_DABRX,r6
658
659         /* Switch DSCR back to host value */
660         mfspr   r8, SPRN_DSCR
661         ld      r7, HSTATE_DSCR(r13)
662         std     r8, VCPU_DSCR(r7)
663         mtspr   SPRN_DSCR, r7
664
665         /* Save non-volatile GPRs */
666         std     r14, VCPU_GPR(r14)(r9)
667         std     r15, VCPU_GPR(r15)(r9)
668         std     r16, VCPU_GPR(r16)(r9)
669         std     r17, VCPU_GPR(r17)(r9)
670         std     r18, VCPU_GPR(r18)(r9)
671         std     r19, VCPU_GPR(r19)(r9)
672         std     r20, VCPU_GPR(r20)(r9)
673         std     r21, VCPU_GPR(r21)(r9)
674         std     r22, VCPU_GPR(r22)(r9)
675         std     r23, VCPU_GPR(r23)(r9)
676         std     r24, VCPU_GPR(r24)(r9)
677         std     r25, VCPU_GPR(r25)(r9)
678         std     r26, VCPU_GPR(r26)(r9)
679         std     r27, VCPU_GPR(r27)(r9)
680         std     r28, VCPU_GPR(r28)(r9)
681         std     r29, VCPU_GPR(r29)(r9)
682         std     r30, VCPU_GPR(r30)(r9)
683         std     r31, VCPU_GPR(r31)(r9)
684
685         /* Save SPRGs */
686         mfspr   r3, SPRN_SPRG0
687         mfspr   r4, SPRN_SPRG1
688         mfspr   r5, SPRN_SPRG2
689         mfspr   r6, SPRN_SPRG3
690         std     r3, VCPU_SPRG0(r9)
691         std     r4, VCPU_SPRG1(r9)
692         std     r5, VCPU_SPRG2(r9)
693         std     r6, VCPU_SPRG3(r9)
694
695         /* Increment yield count if they have a VPA */
696         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
697         cmpdi   r8, 0
698         beq     25f
699         lwz     r3, LPPACA_YIELDCOUNT(r8)
700         addi    r3, r3, 1
701         stw     r3, LPPACA_YIELDCOUNT(r8)
702 25:
703         /* Save PMU registers if requested */
704         /* r8 and cr0.eq are live here */
705         li      r3, 1
706         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
707         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
708         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
709         isync
710         beq     21f                     /* if no VPA, save PMU stuff anyway */
711         lbz     r7, LPPACA_PMCINUSE(r8)
712         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
713         bne     21f
714         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
715         b       22f
716 21:     mfspr   r5, SPRN_MMCR1
717         mfspr   r6, SPRN_MMCRA
718         std     r4, VCPU_MMCR(r9)
719         std     r5, VCPU_MMCR + 8(r9)
720         std     r6, VCPU_MMCR + 16(r9)
721         mfspr   r3, SPRN_PMC1
722         mfspr   r4, SPRN_PMC2
723         mfspr   r5, SPRN_PMC3
724         mfspr   r6, SPRN_PMC4
725         mfspr   r7, SPRN_PMC5
726         mfspr   r8, SPRN_PMC6
727         stw     r3, VCPU_PMC(r9)
728         stw     r4, VCPU_PMC + 4(r9)
729         stw     r5, VCPU_PMC + 8(r9)
730         stw     r6, VCPU_PMC + 12(r9)
731         stw     r7, VCPU_PMC + 16(r9)
732         stw     r8, VCPU_PMC + 20(r9)
733 22:
734         /* save FP state */
735         mr      r3, r9
736         bl      .kvmppc_save_fp
737
738         /* Secondary threads go off to take a nap */
739         lwz     r0,VCPU_PTID(r3)
740         cmpwi   r0,0
741         bne     secondary_nap
742
743         /*
744          * Reload DEC.  HDEC interrupts were disabled when
745          * we reloaded the host's LPCR value.
746          */
747         ld      r3, HSTATE_DECEXP(r13)
748         mftb    r4
749         subf    r4, r4, r3
750         mtspr   SPRN_DEC, r4
751
752         /* Reload the host's PMU registers */
753         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
754         lbz     r4, LPPACA_PMCINUSE(r3)
755         cmpwi   r4, 0
756         beq     23f                     /* skip if not */
757         lwz     r3, HSTATE_PMC(r13)
758         lwz     r4, HSTATE_PMC + 4(r13)
759         lwz     r5, HSTATE_PMC + 8(r13)
760         lwz     r6, HSTATE_PMC + 12(r13)
761         lwz     r8, HSTATE_PMC + 16(r13)
762         lwz     r9, HSTATE_PMC + 20(r13)
763         mtspr   SPRN_PMC1, r3
764         mtspr   SPRN_PMC2, r4
765         mtspr   SPRN_PMC3, r5
766         mtspr   SPRN_PMC4, r6
767         mtspr   SPRN_PMC5, r8
768         mtspr   SPRN_PMC6, r9
769         ld      r3, HSTATE_MMCR(r13)
770         ld      r4, HSTATE_MMCR + 8(r13)
771         ld      r5, HSTATE_MMCR + 16(r13)
772         mtspr   SPRN_MMCR1, r4
773         mtspr   SPRN_MMCRA, r5
774         mtspr   SPRN_MMCR0, r3
775         isync
776 23:
777         /*
778          * For external and machine check interrupts, we need
779          * to call the Linux handler to process the interrupt.
780          * We do that by jumping to the interrupt vector address
781          * which we have in r12.  The [h]rfid at the end of the
782          * handler will return to the book3s_hv_interrupts.S code.
783          * For other interrupts we do the rfid to get back
784          * to the book3s_interrupts.S code here.
785          */
786         ld      r8, HSTATE_VMHANDLER(r13)
787         ld      r7, HSTATE_HOST_MSR(r13)
788
789         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
790         beq     11f
791         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
792
793         /* RFI into the highmem handler, or branch to interrupt handler */
794         mfmsr   r6
795         mtctr   r12
796         li      r0, MSR_RI
797         andc    r6, r6, r0
798         mtmsrd  r6, 1                   /* Clear RI in MSR */
799         mtsrr0  r8
800         mtsrr1  r7
801         beqctr
802         RFI
803
804 11:     mtspr   SPRN_HSRR0, r8
805         mtspr   SPRN_HSRR1, r7
806         ba      0x500
807
808 6:      mfspr   r6,SPRN_HDAR
809         mfspr   r7,SPRN_HDSISR
810         b       7b
811
812 /*
813  * Try to handle an hcall in real mode.
814  * Returns to the guest if we handle it, or continues on up to
815  * the kernel if we can't (i.e. if we don't have a handler for
816  * it, or if the handler returns H_TOO_HARD).
817  */
818         .globl  hcall_try_real_mode
819 hcall_try_real_mode:
820         ld      r3,VCPU_GPR(r3)(r9)
821         andi.   r0,r11,MSR_PR
822         bne     hcall_real_cont
823         clrrdi  r3,r3,2
824         cmpldi  r3,hcall_real_table_end - hcall_real_table
825         bge     hcall_real_cont
826         LOAD_REG_ADDR(r4, hcall_real_table)
827         lwzx    r3,r3,r4
828         cmpwi   r3,0
829         beq     hcall_real_cont
830         add     r3,r3,r4
831         mtctr   r3
832         mr      r3,r9           /* get vcpu pointer */
833         ld      r4,VCPU_GPR(r4)(r9)
834         bctrl
835         cmpdi   r3,H_TOO_HARD
836         beq     hcall_real_fallback
837         ld      r4,HSTATE_KVM_VCPU(r13)
838         std     r3,VCPU_GPR(r3)(r4)
839         ld      r10,VCPU_PC(r4)
840         ld      r11,VCPU_MSR(r4)
841         b       fast_guest_return
842
843         /* We've attempted a real mode hcall, but it's punted it back
844          * to userspace.  We need to restore some clobbered volatiles
845          * before resuming the pass-it-to-qemu path */
846 hcall_real_fallback:
847         li      r12,BOOK3S_INTERRUPT_SYSCALL
848         ld      r9, HSTATE_KVM_VCPU(r13)
849         ld      r11, VCPU_MSR(r9)
850
851         b       hcall_real_cont
852
853         .globl  hcall_real_table
854 hcall_real_table:
855         .long   0               /* 0 - unused */
856         .long   .kvmppc_h_remove - hcall_real_table
857         .long   .kvmppc_h_enter - hcall_real_table
858         .long   .kvmppc_h_read - hcall_real_table
859         .long   0               /* 0x10 - H_CLEAR_MOD */
860         .long   0               /* 0x14 - H_CLEAR_REF */
861         .long   .kvmppc_h_protect - hcall_real_table
862         .long   0               /* 0x1c - H_GET_TCE */
863         .long   .kvmppc_h_put_tce - hcall_real_table
864         .long   0               /* 0x24 - H_SET_SPRG0 */
865         .long   .kvmppc_h_set_dabr - hcall_real_table
866         .long   0               /* 0x2c */
867         .long   0               /* 0x30 */
868         .long   0               /* 0x34 */
869         .long   0               /* 0x38 */
870         .long   0               /* 0x3c */
871         .long   0               /* 0x40 */
872         .long   0               /* 0x44 */
873         .long   0               /* 0x48 */
874         .long   0               /* 0x4c */
875         .long   0               /* 0x50 */
876         .long   0               /* 0x54 */
877         .long   0               /* 0x58 */
878         .long   0               /* 0x5c */
879         .long   0               /* 0x60 */
880         .long   0               /* 0x64 */
881         .long   0               /* 0x68 */
882         .long   0               /* 0x6c */
883         .long   0               /* 0x70 */
884         .long   0               /* 0x74 */
885         .long   0               /* 0x78 */
886         .long   0               /* 0x7c */
887         .long   0               /* 0x80 */
888         .long   0               /* 0x84 */
889         .long   0               /* 0x88 */
890         .long   0               /* 0x8c */
891         .long   0               /* 0x90 */
892         .long   0               /* 0x94 */
893         .long   0               /* 0x98 */
894         .long   0               /* 0x9c */
895         .long   0               /* 0xa0 */
896         .long   0               /* 0xa4 */
897         .long   0               /* 0xa8 */
898         .long   0               /* 0xac */
899         .long   0               /* 0xb0 */
900         .long   0               /* 0xb4 */
901         .long   0               /* 0xb8 */
902         .long   0               /* 0xbc */
903         .long   0               /* 0xc0 */
904         .long   0               /* 0xc4 */
905         .long   0               /* 0xc8 */
906         .long   0               /* 0xcc */
907         .long   0               /* 0xd0 */
908         .long   0               /* 0xd4 */
909         .long   0               /* 0xd8 */
910         .long   0               /* 0xdc */
911         .long   0               /* 0xe0 */
912         .long   0               /* 0xe4 */
913         .long   0               /* 0xe8 */
914         .long   0               /* 0xec */
915         .long   0               /* 0xf0 */
916         .long   0               /* 0xf4 */
917         .long   0               /* 0xf8 */
918         .long   0               /* 0xfc */
919         .long   0               /* 0x100 */
920         .long   0               /* 0x104 */
921         .long   0               /* 0x108 */
922         .long   0               /* 0x10c */
923         .long   0               /* 0x110 */
924         .long   0               /* 0x114 */
925         .long   0               /* 0x118 */
926         .long   0               /* 0x11c */
927         .long   0               /* 0x120 */
928         .long   .kvmppc_h_bulk_remove - hcall_real_table
929 hcall_real_table_end:
930
931 ignore_hdec:
932         mr      r4,r9
933         b       fast_guest_return
934
935 bounce_ext_interrupt:
936         mr      r4,r9
937         mtspr   SPRN_SRR0,r10
938         mtspr   SPRN_SRR1,r11
939         li      r10,BOOK3S_INTERRUPT_EXTERNAL
940         LOAD_REG_IMMEDIATE(r11,MSR_SF | MSR_ME);
941         b       fast_guest_return
942
943 _GLOBAL(kvmppc_h_set_dabr)
944         std     r4,VCPU_DABR(r3)
945         mtspr   SPRN_DABR,r4
946         li      r3,0
947         blr
948
949 secondary_too_late:
950         ld      r5,HSTATE_KVM_VCORE(r13)
951         HMT_LOW
952 13:     lbz     r3,VCORE_IN_GUEST(r5)
953         cmpwi   r3,0
954         bne     13b
955         HMT_MEDIUM
956         ld      r11,PACA_SLBSHADOWPTR(r13)
957
958         .rept   SLB_NUM_BOLTED
959         ld      r5,SLBSHADOW_SAVEAREA(r11)
960         ld      r6,SLBSHADOW_SAVEAREA+8(r11)
961         andis.  r7,r5,SLB_ESID_V@h
962         beq     1f
963         slbmte  r6,r5
964 1:      addi    r11,r11,16
965         .endr
966         b       50f
967
968 secondary_nap:
969         /* Clear any pending IPI */
970 50:     ld      r5, HSTATE_XICS_PHYS(r13)
971         li      r0, 0xff
972         li      r6, XICS_QIRR
973         stbcix  r0, r5, r6
974
975         /* increment the nap count and then go to nap mode */
976         ld      r4, HSTATE_KVM_VCORE(r13)
977         addi    r4, r4, VCORE_NAP_COUNT
978         lwsync                          /* make previous updates visible */
979 51:     lwarx   r3, 0, r4
980         addi    r3, r3, 1
981         stwcx.  r3, 0, r4
982         bne     51b
983         isync
984
985         mfspr   r4, SPRN_LPCR
986         li      r0, LPCR_PECE
987         andc    r4, r4, r0
988         ori     r4, r4, LPCR_PECE0      /* exit nap on interrupt */
989         mtspr   SPRN_LPCR, r4
990         li      r0, 0
991         std     r0, HSTATE_SCRATCH0(r13)
992         ptesync
993         ld      r0, HSTATE_SCRATCH0(r13)
994 1:      cmpd    r0, r0
995         bne     1b
996         nap
997         b       .
998
999 /*
1000  * Save away FP, VMX and VSX registers.
1001  * r3 = vcpu pointer
1002  */
1003 _GLOBAL(kvmppc_save_fp)
1004         mfmsr   r9
1005         ori     r8,r9,MSR_FP
1006 #ifdef CONFIG_ALTIVEC
1007 BEGIN_FTR_SECTION
1008         oris    r8,r8,MSR_VEC@h
1009 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1010 #endif
1011 #ifdef CONFIG_VSX
1012 BEGIN_FTR_SECTION
1013         oris    r8,r8,MSR_VSX@h
1014 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1015 #endif
1016         mtmsrd  r8
1017         isync
1018 #ifdef CONFIG_VSX
1019 BEGIN_FTR_SECTION
1020         reg = 0
1021         .rept   32
1022         li      r6,reg*16+VCPU_VSRS
1023         stxvd2x reg,r6,r3
1024         reg = reg + 1
1025         .endr
1026 FTR_SECTION_ELSE
1027 #endif
1028         reg = 0
1029         .rept   32
1030         stfd    reg,reg*8+VCPU_FPRS(r3)
1031         reg = reg + 1
1032         .endr
1033 #ifdef CONFIG_VSX
1034 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1035 #endif
1036         mffs    fr0
1037         stfd    fr0,VCPU_FPSCR(r3)
1038
1039 #ifdef CONFIG_ALTIVEC
1040 BEGIN_FTR_SECTION
1041         reg = 0
1042         .rept   32
1043         li      r6,reg*16+VCPU_VRS
1044         stvx    reg,r6,r3
1045         reg = reg + 1
1046         .endr
1047         mfvscr  vr0
1048         li      r6,VCPU_VSCR
1049         stvx    vr0,r6,r3
1050 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1051 #endif
1052         mfspr   r6,SPRN_VRSAVE
1053         stw     r6,VCPU_VRSAVE(r3)
1054         mtmsrd  r9
1055         isync
1056         blr
1057
1058 /*
1059  * Load up FP, VMX and VSX registers
1060  * r4 = vcpu pointer
1061  */
1062         .globl  kvmppc_load_fp
1063 kvmppc_load_fp:
1064         mfmsr   r9
1065         ori     r8,r9,MSR_FP
1066 #ifdef CONFIG_ALTIVEC
1067 BEGIN_FTR_SECTION
1068         oris    r8,r8,MSR_VEC@h
1069 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1070 #endif
1071 #ifdef CONFIG_VSX
1072 BEGIN_FTR_SECTION
1073         oris    r8,r8,MSR_VSX@h
1074 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1075 #endif
1076         mtmsrd  r8
1077         isync
1078         lfd     fr0,VCPU_FPSCR(r4)
1079         MTFSF_L(fr0)
1080 #ifdef CONFIG_VSX
1081 BEGIN_FTR_SECTION
1082         reg = 0
1083         .rept   32
1084         li      r7,reg*16+VCPU_VSRS
1085         lxvd2x  reg,r7,r4
1086         reg = reg + 1
1087         .endr
1088 FTR_SECTION_ELSE
1089 #endif
1090         reg = 0
1091         .rept   32
1092         lfd     reg,reg*8+VCPU_FPRS(r4)
1093         reg = reg + 1
1094         .endr
1095 #ifdef CONFIG_VSX
1096 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1097 #endif
1098
1099 #ifdef CONFIG_ALTIVEC
1100 BEGIN_FTR_SECTION
1101         li      r7,VCPU_VSCR
1102         lvx     vr0,r7,r4
1103         mtvscr  vr0
1104         reg = 0
1105         .rept   32
1106         li      r7,reg*16+VCPU_VRS
1107         lvx     reg,r7,r4
1108         reg = reg + 1
1109         .endr
1110 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1111 #endif
1112         lwz     r7,VCPU_VRSAVE(r4)
1113         mtspr   SPRN_VRSAVE,r7
1114         blr