[PATCH] paravirt: Patch inline replacements for paravirt intercepts
[linux-2.6.git] / arch / i386 / kernel / entry.S
1 /*
2  *  linux/arch/i386/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  */
6
7 /*
8  * entry.S contains the system-call and fault low-level handling routines.
9  * This also contains the timer-interrupt handler, as well as all interrupts
10  * and faults that can result in a task-switch.
11  *
12  * NOTE: This code handles signal-recognition, which happens every time
13  * after a timer-interrupt and after each system call.
14  *
15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
16  * on a 486.
17  *
18  * Stack layout in 'ret_from_system_call':
19  *      ptrace needs to have all regs on the stack.
20  *      if the order here is changed, it needs to be
21  *      updated in fork.c:copy_process, signal.c:do_signal,
22  *      ptrace.c and ptrace.h
23  *
24  *       0(%esp) - %ebx
25  *       4(%esp) - %ecx
26  *       8(%esp) - %edx
27  *       C(%esp) - %esi
28  *      10(%esp) - %edi
29  *      14(%esp) - %ebp
30  *      18(%esp) - %eax
31  *      1C(%esp) - %ds
32  *      20(%esp) - %es
33  *      24(%esp) - %gs
34  *      28(%esp) - orig_eax
35  *      2C(%esp) - %eip
36  *      30(%esp) - %cs
37  *      34(%esp) - %eflags
38  *      38(%esp) - %oldesp
39  *      3C(%esp) - %oldss
40  *
41  * "current" is in register %ebx during any slow entries.
42  */
43
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/irqflags.h>
47 #include <asm/errno.h>
48 #include <asm/segment.h>
49 #include <asm/smp.h>
50 #include <asm/page.h>
51 #include <asm/desc.h>
52 #include <asm/percpu.h>
53 #include <asm/dwarf2.h>
54 #include "irq_vectors.h"
55
56 /*
57  * We use macros for low-level operations which need to be overridden
58  * for paravirtualization.  The following will never clobber any registers:
59  *   INTERRUPT_RETURN (aka. "iret")
60  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
61  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
62  *
63  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
64  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
65  * Allowing a register to be clobbered can shrink the paravirt replacement
66  * enough to patch inline, increasing performance.
67  */
68
69 #define nr_syscalls ((syscall_table_size)/4)
70
71 CF_MASK         = 0x00000001
72 TF_MASK         = 0x00000100
73 IF_MASK         = 0x00000200
74 DF_MASK         = 0x00000400 
75 NT_MASK         = 0x00004000
76 VM_MASK         = 0x00020000
77
78 #ifdef CONFIG_PREEMPT
79 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
80 #else
81 #define preempt_stop(clobbers)
82 #define resume_kernel           restore_nocheck
83 #endif
84
85 .macro TRACE_IRQS_IRET
86 #ifdef CONFIG_TRACE_IRQFLAGS
87         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
88         jz 1f
89         TRACE_IRQS_ON
90 1:
91 #endif
92 .endm
93
94 #ifdef CONFIG_VM86
95 #define resume_userspace_sig    check_userspace
96 #else
97 #define resume_userspace_sig    resume_userspace
98 #endif
99
100 #define SAVE_ALL \
101         cld; \
102         pushl %gs; \
103         CFI_ADJUST_CFA_OFFSET 4;\
104         /*CFI_REL_OFFSET gs, 0;*/\
105         pushl %es; \
106         CFI_ADJUST_CFA_OFFSET 4;\
107         /*CFI_REL_OFFSET es, 0;*/\
108         pushl %ds; \
109         CFI_ADJUST_CFA_OFFSET 4;\
110         /*CFI_REL_OFFSET ds, 0;*/\
111         pushl %eax; \
112         CFI_ADJUST_CFA_OFFSET 4;\
113         CFI_REL_OFFSET eax, 0;\
114         pushl %ebp; \
115         CFI_ADJUST_CFA_OFFSET 4;\
116         CFI_REL_OFFSET ebp, 0;\
117         pushl %edi; \
118         CFI_ADJUST_CFA_OFFSET 4;\
119         CFI_REL_OFFSET edi, 0;\
120         pushl %esi; \
121         CFI_ADJUST_CFA_OFFSET 4;\
122         CFI_REL_OFFSET esi, 0;\
123         pushl %edx; \
124         CFI_ADJUST_CFA_OFFSET 4;\
125         CFI_REL_OFFSET edx, 0;\
126         pushl %ecx; \
127         CFI_ADJUST_CFA_OFFSET 4;\
128         CFI_REL_OFFSET ecx, 0;\
129         pushl %ebx; \
130         CFI_ADJUST_CFA_OFFSET 4;\
131         CFI_REL_OFFSET ebx, 0;\
132         movl $(__USER_DS), %edx; \
133         movl %edx, %ds; \
134         movl %edx, %es; \
135         movl $(__KERNEL_PDA), %edx; \
136         movl %edx, %gs
137
138 #define RESTORE_INT_REGS \
139         popl %ebx;      \
140         CFI_ADJUST_CFA_OFFSET -4;\
141         CFI_RESTORE ebx;\
142         popl %ecx;      \
143         CFI_ADJUST_CFA_OFFSET -4;\
144         CFI_RESTORE ecx;\
145         popl %edx;      \
146         CFI_ADJUST_CFA_OFFSET -4;\
147         CFI_RESTORE edx;\
148         popl %esi;      \
149         CFI_ADJUST_CFA_OFFSET -4;\
150         CFI_RESTORE esi;\
151         popl %edi;      \
152         CFI_ADJUST_CFA_OFFSET -4;\
153         CFI_RESTORE edi;\
154         popl %ebp;      \
155         CFI_ADJUST_CFA_OFFSET -4;\
156         CFI_RESTORE ebp;\
157         popl %eax;      \
158         CFI_ADJUST_CFA_OFFSET -4;\
159         CFI_RESTORE eax
160
161 #define RESTORE_REGS    \
162         RESTORE_INT_REGS; \
163 1:      popl %ds;       \
164         CFI_ADJUST_CFA_OFFSET -4;\
165         /*CFI_RESTORE ds;*/\
166 2:      popl %es;       \
167         CFI_ADJUST_CFA_OFFSET -4;\
168         /*CFI_RESTORE es;*/\
169 3:      popl %gs;       \
170         CFI_ADJUST_CFA_OFFSET -4;\
171         /*CFI_RESTORE gs;*/\
172 .pushsection .fixup,"ax";       \
173 4:      movl $0,(%esp); \
174         jmp 1b;         \
175 5:      movl $0,(%esp); \
176         jmp 2b;         \
177 6:      movl $0,(%esp); \
178         jmp 3b;         \
179 .section __ex_table,"a";\
180         .align 4;       \
181         .long 1b,4b;    \
182         .long 2b,5b;    \
183         .long 3b,6b;    \
184 .popsection
185
186 #define RING0_INT_FRAME \
187         CFI_STARTPROC simple;\
188         CFI_SIGNAL_FRAME;\
189         CFI_DEF_CFA esp, 3*4;\
190         /*CFI_OFFSET cs, -2*4;*/\
191         CFI_OFFSET eip, -3*4
192
193 #define RING0_EC_FRAME \
194         CFI_STARTPROC simple;\
195         CFI_SIGNAL_FRAME;\
196         CFI_DEF_CFA esp, 4*4;\
197         /*CFI_OFFSET cs, -2*4;*/\
198         CFI_OFFSET eip, -3*4
199
200 #define RING0_PTREGS_FRAME \
201         CFI_STARTPROC simple;\
202         CFI_SIGNAL_FRAME;\
203         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
204         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
205         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
206         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
207         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
208         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
209         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
210         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
211         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
212         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
213         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
214         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
215
216 ENTRY(ret_from_fork)
217         CFI_STARTPROC
218         pushl %eax
219         CFI_ADJUST_CFA_OFFSET 4
220         call schedule_tail
221         GET_THREAD_INFO(%ebp)
222         popl %eax
223         CFI_ADJUST_CFA_OFFSET -4
224         pushl $0x0202                   # Reset kernel eflags
225         CFI_ADJUST_CFA_OFFSET 4
226         popfl
227         CFI_ADJUST_CFA_OFFSET -4
228         jmp syscall_exit
229         CFI_ENDPROC
230
231 /*
232  * Return to user mode is not as complex as all this looks,
233  * but we want the default path for a system call return to
234  * go as quickly as possible which is why some of this is
235  * less clear than it otherwise should be.
236  */
237
238         # userspace resumption stub bypassing syscall exit tracing
239         ALIGN
240         RING0_PTREGS_FRAME
241 ret_from_exception:
242         preempt_stop(CLBR_ANY)
243 ret_from_intr:
244         GET_THREAD_INFO(%ebp)
245 check_userspace:
246         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
247         movb PT_CS(%esp), %al
248         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
249         cmpl $USER_RPL, %eax
250         jb resume_kernel                # not returning to v8086 or userspace
251
252 ENTRY(resume_userspace)
253         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
254                                         # setting need_resched or sigpending
255                                         # between sampling and the iret
256         movl TI_flags(%ebp), %ecx
257         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
258                                         # int/exception return?
259         jne work_pending
260         jmp restore_all
261
262 #ifdef CONFIG_PREEMPT
263 ENTRY(resume_kernel)
264         DISABLE_INTERRUPTS(CLBR_ANY)
265         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
266         jnz restore_nocheck
267 need_resched:
268         movl TI_flags(%ebp), %ecx       # need_resched set ?
269         testb $_TIF_NEED_RESCHED, %cl
270         jz restore_all
271         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
272         jz restore_all
273         call preempt_schedule_irq
274         jmp need_resched
275 #endif
276         CFI_ENDPROC
277
278 /* SYSENTER_RETURN points to after the "sysenter" instruction in
279    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
280
281         # sysenter call handler stub
282 ENTRY(sysenter_entry)
283         CFI_STARTPROC simple
284         CFI_SIGNAL_FRAME
285         CFI_DEF_CFA esp, 0
286         CFI_REGISTER esp, ebp
287         movl TSS_sysenter_esp0(%esp),%esp
288 sysenter_past_esp:
289         /*
290          * No need to follow this irqs on/off section: the syscall
291          * disabled irqs and here we enable it straight after entry:
292          */
293         ENABLE_INTERRUPTS(CLBR_NONE)
294         pushl $(__USER_DS)
295         CFI_ADJUST_CFA_OFFSET 4
296         /*CFI_REL_OFFSET ss, 0*/
297         pushl %ebp
298         CFI_ADJUST_CFA_OFFSET 4
299         CFI_REL_OFFSET esp, 0
300         pushfl
301         CFI_ADJUST_CFA_OFFSET 4
302         pushl $(__USER_CS)
303         CFI_ADJUST_CFA_OFFSET 4
304         /*CFI_REL_OFFSET cs, 0*/
305         /*
306          * Push current_thread_info()->sysenter_return to the stack.
307          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
308          * pushed above; +8 corresponds to copy_thread's esp0 setting.
309          */
310         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
311         CFI_ADJUST_CFA_OFFSET 4
312         CFI_REL_OFFSET eip, 0
313
314 /*
315  * Load the potential sixth argument from user stack.
316  * Careful about security.
317  */
318         cmpl $__PAGE_OFFSET-3,%ebp
319         jae syscall_fault
320 1:      movl (%ebp),%ebp
321 .section __ex_table,"a"
322         .align 4
323         .long 1b,syscall_fault
324 .previous
325
326         pushl %eax
327         CFI_ADJUST_CFA_OFFSET 4
328         SAVE_ALL
329         GET_THREAD_INFO(%ebp)
330
331         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
332         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
333         jnz syscall_trace_entry
334         cmpl $(nr_syscalls), %eax
335         jae syscall_badsys
336         call *sys_call_table(,%eax,4)
337         movl %eax,PT_EAX(%esp)
338         DISABLE_INTERRUPTS(CLBR_ECX|CLBR_EDX)
339         TRACE_IRQS_OFF
340         movl TI_flags(%ebp), %ecx
341         testw $_TIF_ALLWORK_MASK, %cx
342         jne syscall_exit_work
343 /* if something modifies registers it must also disable sysexit */
344         movl PT_EIP(%esp), %edx
345         movl PT_OLDESP(%esp), %ecx
346         xorl %ebp,%ebp
347         TRACE_IRQS_ON
348 1:      mov  PT_GS(%esp), %gs
349         ENABLE_INTERRUPTS_SYSEXIT
350         CFI_ENDPROC
351 .pushsection .fixup,"ax"
352 2:      movl $0,PT_GS(%esp)
353         jmp 1b
354 .section __ex_table,"a"
355         .align 4
356         .long 1b,2b
357 .popsection
358
359         # system call handler stub
360 ENTRY(system_call)
361         RING0_INT_FRAME                 # can't unwind into user space anyway
362         pushl %eax                      # save orig_eax
363         CFI_ADJUST_CFA_OFFSET 4
364         SAVE_ALL
365         GET_THREAD_INFO(%ebp)
366         testl $TF_MASK,PT_EFLAGS(%esp)
367         jz no_singlestep
368         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
369 no_singlestep:
370                                         # system call tracing in operation / emulation
371         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
372         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
373         jnz syscall_trace_entry
374         cmpl $(nr_syscalls), %eax
375         jae syscall_badsys
376 syscall_call:
377         call *sys_call_table(,%eax,4)
378         movl %eax,PT_EAX(%esp)          # store the return value
379 syscall_exit:
380         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
381                                         # setting need_resched or sigpending
382                                         # between sampling and the iret
383         TRACE_IRQS_OFF
384         movl TI_flags(%ebp), %ecx
385         testw $_TIF_ALLWORK_MASK, %cx   # current->work
386         jne syscall_exit_work
387
388 restore_all:
389         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
390         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
391         # are returning to the kernel.
392         # See comments in process.c:copy_thread() for details.
393         movb PT_OLDSS(%esp), %ah
394         movb PT_CS(%esp), %al
395         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
396         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
397         CFI_REMEMBER_STATE
398         je ldt_ss                       # returning to user-space with LDT SS
399 restore_nocheck:
400         TRACE_IRQS_IRET
401 restore_nocheck_notrace:
402         RESTORE_REGS
403         addl $4, %esp                   # skip orig_eax/error_code
404         CFI_ADJUST_CFA_OFFSET -4
405 1:      INTERRUPT_RETURN
406 .section .fixup,"ax"
407 iret_exc:
408         TRACE_IRQS_ON
409         ENABLE_INTERRUPTS(CLBR_NONE)
410         pushl $0                        # no error code
411         pushl $do_iret_error
412         jmp error_code
413 .previous
414 .section __ex_table,"a"
415         .align 4
416         .long 1b,iret_exc
417 .previous
418
419         CFI_RESTORE_STATE
420 ldt_ss:
421         larl PT_OLDSS(%esp), %eax
422         jnz restore_nocheck
423         testl $0x00400000, %eax         # returning to 32bit stack?
424         jnz restore_nocheck             # allright, normal return
425
426 #ifdef CONFIG_PARAVIRT
427         /*
428          * The kernel can't run on a non-flat stack if paravirt mode
429          * is active.  Rather than try to fixup the high bits of
430          * ESP, bypass this code entirely.  This may break DOSemu
431          * and/or Wine support in a paravirt VM, although the option
432          * is still available to implement the setting of the high
433          * 16-bits in the INTERRUPT_RETURN paravirt-op.
434          */
435         cmpl $0, paravirt_ops+PARAVIRT_enabled
436         jne restore_nocheck
437 #endif
438
439         /* If returning to userspace with 16bit stack,
440          * try to fix the higher word of ESP, as the CPU
441          * won't restore it.
442          * This is an "official" bug of all the x86-compatible
443          * CPUs, which we can try to work around to make
444          * dosemu and wine happy. */
445         movl PT_OLDESP(%esp), %eax
446         movl %esp, %edx
447         call patch_espfix_desc
448         pushl $__ESPFIX_SS
449         CFI_ADJUST_CFA_OFFSET 4
450         pushl %eax
451         CFI_ADJUST_CFA_OFFSET 4
452         DISABLE_INTERRUPTS(CLBR_EAX)
453         TRACE_IRQS_OFF
454         lss (%esp), %esp
455         CFI_ADJUST_CFA_OFFSET -8
456         jmp restore_nocheck
457         CFI_ENDPROC
458
459         # perform work that needs to be done immediately before resumption
460         ALIGN
461         RING0_PTREGS_FRAME              # can't unwind into user space anyway
462 work_pending:
463         testb $_TIF_NEED_RESCHED, %cl
464         jz work_notifysig
465 work_resched:
466         call schedule
467         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
468                                         # setting need_resched or sigpending
469                                         # between sampling and the iret
470         TRACE_IRQS_OFF
471         movl TI_flags(%ebp), %ecx
472         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
473                                         # than syscall tracing?
474         jz restore_all
475         testb $_TIF_NEED_RESCHED, %cl
476         jnz work_resched
477
478 work_notifysig:                         # deal with pending signals and
479                                         # notify-resume requests
480 #ifdef CONFIG_VM86
481         testl $VM_MASK, PT_EFLAGS(%esp)
482         movl %esp, %eax
483         jne work_notifysig_v86          # returning to kernel-space or
484                                         # vm86-space
485         xorl %edx, %edx
486         call do_notify_resume
487         jmp resume_userspace_sig
488
489         ALIGN
490 work_notifysig_v86:
491         pushl %ecx                      # save ti_flags for do_notify_resume
492         CFI_ADJUST_CFA_OFFSET 4
493         call save_v86_state             # %eax contains pt_regs pointer
494         popl %ecx
495         CFI_ADJUST_CFA_OFFSET -4
496         movl %eax, %esp
497 #else
498         movl %esp, %eax
499 #endif
500         xorl %edx, %edx
501         call do_notify_resume
502         jmp resume_userspace_sig
503
504         # perform syscall exit tracing
505         ALIGN
506 syscall_trace_entry:
507         movl $-ENOSYS,PT_EAX(%esp)
508         movl %esp, %eax
509         xorl %edx,%edx
510         call do_syscall_trace
511         cmpl $0, %eax
512         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
513                                         # so must skip actual syscall
514         movl PT_ORIG_EAX(%esp), %eax
515         cmpl $(nr_syscalls), %eax
516         jnae syscall_call
517         jmp syscall_exit
518
519         # perform syscall exit tracing
520         ALIGN
521 syscall_exit_work:
522         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
523         jz work_pending
524         TRACE_IRQS_ON
525         ENABLE_INTERRUPTS(CLBR_ANY)     # could let do_syscall_trace() call
526                                         # schedule() instead
527         movl %esp, %eax
528         movl $1, %edx
529         call do_syscall_trace
530         jmp resume_userspace
531         CFI_ENDPROC
532
533         RING0_INT_FRAME                 # can't unwind into user space anyway
534 syscall_fault:
535         pushl %eax                      # save orig_eax
536         CFI_ADJUST_CFA_OFFSET 4
537         SAVE_ALL
538         GET_THREAD_INFO(%ebp)
539         movl $-EFAULT,PT_EAX(%esp)
540         jmp resume_userspace
541
542 syscall_badsys:
543         movl $-ENOSYS,PT_EAX(%esp)
544         jmp resume_userspace
545         CFI_ENDPROC
546
547 #define FIXUP_ESPFIX_STACK \
548         /* since we are on a wrong stack, we cant make it a C code :( */ \
549         movl %gs:PDA_cpu, %ebx; \
550         PER_CPU(cpu_gdt_descr, %ebx); \
551         movl GDS_address(%ebx), %ebx; \
552         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
553         addl %esp, %eax; \
554         pushl $__KERNEL_DS; \
555         CFI_ADJUST_CFA_OFFSET 4; \
556         pushl %eax; \
557         CFI_ADJUST_CFA_OFFSET 4; \
558         lss (%esp), %esp; \
559         CFI_ADJUST_CFA_OFFSET -8;
560 #define UNWIND_ESPFIX_STACK \
561         movl %ss, %eax; \
562         /* see if on espfix stack */ \
563         cmpw $__ESPFIX_SS, %ax; \
564         jne 27f; \
565         movl $__KERNEL_DS, %eax; \
566         movl %eax, %ds; \
567         movl %eax, %es; \
568         /* switch to normal stack */ \
569         FIXUP_ESPFIX_STACK; \
570 27:;
571
572 /*
573  * Build the entry stubs and pointer table with
574  * some assembler magic.
575  */
576 .data
577 ENTRY(interrupt)
578 .text
579
580 vector=0
581 ENTRY(irq_entries_start)
582         RING0_INT_FRAME
583 .rept NR_IRQS
584         ALIGN
585  .if vector
586         CFI_ADJUST_CFA_OFFSET -4
587  .endif
588 1:      pushl $~(vector)
589         CFI_ADJUST_CFA_OFFSET 4
590         jmp common_interrupt
591 .data
592         .long 1b
593 .text
594 vector=vector+1
595 .endr
596
597 /*
598  * the CPU automatically disables interrupts when executing an IRQ vector,
599  * so IRQ-flags tracing has to follow that:
600  */
601         ALIGN
602 common_interrupt:
603         SAVE_ALL
604         TRACE_IRQS_OFF
605         movl %esp,%eax
606         call do_IRQ
607         jmp ret_from_intr
608         CFI_ENDPROC
609
610 #define BUILD_INTERRUPT(name, nr)       \
611 ENTRY(name)                             \
612         RING0_INT_FRAME;                \
613         pushl $~(nr);                   \
614         CFI_ADJUST_CFA_OFFSET 4;        \
615         SAVE_ALL;                       \
616         TRACE_IRQS_OFF                  \
617         movl %esp,%eax;                 \
618         call smp_/**/name;              \
619         jmp ret_from_intr;              \
620         CFI_ENDPROC
621
622 /* The include is where all of the SMP etc. interrupts come from */
623 #include "entry_arch.h"
624
625 KPROBE_ENTRY(page_fault)
626         RING0_EC_FRAME
627         pushl $do_page_fault
628         CFI_ADJUST_CFA_OFFSET 4
629         ALIGN
630 error_code:
631         /* the function address is in %gs's slot on the stack */
632         pushl %es
633         CFI_ADJUST_CFA_OFFSET 4
634         /*CFI_REL_OFFSET es, 0*/
635         pushl %ds
636         CFI_ADJUST_CFA_OFFSET 4
637         /*CFI_REL_OFFSET ds, 0*/
638         pushl %eax
639         CFI_ADJUST_CFA_OFFSET 4
640         CFI_REL_OFFSET eax, 0
641         pushl %ebp
642         CFI_ADJUST_CFA_OFFSET 4
643         CFI_REL_OFFSET ebp, 0
644         pushl %edi
645         CFI_ADJUST_CFA_OFFSET 4
646         CFI_REL_OFFSET edi, 0
647         pushl %esi
648         CFI_ADJUST_CFA_OFFSET 4
649         CFI_REL_OFFSET esi, 0
650         pushl %edx
651         CFI_ADJUST_CFA_OFFSET 4
652         CFI_REL_OFFSET edx, 0
653         pushl %ecx
654         CFI_ADJUST_CFA_OFFSET 4
655         CFI_REL_OFFSET ecx, 0
656         pushl %ebx
657         CFI_ADJUST_CFA_OFFSET 4
658         CFI_REL_OFFSET ebx, 0
659         cld
660         pushl %gs
661         CFI_ADJUST_CFA_OFFSET 4
662         /*CFI_REL_OFFSET gs, 0*/
663         movl $(__KERNEL_PDA), %ecx
664         movl %ecx, %gs
665         UNWIND_ESPFIX_STACK
666         popl %ecx
667         CFI_ADJUST_CFA_OFFSET -4
668         /*CFI_REGISTER es, ecx*/
669         movl PT_GS(%esp), %edi          # get the function address
670         movl PT_ORIG_EAX(%esp), %edx    # get the error code
671         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
672         mov  %ecx, PT_GS(%esp)
673         /*CFI_REL_OFFSET gs, ES*/
674         movl $(__USER_DS), %ecx
675         movl %ecx, %ds
676         movl %ecx, %es
677         movl %esp,%eax                  # pt_regs pointer
678         call *%edi
679         jmp ret_from_exception
680         CFI_ENDPROC
681 KPROBE_END(page_fault)
682
683 ENTRY(coprocessor_error)
684         RING0_INT_FRAME
685         pushl $0
686         CFI_ADJUST_CFA_OFFSET 4
687         pushl $do_coprocessor_error
688         CFI_ADJUST_CFA_OFFSET 4
689         jmp error_code
690         CFI_ENDPROC
691
692 ENTRY(simd_coprocessor_error)
693         RING0_INT_FRAME
694         pushl $0
695         CFI_ADJUST_CFA_OFFSET 4
696         pushl $do_simd_coprocessor_error
697         CFI_ADJUST_CFA_OFFSET 4
698         jmp error_code
699         CFI_ENDPROC
700
701 ENTRY(device_not_available)
702         RING0_INT_FRAME
703         pushl $-1                       # mark this as an int
704         CFI_ADJUST_CFA_OFFSET 4
705         SAVE_ALL
706         GET_CR0_INTO_EAX
707         testl $0x4, %eax                # EM (math emulation bit)
708         jne device_not_available_emulate
709         preempt_stop(CLBR_ANY)
710         call math_state_restore
711         jmp ret_from_exception
712 device_not_available_emulate:
713         pushl $0                        # temporary storage for ORIG_EIP
714         CFI_ADJUST_CFA_OFFSET 4
715         call math_emulate
716         addl $4, %esp
717         CFI_ADJUST_CFA_OFFSET -4
718         jmp ret_from_exception
719         CFI_ENDPROC
720
721 /*
722  * Debug traps and NMI can happen at the one SYSENTER instruction
723  * that sets up the real kernel stack. Check here, since we can't
724  * allow the wrong stack to be used.
725  *
726  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
727  * already pushed 3 words if it hits on the sysenter instruction:
728  * eflags, cs and eip.
729  *
730  * We just load the right stack, and push the three (known) values
731  * by hand onto the new stack - while updating the return eip past
732  * the instruction that would have done it for sysenter.
733  */
734 #define FIX_STACK(offset, ok, label)            \
735         cmpw $__KERNEL_CS,4(%esp);              \
736         jne ok;                                 \
737 label:                                          \
738         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
739         CFI_DEF_CFA esp, 0;                     \
740         CFI_UNDEFINED eip;                      \
741         pushfl;                                 \
742         CFI_ADJUST_CFA_OFFSET 4;                \
743         pushl $__KERNEL_CS;                     \
744         CFI_ADJUST_CFA_OFFSET 4;                \
745         pushl $sysenter_past_esp;               \
746         CFI_ADJUST_CFA_OFFSET 4;                \
747         CFI_REL_OFFSET eip, 0
748
749 KPROBE_ENTRY(debug)
750         RING0_INT_FRAME
751         cmpl $sysenter_entry,(%esp)
752         jne debug_stack_correct
753         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
754 debug_stack_correct:
755         pushl $-1                       # mark this as an int
756         CFI_ADJUST_CFA_OFFSET 4
757         SAVE_ALL
758         xorl %edx,%edx                  # error code 0
759         movl %esp,%eax                  # pt_regs pointer
760         call do_debug
761         jmp ret_from_exception
762         CFI_ENDPROC
763 KPROBE_END(debug)
764
765 /*
766  * NMI is doubly nasty. It can happen _while_ we're handling
767  * a debug fault, and the debug fault hasn't yet been able to
768  * clear up the stack. So we first check whether we got  an
769  * NMI on the sysenter entry path, but after that we need to
770  * check whether we got an NMI on the debug path where the debug
771  * fault happened on the sysenter path.
772  */
773 KPROBE_ENTRY(nmi)
774         RING0_INT_FRAME
775         pushl %eax
776         CFI_ADJUST_CFA_OFFSET 4
777         movl %ss, %eax
778         cmpw $__ESPFIX_SS, %ax
779         popl %eax
780         CFI_ADJUST_CFA_OFFSET -4
781         je nmi_espfix_stack
782         cmpl $sysenter_entry,(%esp)
783         je nmi_stack_fixup
784         pushl %eax
785         CFI_ADJUST_CFA_OFFSET 4
786         movl %esp,%eax
787         /* Do not access memory above the end of our stack page,
788          * it might not exist.
789          */
790         andl $(THREAD_SIZE-1),%eax
791         cmpl $(THREAD_SIZE-20),%eax
792         popl %eax
793         CFI_ADJUST_CFA_OFFSET -4
794         jae nmi_stack_correct
795         cmpl $sysenter_entry,12(%esp)
796         je nmi_debug_stack_check
797 nmi_stack_correct:
798         /* We have a RING0_INT_FRAME here */
799         pushl %eax
800         CFI_ADJUST_CFA_OFFSET 4
801         SAVE_ALL
802         xorl %edx,%edx          # zero error code
803         movl %esp,%eax          # pt_regs pointer
804         call do_nmi
805         jmp restore_nocheck_notrace
806         CFI_ENDPROC
807
808 nmi_stack_fixup:
809         RING0_INT_FRAME
810         FIX_STACK(12,nmi_stack_correct, 1)
811         jmp nmi_stack_correct
812
813 nmi_debug_stack_check:
814         /* We have a RING0_INT_FRAME here */
815         cmpw $__KERNEL_CS,16(%esp)
816         jne nmi_stack_correct
817         cmpl $debug,(%esp)
818         jb nmi_stack_correct
819         cmpl $debug_esp_fix_insn,(%esp)
820         ja nmi_stack_correct
821         FIX_STACK(24,nmi_stack_correct, 1)
822         jmp nmi_stack_correct
823
824 nmi_espfix_stack:
825         /* We have a RING0_INT_FRAME here.
826          *
827          * create the pointer to lss back
828          */
829         pushl %ss
830         CFI_ADJUST_CFA_OFFSET 4
831         pushl %esp
832         CFI_ADJUST_CFA_OFFSET 4
833         addw $4, (%esp)
834         /* copy the iret frame of 12 bytes */
835         .rept 3
836         pushl 16(%esp)
837         CFI_ADJUST_CFA_OFFSET 4
838         .endr
839         pushl %eax
840         CFI_ADJUST_CFA_OFFSET 4
841         SAVE_ALL
842         FIXUP_ESPFIX_STACK              # %eax == %esp
843         xorl %edx,%edx                  # zero error code
844         call do_nmi
845         RESTORE_REGS
846         lss 12+4(%esp), %esp            # back to espfix stack
847         CFI_ADJUST_CFA_OFFSET -24
848 1:      INTERRUPT_RETURN
849         CFI_ENDPROC
850 .section __ex_table,"a"
851         .align 4
852         .long 1b,iret_exc
853 .previous
854 KPROBE_END(nmi)
855
856 #ifdef CONFIG_PARAVIRT
857 ENTRY(native_iret)
858 1:      iret
859 .section __ex_table,"a"
860         .align 4
861         .long 1b,iret_exc
862 .previous
863
864 ENTRY(native_irq_enable_sysexit)
865         sti
866         sysexit
867 #endif
868
869 KPROBE_ENTRY(int3)
870         RING0_INT_FRAME
871         pushl $-1                       # mark this as an int
872         CFI_ADJUST_CFA_OFFSET 4
873         SAVE_ALL
874         xorl %edx,%edx          # zero error code
875         movl %esp,%eax          # pt_regs pointer
876         call do_int3
877         jmp ret_from_exception
878         CFI_ENDPROC
879 KPROBE_END(int3)
880
881 ENTRY(overflow)
882         RING0_INT_FRAME
883         pushl $0
884         CFI_ADJUST_CFA_OFFSET 4
885         pushl $do_overflow
886         CFI_ADJUST_CFA_OFFSET 4
887         jmp error_code
888         CFI_ENDPROC
889
890 ENTRY(bounds)
891         RING0_INT_FRAME
892         pushl $0
893         CFI_ADJUST_CFA_OFFSET 4
894         pushl $do_bounds
895         CFI_ADJUST_CFA_OFFSET 4
896         jmp error_code
897         CFI_ENDPROC
898
899 ENTRY(invalid_op)
900         RING0_INT_FRAME
901         pushl $0
902         CFI_ADJUST_CFA_OFFSET 4
903         pushl $do_invalid_op
904         CFI_ADJUST_CFA_OFFSET 4
905         jmp error_code
906         CFI_ENDPROC
907
908 ENTRY(coprocessor_segment_overrun)
909         RING0_INT_FRAME
910         pushl $0
911         CFI_ADJUST_CFA_OFFSET 4
912         pushl $do_coprocessor_segment_overrun
913         CFI_ADJUST_CFA_OFFSET 4
914         jmp error_code
915         CFI_ENDPROC
916
917 ENTRY(invalid_TSS)
918         RING0_EC_FRAME
919         pushl $do_invalid_TSS
920         CFI_ADJUST_CFA_OFFSET 4
921         jmp error_code
922         CFI_ENDPROC
923
924 ENTRY(segment_not_present)
925         RING0_EC_FRAME
926         pushl $do_segment_not_present
927         CFI_ADJUST_CFA_OFFSET 4
928         jmp error_code
929         CFI_ENDPROC
930
931 ENTRY(stack_segment)
932         RING0_EC_FRAME
933         pushl $do_stack_segment
934         CFI_ADJUST_CFA_OFFSET 4
935         jmp error_code
936         CFI_ENDPROC
937
938 KPROBE_ENTRY(general_protection)
939         RING0_EC_FRAME
940         pushl $do_general_protection
941         CFI_ADJUST_CFA_OFFSET 4
942         jmp error_code
943         CFI_ENDPROC
944 KPROBE_END(general_protection)
945
946 ENTRY(alignment_check)
947         RING0_EC_FRAME
948         pushl $do_alignment_check
949         CFI_ADJUST_CFA_OFFSET 4
950         jmp error_code
951         CFI_ENDPROC
952
953 ENTRY(divide_error)
954         RING0_INT_FRAME
955         pushl $0                        # no error code
956         CFI_ADJUST_CFA_OFFSET 4
957         pushl $do_divide_error
958         CFI_ADJUST_CFA_OFFSET 4
959         jmp error_code
960         CFI_ENDPROC
961
962 #ifdef CONFIG_X86_MCE
963 ENTRY(machine_check)
964         RING0_INT_FRAME
965         pushl $0
966         CFI_ADJUST_CFA_OFFSET 4
967         pushl machine_check_vector
968         CFI_ADJUST_CFA_OFFSET 4
969         jmp error_code
970         CFI_ENDPROC
971 #endif
972
973 ENTRY(spurious_interrupt_bug)
974         RING0_INT_FRAME
975         pushl $0
976         CFI_ADJUST_CFA_OFFSET 4
977         pushl $do_spurious_interrupt_bug
978         CFI_ADJUST_CFA_OFFSET 4
979         jmp error_code
980         CFI_ENDPROC
981
982 #ifdef CONFIG_STACK_UNWIND
983 ENTRY(arch_unwind_init_running)
984         CFI_STARTPROC
985         movl    4(%esp), %edx
986         movl    (%esp), %ecx
987         leal    4(%esp), %eax
988         movl    %ebx, PT_EBX(%edx)
989         xorl    %ebx, %ebx
990         movl    %ebx, PT_ECX(%edx)
991         movl    %ebx, PT_EDX(%edx)
992         movl    %esi, PT_ESI(%edx)
993         movl    %edi, PT_EDI(%edx)
994         movl    %ebp, PT_EBP(%edx)
995         movl    %ebx, PT_EAX(%edx)
996         movl    $__USER_DS, PT_DS(%edx)
997         movl    $__USER_DS, PT_ES(%edx)
998         movl    $0, PT_GS(%edx)
999         movl    %ebx, PT_ORIG_EAX(%edx)
1000         movl    %ecx, PT_EIP(%edx)
1001         movl    12(%esp), %ecx
1002         movl    $__KERNEL_CS, PT_CS(%edx)
1003         movl    %ebx, PT_EFLAGS(%edx)
1004         movl    %eax, PT_OLDESP(%edx)
1005         movl    8(%esp), %eax
1006         movl    %ecx, 8(%esp)
1007         movl    PT_EBX(%edx), %ebx
1008         movl    $__KERNEL_DS, PT_OLDSS(%edx)
1009         jmpl    *%eax
1010         CFI_ENDPROC
1011 ENDPROC(arch_unwind_init_running)
1012 #endif
1013
1014 ENTRY(kernel_thread_helper)
1015         pushl $0                # fake return address for unwinder
1016         CFI_STARTPROC
1017         movl %edx,%eax
1018         push %edx
1019         CFI_ADJUST_CFA_OFFSET 4
1020         call *%ebx
1021         push %eax
1022         CFI_ADJUST_CFA_OFFSET 4
1023         call do_exit
1024         CFI_ENDPROC
1025 ENDPROC(kernel_thread_helper)
1026
1027 .section .rodata,"a"
1028 #include "syscall_table.S"
1029
1030 syscall_table_size=(.-sys_call_table)