607c0600750894e21f2beeb423101ab2e56f5952
[linux-2.6.git] / arch / i386 / kernel / entry.S
1 /*
2  *  linux/arch/i386/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  */
6
7 /*
8  * entry.S contains the system-call and fault low-level handling routines.
9  * This also contains the timer-interrupt handler, as well as all interrupts
10  * and faults that can result in a task-switch.
11  *
12  * NOTE: This code handles signal-recognition, which happens every time
13  * after a timer-interrupt and after each system call.
14  *
15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
16  * on a 486.
17  *
18  * Stack layout in 'ret_from_system_call':
19  *      ptrace needs to have all regs on the stack.
20  *      if the order here is changed, it needs to be
21  *      updated in fork.c:copy_process, signal.c:do_signal,
22  *      ptrace.c and ptrace.h
23  *
24  *       0(%esp) - %ebx
25  *       4(%esp) - %ecx
26  *       8(%esp) - %edx
27  *       C(%esp) - %esi
28  *      10(%esp) - %edi
29  *      14(%esp) - %ebp
30  *      18(%esp) - %eax
31  *      1C(%esp) - %ds
32  *      20(%esp) - %es
33  *      24(%esp) - orig_eax
34  *      28(%esp) - %eip
35  *      2C(%esp) - %cs
36  *      30(%esp) - %eflags
37  *      34(%esp) - %oldesp
38  *      38(%esp) - %oldss
39  *
40  * "current" is in register %ebx during any slow entries.
41  */
42
43 #include <linux/config.h>
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/errno.h>
47 #include <asm/segment.h>
48 #include <asm/smp.h>
49 #include <asm/page.h>
50 #include <asm/desc.h>
51 #include "irq_vectors.h"
52
53 #define nr_syscalls ((syscall_table_size)/4)
54
55 EBX             = 0x00
56 ECX             = 0x04
57 EDX             = 0x08
58 ESI             = 0x0C
59 EDI             = 0x10
60 EBP             = 0x14
61 EAX             = 0x18
62 DS              = 0x1C
63 ES              = 0x20
64 ORIG_EAX        = 0x24
65 EIP             = 0x28
66 CS              = 0x2C
67 EFLAGS          = 0x30
68 OLDESP          = 0x34
69 OLDSS           = 0x38
70
71 CF_MASK         = 0x00000001
72 TF_MASK         = 0x00000100
73 IF_MASK         = 0x00000200
74 DF_MASK         = 0x00000400 
75 NT_MASK         = 0x00004000
76 VM_MASK         = 0x00020000
77
78 #ifdef CONFIG_PREEMPT
79 #define preempt_stop            cli
80 #else
81 #define preempt_stop
82 #define resume_kernel           restore_nocheck
83 #endif
84
85 #define SAVE_ALL \
86         cld; \
87         pushl %es; \
88         pushl %ds; \
89         pushl %eax; \
90         pushl %ebp; \
91         pushl %edi; \
92         pushl %esi; \
93         pushl %edx; \
94         pushl %ecx; \
95         pushl %ebx; \
96         movl $(__USER_DS), %edx; \
97         movl %edx, %ds; \
98         movl %edx, %es;
99
100 #define RESTORE_INT_REGS \
101         popl %ebx;      \
102         popl %ecx;      \
103         popl %edx;      \
104         popl %esi;      \
105         popl %edi;      \
106         popl %ebp;      \
107         popl %eax
108
109 #define RESTORE_REGS    \
110         RESTORE_INT_REGS; \
111 1:      popl %ds;       \
112 2:      popl %es;       \
113 .section .fixup,"ax";   \
114 3:      movl $0,(%esp); \
115         jmp 1b;         \
116 4:      movl $0,(%esp); \
117         jmp 2b;         \
118 .previous;              \
119 .section __ex_table,"a";\
120         .align 4;       \
121         .long 1b,3b;    \
122         .long 2b,4b;    \
123 .previous
124
125
126 ENTRY(ret_from_fork)
127         pushl %eax
128         call schedule_tail
129         GET_THREAD_INFO(%ebp)
130         popl %eax
131         jmp syscall_exit
132
133 /*
134  * Return to user mode is not as complex as all this looks,
135  * but we want the default path for a system call return to
136  * go as quickly as possible which is why some of this is
137  * less clear than it otherwise should be.
138  */
139
140         # userspace resumption stub bypassing syscall exit tracing
141         ALIGN
142 ret_from_exception:
143         preempt_stop
144 ret_from_intr:
145         GET_THREAD_INFO(%ebp)
146         movl EFLAGS(%esp), %eax         # mix EFLAGS and CS
147         movb CS(%esp), %al
148         testl $(VM_MASK | 3), %eax
149         jz resume_kernel
150 ENTRY(resume_userspace)
151         cli                             # make sure we don't miss an interrupt
152                                         # setting need_resched or sigpending
153                                         # between sampling and the iret
154         movl TI_flags(%ebp), %ecx
155         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
156                                         # int/exception return?
157         jne work_pending
158         jmp restore_all
159
160 #ifdef CONFIG_PREEMPT
161 ENTRY(resume_kernel)
162         cli
163         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
164         jnz restore_nocheck
165 need_resched:
166         movl TI_flags(%ebp), %ecx       # need_resched set ?
167         testb $_TIF_NEED_RESCHED, %cl
168         jz restore_all
169         testl $IF_MASK,EFLAGS(%esp)     # interrupts off (exception path) ?
170         jz restore_all
171         call preempt_schedule_irq
172         jmp need_resched
173 #endif
174
175 /* SYSENTER_RETURN points to after the "sysenter" instruction in
176    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
177
178         # sysenter call handler stub
179 ENTRY(sysenter_entry)
180         movl TSS_sysenter_esp0(%esp),%esp
181 sysenter_past_esp:
182         sti
183         pushl $(__USER_DS)
184         pushl %ebp
185         pushfl
186         pushl $(__USER_CS)
187         pushl $SYSENTER_RETURN
188
189 /*
190  * Load the potential sixth argument from user stack.
191  * Careful about security.
192  */
193         cmpl $__PAGE_OFFSET-3,%ebp
194         jae syscall_fault
195 1:      movl (%ebp),%ebp
196 .section __ex_table,"a"
197         .align 4
198         .long 1b,syscall_fault
199 .previous
200
201         pushl %eax
202         SAVE_ALL
203         GET_THREAD_INFO(%ebp)
204
205         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
206         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
207         jnz syscall_trace_entry
208         cmpl $(nr_syscalls), %eax
209         jae syscall_badsys
210         call *sys_call_table(,%eax,4)
211         movl %eax,EAX(%esp)
212         cli
213         movl TI_flags(%ebp), %ecx
214         testw $_TIF_ALLWORK_MASK, %cx
215         jne syscall_exit_work
216 /* if something modifies registers it must also disable sysexit */
217         movl EIP(%esp), %edx
218         movl OLDESP(%esp), %ecx
219         xorl %ebp,%ebp
220         sti
221         sysexit
222
223
224         # system call handler stub
225 ENTRY(system_call)
226         pushl %eax                      # save orig_eax
227         SAVE_ALL
228         GET_THREAD_INFO(%ebp)
229                                         # system call tracing in operation / emulation
230         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
231         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
232         jnz syscall_trace_entry
233         cmpl $(nr_syscalls), %eax
234         jae syscall_badsys
235 syscall_call:
236         call *sys_call_table(,%eax,4)
237         movl %eax,EAX(%esp)             # store the return value
238 syscall_exit:
239         cli                             # make sure we don't miss an interrupt
240                                         # setting need_resched or sigpending
241                                         # between sampling and the iret
242         movl TI_flags(%ebp), %ecx
243         testw $_TIF_ALLWORK_MASK, %cx   # current->work
244         jne syscall_exit_work
245
246 restore_all:
247         movl EFLAGS(%esp), %eax         # mix EFLAGS, SS and CS
248         # Warning: OLDSS(%esp) contains the wrong/random values if we
249         # are returning to the kernel.
250         # See comments in process.c:copy_thread() for details.
251         movb OLDSS(%esp), %ah
252         movb CS(%esp), %al
253         andl $(VM_MASK | (4 << 8) | 3), %eax
254         cmpl $((4 << 8) | 3), %eax
255         je ldt_ss                       # returning to user-space with LDT SS
256 restore_nocheck:
257         RESTORE_REGS
258         addl $4, %esp
259 1:      iret
260 .section .fixup,"ax"
261 iret_exc:
262         sti
263         pushl $0                        # no error code
264         pushl $do_iret_error
265         jmp error_code
266 .previous
267 .section __ex_table,"a"
268         .align 4
269         .long 1b,iret_exc
270 .previous
271
272 ldt_ss:
273         larl OLDSS(%esp), %eax
274         jnz restore_nocheck
275         testl $0x00400000, %eax         # returning to 32bit stack?
276         jnz restore_nocheck             # allright, normal return
277         /* If returning to userspace with 16bit stack,
278          * try to fix the higher word of ESP, as the CPU
279          * won't restore it.
280          * This is an "official" bug of all the x86-compatible
281          * CPUs, which we can try to work around to make
282          * dosemu and wine happy. */
283         subl $8, %esp           # reserve space for switch16 pointer
284         cli
285         movl %esp, %eax
286         /* Set up the 16bit stack frame with switch32 pointer on top,
287          * and a switch16 pointer on top of the current frame. */
288         call setup_x86_bogus_stack
289         RESTORE_REGS
290         lss 20+4(%esp), %esp    # switch to 16bit stack
291 1:      iret
292 .section __ex_table,"a"
293         .align 4
294         .long 1b,iret_exc
295 .previous
296
297         # perform work that needs to be done immediately before resumption
298         ALIGN
299 work_pending:
300         testb $_TIF_NEED_RESCHED, %cl
301         jz work_notifysig
302 work_resched:
303         call schedule
304         cli                             # make sure we don't miss an interrupt
305                                         # setting need_resched or sigpending
306                                         # between sampling and the iret
307         movl TI_flags(%ebp), %ecx
308         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
309                                         # than syscall tracing?
310         jz restore_all
311         testb $_TIF_NEED_RESCHED, %cl
312         jnz work_resched
313
314 work_notifysig:                         # deal with pending signals and
315                                         # notify-resume requests
316         testl $VM_MASK, EFLAGS(%esp)
317         movl %esp, %eax
318         jne work_notifysig_v86          # returning to kernel-space or
319                                         # vm86-space
320         xorl %edx, %edx
321         call do_notify_resume
322         jmp resume_userspace
323
324         ALIGN
325 work_notifysig_v86:
326         pushl %ecx                      # save ti_flags for do_notify_resume
327         call save_v86_state             # %eax contains pt_regs pointer
328         popl %ecx
329         movl %eax, %esp
330         xorl %edx, %edx
331         call do_notify_resume
332         jmp resume_userspace
333
334         # perform syscall exit tracing
335         ALIGN
336 syscall_trace_entry:
337         movl $-ENOSYS,EAX(%esp)
338         movl %esp, %eax
339         xorl %edx,%edx
340         call do_syscall_trace
341         cmpl $0, %eax
342         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
343                                         # so must skip actual syscall
344         movl ORIG_EAX(%esp), %eax
345         cmpl $(nr_syscalls), %eax
346         jnae syscall_call
347         jmp syscall_exit
348
349         # perform syscall exit tracing
350         ALIGN
351 syscall_exit_work:
352         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
353         jz work_pending
354         sti                             # could let do_syscall_trace() call
355                                         # schedule() instead
356         movl %esp, %eax
357         movl $1, %edx
358         call do_syscall_trace
359         jmp resume_userspace
360
361         ALIGN
362 syscall_fault:
363         pushl %eax                      # save orig_eax
364         SAVE_ALL
365         GET_THREAD_INFO(%ebp)
366         movl $-EFAULT,EAX(%esp)
367         jmp resume_userspace
368
369         ALIGN
370 syscall_badsys:
371         movl $-ENOSYS,EAX(%esp)
372         jmp resume_userspace
373
374 #define FIXUP_ESPFIX_STACK \
375         movl %esp, %eax; \
376         /* switch to 32bit stack using the pointer on top of 16bit stack */ \
377         lss %ss:CPU_16BIT_STACK_SIZE-8, %esp; \
378         /* copy data from 16bit stack to 32bit stack */ \
379         call fixup_x86_bogus_stack; \
380         /* put ESP to the proper location */ \
381         movl %eax, %esp;
382 #define UNWIND_ESPFIX_STACK \
383         pushl %eax; \
384         movl %ss, %eax; \
385         /* see if on 16bit stack */ \
386         cmpw $__ESPFIX_SS, %ax; \
387         jne 28f; \
388         movl $__KERNEL_DS, %edx; \
389         movl %edx, %ds; \
390         movl %edx, %es; \
391         /* switch to 32bit stack */ \
392         FIXUP_ESPFIX_STACK \
393 28:     popl %eax;
394
395 /*
396  * Build the entry stubs and pointer table with
397  * some assembler magic.
398  */
399 .data
400 ENTRY(interrupt)
401 .text
402
403 vector=0
404 ENTRY(irq_entries_start)
405 .rept NR_IRQS
406         ALIGN
407 1:      pushl $vector-256
408         jmp common_interrupt
409 .data
410         .long 1b
411 .text
412 vector=vector+1
413 .endr
414
415         ALIGN
416 common_interrupt:
417         SAVE_ALL
418         movl %esp,%eax
419         call do_IRQ
420         jmp ret_from_intr
421
422 #define BUILD_INTERRUPT(name, nr)       \
423 ENTRY(name)                             \
424         pushl $nr-256;                  \
425         SAVE_ALL                        \
426         movl %esp,%eax;                 \
427         call smp_/**/name;              \
428         jmp ret_from_intr;
429
430 /* The include is where all of the SMP etc. interrupts come from */
431 #include "entry_arch.h"
432
433 ENTRY(divide_error)
434         pushl $0                        # no error code
435         pushl $do_divide_error
436         ALIGN
437 error_code:
438         pushl %ds
439         pushl %eax
440         xorl %eax, %eax
441         pushl %ebp
442         pushl %edi
443         pushl %esi
444         pushl %edx
445         decl %eax                       # eax = -1
446         pushl %ecx
447         pushl %ebx
448         cld
449         pushl %es
450         UNWIND_ESPFIX_STACK
451         popl %ecx
452         movl ES(%esp), %edi             # get the function address
453         movl ORIG_EAX(%esp), %edx       # get the error code
454         movl %eax, ORIG_EAX(%esp)
455         movl %ecx, ES(%esp)
456         movl $(__USER_DS), %ecx
457         movl %ecx, %ds
458         movl %ecx, %es
459         movl %esp,%eax                  # pt_regs pointer
460         call *%edi
461         jmp ret_from_exception
462
463 ENTRY(coprocessor_error)
464         pushl $0
465         pushl $do_coprocessor_error
466         jmp error_code
467
468 ENTRY(simd_coprocessor_error)
469         pushl $0
470         pushl $do_simd_coprocessor_error
471         jmp error_code
472
473 ENTRY(device_not_available)
474         pushl $-1                       # mark this as an int
475         SAVE_ALL
476         movl %cr0, %eax
477         testl $0x4, %eax                # EM (math emulation bit)
478         jne device_not_available_emulate
479         preempt_stop
480         call math_state_restore
481         jmp ret_from_exception
482 device_not_available_emulate:
483         pushl $0                        # temporary storage for ORIG_EIP
484         call math_emulate
485         addl $4, %esp
486         jmp ret_from_exception
487
488 /*
489  * Debug traps and NMI can happen at the one SYSENTER instruction
490  * that sets up the real kernel stack. Check here, since we can't
491  * allow the wrong stack to be used.
492  *
493  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
494  * already pushed 3 words if it hits on the sysenter instruction:
495  * eflags, cs and eip.
496  *
497  * We just load the right stack, and push the three (known) values
498  * by hand onto the new stack - while updating the return eip past
499  * the instruction that would have done it for sysenter.
500  */
501 #define FIX_STACK(offset, ok, label)            \
502         cmpw $__KERNEL_CS,4(%esp);              \
503         jne ok;                                 \
504 label:                                          \
505         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
506         pushfl;                                 \
507         pushl $__KERNEL_CS;                     \
508         pushl $sysenter_past_esp
509
510 KPROBE_ENTRY(debug)
511         cmpl $sysenter_entry,(%esp)
512         jne debug_stack_correct
513         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
514 debug_stack_correct:
515         pushl $-1                       # mark this as an int
516         SAVE_ALL
517         xorl %edx,%edx                  # error code 0
518         movl %esp,%eax                  # pt_regs pointer
519         call do_debug
520         jmp ret_from_exception
521         .previous .text
522 /*
523  * NMI is doubly nasty. It can happen _while_ we're handling
524  * a debug fault, and the debug fault hasn't yet been able to
525  * clear up the stack. So we first check whether we got  an
526  * NMI on the sysenter entry path, but after that we need to
527  * check whether we got an NMI on the debug path where the debug
528  * fault happened on the sysenter path.
529  */
530 ENTRY(nmi)
531         pushl %eax
532         movl %ss, %eax
533         cmpw $__ESPFIX_SS, %ax
534         popl %eax
535         je nmi_16bit_stack
536         cmpl $sysenter_entry,(%esp)
537         je nmi_stack_fixup
538         pushl %eax
539         movl %esp,%eax
540         /* Do not access memory above the end of our stack page,
541          * it might not exist.
542          */
543         andl $(THREAD_SIZE-1),%eax
544         cmpl $(THREAD_SIZE-20),%eax
545         popl %eax
546         jae nmi_stack_correct
547         cmpl $sysenter_entry,12(%esp)
548         je nmi_debug_stack_check
549 nmi_stack_correct:
550         pushl %eax
551         SAVE_ALL
552         xorl %edx,%edx          # zero error code
553         movl %esp,%eax          # pt_regs pointer
554         call do_nmi
555         jmp restore_all
556
557 nmi_stack_fixup:
558         FIX_STACK(12,nmi_stack_correct, 1)
559         jmp nmi_stack_correct
560 nmi_debug_stack_check:
561         cmpw $__KERNEL_CS,16(%esp)
562         jne nmi_stack_correct
563         cmpl $debug,(%esp)
564         jb nmi_stack_correct
565         cmpl $debug_esp_fix_insn,(%esp)
566         ja nmi_stack_correct
567         FIX_STACK(24,nmi_stack_correct, 1)
568         jmp nmi_stack_correct
569
570 nmi_16bit_stack:
571         /* create the pointer to lss back */
572         pushl %ss
573         pushl %esp
574         movzwl %sp, %esp
575         addw $4, (%esp)
576         /* copy the iret frame of 12 bytes */
577         .rept 3
578         pushl 16(%esp)
579         .endr
580         pushl %eax
581         SAVE_ALL
582         FIXUP_ESPFIX_STACK              # %eax == %esp
583         xorl %edx,%edx                  # zero error code
584         call do_nmi
585         RESTORE_REGS
586         lss 12+4(%esp), %esp            # back to 16bit stack
587 1:      iret
588 .section __ex_table,"a"
589         .align 4
590         .long 1b,iret_exc
591 .previous
592
593 KPROBE_ENTRY(int3)
594         pushl $-1                       # mark this as an int
595         SAVE_ALL
596         xorl %edx,%edx          # zero error code
597         movl %esp,%eax          # pt_regs pointer
598         call do_int3
599         jmp ret_from_exception
600         .previous .text
601
602 ENTRY(overflow)
603         pushl $0
604         pushl $do_overflow
605         jmp error_code
606
607 ENTRY(bounds)
608         pushl $0
609         pushl $do_bounds
610         jmp error_code
611
612 ENTRY(invalid_op)
613         pushl $0
614         pushl $do_invalid_op
615         jmp error_code
616
617 ENTRY(coprocessor_segment_overrun)
618         pushl $0
619         pushl $do_coprocessor_segment_overrun
620         jmp error_code
621
622 ENTRY(invalid_TSS)
623         pushl $do_invalid_TSS
624         jmp error_code
625
626 ENTRY(segment_not_present)
627         pushl $do_segment_not_present
628         jmp error_code
629
630 ENTRY(stack_segment)
631         pushl $do_stack_segment
632         jmp error_code
633
634 KPROBE_ENTRY(general_protection)
635         pushl $do_general_protection
636         jmp error_code
637         .previous .text
638
639 ENTRY(alignment_check)
640         pushl $do_alignment_check
641         jmp error_code
642
643 KPROBE_ENTRY(page_fault)
644         pushl $do_page_fault
645         jmp error_code
646         .previous .text
647
648 #ifdef CONFIG_X86_MCE
649 ENTRY(machine_check)
650         pushl $0
651         pushl machine_check_vector
652         jmp error_code
653 #endif
654
655 ENTRY(spurious_interrupt_bug)
656         pushl $0
657         pushl $do_spurious_interrupt_bug
658         jmp error_code
659
660 .section .rodata,"a"
661 #include "syscall_table.S"
662
663 syscall_table_size=(.-sys_call_table)