Merge branch 'x86-fixes-for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git...
[linux-2.6.git] / arch / cris / kernel / vmlinux.lds.S
1 /* ld script to make the Linux/CRIS kernel
2  * Authors: Bjorn Wesen (bjornw@axis.com)
3  *
4  * It is VERY DANGEROUS to fiddle around with the symbols in this
5  * script. It is for example quite vital that all generated sections
6  * that are used are actually named here, otherwise the linker will
7  * put them at the end, where the init stuff is which is FREED after
8  * the kernel has booted.
9  */
10
11 #include <asm-generic/vmlinux.lds.h>
12 #include <asm/page.h>
13
14 #ifdef CONFIG_ETRAX_VMEM_SIZE
15 #define __CONFIG_ETRAX_VMEM_SIZE CONFIG_ETRAX_VMEM_SIZE
16 #else
17 #define __CONFIG_ETRAX_VMEM_SIZE 0
18 #endif
19
20
21 jiffies = jiffies_64;
22 SECTIONS
23 {
24         . = DRAM_VIRTUAL_BASE;
25         dram_start = .;
26 #ifdef CONFIG_ETRAX_ARCH_V10
27         ibr_start = .;
28 #else
29         ebp_start = .;
30         /* The boot section is only necessary until the VCS top */
31         /* level testbench includes both flash and DRAM. */
32         .boot : { *(.boot) }
33 #endif
34
35         /* see head.S and pages reserved at the start */
36         . = DRAM_VIRTUAL_BASE + 0x4000;
37
38         _text = .;                      /* Text and read-only data. */
39         text_start = .;                 /* Lots of aliases. */
40         _stext = .;
41         __stext = .;
42         .text : {
43                 TEXT_TEXT
44                 SCHED_TEXT
45                 LOCK_TEXT
46                 *(.fixup)
47                 *(.text.__*)
48         }
49
50         _etext = . ;                    /* End of text section. */
51         __etext = .;
52
53         EXCEPTION_TABLE(4)
54
55         RODATA
56
57         . = ALIGN (4);
58         ___data_start = . ;
59         __Sdata = . ;
60         .data : {                       /* Data */
61                 DATA_DATA
62         }
63         __edata = . ;                   /* End of data section. */
64         _edata = . ;
65
66         INIT_TASK_DATA_SECTION(PAGE_SIZE)
67
68         . = ALIGN(PAGE_SIZE);           /* Init code and data. */
69         __init_begin = .;
70         INIT_TEXT_SECTION(PAGE_SIZE)
71         .init.data : { INIT_DATA }
72         .init.setup : { INIT_SETUP(16) }
73 #ifdef CONFIG_ETRAX_ARCH_V32
74         __start___param = .;
75         __param : { *(__param) }
76         __stop___param = .;
77 #endif
78         .initcall.init : {
79                 INIT_CALLS
80         }
81
82         .con_initcall.init : {
83                 CON_INITCALL
84         }
85         SECURITY_INIT
86
87 #ifdef CONFIG_ETRAX_ARCH_V10
88 #ifdef CONFIG_BLK_DEV_INITRD
89         .init.ramfs : {
90                 __initramfs_start = .;
91                 *(.init.ramfs)
92                 __initramfs_end = .;
93         }
94 #endif
95 #endif
96         __vmlinux_end = .;              /* Last address of the physical file. */
97 #ifdef CONFIG_ETRAX_ARCH_V32
98         PERCPU(PAGE_SIZE)
99
100         .init.ramfs : {
101                 INIT_RAM_FS
102         }
103 #endif
104
105         /*
106          * We fill to the next page, so we can discard all init
107          * pages without needing to consider what payload might be
108          * appended to the kernel image.
109          */
110         . = ALIGN(PAGE_SIZE);
111
112         __init_end = .;
113
114         __data_end = . ;                /* Move to _edata ? */
115         BSS_SECTION(0, 0, 0)
116
117         . =  ALIGN (0x20);
118         _end = .;
119         __end = .;
120
121         dram_end = dram_start + (CONFIG_ETRAX_DRAM_SIZE - __CONFIG_ETRAX_VMEM_SIZE)*1024*1024;
122
123         DISCARDS
124 }