2604b532897cf745378d227a95c1f8b78ce2cc2b
[linux-2.6.git] / arch / blackfin / mach-common / interrupt.S
1 /*
2  * File:         arch/blackfin/mach-common/interrupt.S
3  * Based on:
4  * Author:       D. Jeff Dionne <jeff@ryeham.ee.ryerson.ca>
5  *               Kenneth Albanowski <kjahds@kjahds.com>
6  *
7  * Created:      ?
8  * Description:  Interrupt Entries
9  *
10  * Modified:
11  *               Copyright 2004-2006 Analog Devices Inc.
12  *
13  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
14  *
15  * This program is free software; you can redistribute it and/or modify
16  * it under the terms of the GNU General Public License as published by
17  * the Free Software Foundation; either version 2 of the License, or
18  * (at your option) any later version.
19  *
20  * This program is distributed in the hope that it will be useful,
21  * but WITHOUT ANY WARRANTY; without even the implied warranty of
22  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
23  * GNU General Public License for more details.
24  *
25  * You should have received a copy of the GNU General Public License
26  * along with this program; if not, see the file COPYING, or write
27  * to the Free Software Foundation, Inc.,
28  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
29  */
30
31 #include <asm/blackfin.h>
32 #include <mach/irq.h>
33 #include <linux/linkage.h>
34 #include <asm/entry.h>
35 #include <asm/asm-offsets.h>
36 #include <asm/trace.h>
37 #include <asm/traps.h>
38 #include <asm/thread_info.h>
39
40 #include <asm/context.S>
41
42 .extern _ret_from_exception
43
44 #ifdef CONFIG_I_ENTRY_L1
45 .section .l1.text
46 #else
47 .text
48 #endif
49
50 .align 4        /* just in case */
51
52 /* Common interrupt entry code.  First we do CLI, then push
53  * RETI, to keep interrupts disabled, but to allow this state to be changed
54  * by local_bh_enable.
55  * R0 contains the interrupt number, while R1 may contain the value of IPEND,
56  * or garbage if IPEND won't be needed by the ISR.  */
57 __common_int_entry:
58         [--sp] = fp;
59         [--sp] = usp;
60
61         [--sp] = i0;
62         [--sp] = i1;
63         [--sp] = i2;
64         [--sp] = i3;
65
66         [--sp] = m0;
67         [--sp] = m1;
68         [--sp] = m2;
69         [--sp] = m3;
70
71         [--sp] = l0;
72         [--sp] = l1;
73         [--sp] = l2;
74         [--sp] = l3;
75
76         [--sp] = b0;
77         [--sp] = b1;
78         [--sp] = b2;
79         [--sp] = b3;
80         [--sp] = a0.x;
81         [--sp] = a0.w;
82         [--sp] = a1.x;
83         [--sp] = a1.w;
84
85         [--sp] = LC0;
86         [--sp] = LC1;
87         [--sp] = LT0;
88         [--sp] = LT1;
89         [--sp] = LB0;
90         [--sp] = LB1;
91
92         [--sp] = ASTAT;
93
94         [--sp] = r0;    /* Skip reserved */
95         [--sp] = RETS;
96         r2 = RETI;
97         [--sp] = r2;
98         [--sp] = RETX;
99         [--sp] = RETN;
100         [--sp] = RETE;
101         [--sp] = SEQSTAT;
102         [--sp] = r1;    /* IPEND - R1 may or may not be set up before jumping here. */
103
104         /* Switch to other method of keeping interrupts disabled.  */
105 #ifdef CONFIG_DEBUG_HWERR
106         r1 = 0x3f;
107         sti r1;
108 #else
109         cli r1;
110 #endif
111         [--sp] = RETI;  /* orig_pc */
112         /* Clear all L registers.  */
113         r1 = 0 (x);
114         l0 = r1;
115         l1 = r1;
116         l2 = r1;
117         l3 = r1;
118 #ifdef CONFIG_FRAME_POINTER
119         fp = 0;
120 #endif
121
122 #if ANOMALY_05000283 || ANOMALY_05000315
123         cc = r7 == r7;
124         p5.h = HI(CHIPID);
125         p5.l = LO(CHIPID);
126         if cc jump 1f;
127         r7.l = W[p5];
128 1:
129 #endif
130         r1 =  sp;
131         SP += -12;
132         call _do_irq;
133         SP += 12;
134         call _return_from_int;
135 .Lcommon_restore_context:
136         RESTORE_CONTEXT
137         rti;
138
139 /* interrupt routine for ivhw - 5 */
140 ENTRY(_evt_ivhw)
141         SAVE_ALL_SYS
142 #ifdef CONFIG_FRAME_POINTER
143         fp = 0;
144 #endif
145
146 #if ANOMALY_05000283 || ANOMALY_05000315
147         cc = r7 == r7;
148         p5.h = HI(CHIPID);
149         p5.l = LO(CHIPID);
150         if cc jump 1f;
151         r7.l = W[p5];
152 1:
153 #endif
154
155         # We are going to dump something out, so make sure we print IPEND properly
156         p2.l = lo(IPEND);
157         p2.h = hi(IPEND);
158         r0 = [p2];
159         [sp + PT_IPEND] = r0;
160
161 #ifdef CONFIG_HARDWARE_PM
162         r7 = [sp + PT_SEQSTAT];
163         r7 = r7 >>> 0xe;
164         r6 = 0x1F;
165         r7 = r7 & r6;
166         r5 = 0x12;
167         cc = r7 == r5;
168         if cc jump .Lcall_do_ovf; /* deal with performance counter overflow */
169 #endif
170
171         /* set the EXCAUSE to HWERR for trap_c */
172         r0 = [sp + PT_SEQSTAT];
173         R1.L = LO(VEC_HWERR);
174         R1.H = HI(VEC_HWERR);
175         R0 = R0 | R1;
176         [sp + PT_SEQSTAT] = R0;
177
178         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
179         SP += -12;
180         call _trap_c;
181         SP += 12;
182
183 #ifdef EBIU_ERRMST
184         /* make sure EBIU_ERRMST is clear */
185         p0.l = LO(EBIU_ERRMST);
186         p0.h = HI(EBIU_ERRMST);
187         r0.l = (CORE_ERROR | CORE_MERROR);
188         w[p0] = r0.l;
189 #endif
190
191         call _ret_from_exception;
192
193 .Lcommon_restore_all_sys:
194         RESTORE_ALL_SYS
195         rti;
196
197 #ifdef CONFIG_HARDWARE_PM
198 .Lcall_do_ovf:
199
200         R0 = SP;
201         SP += -12;
202         call _pm_overflow;
203         SP += 12;
204
205         jump .Lcommon_restore_all_sys;
206 #endif
207
208 ENDPROC(_evt_ivhw)
209
210 /* Interrupt routine for evt2 (NMI).
211  * We don't actually use this, so just return.
212  * For inner circle type details, please see:
213  * http://docs.blackfin.uclinux.org/doku.php?id=linux:nmi
214  */
215 ENTRY(_evt_nmi)
216 .weak _evt_nmi
217         rtn;
218 ENDPROC(_evt_nmi)
219
220 /* interrupt routine for core timer - 6 */
221 ENTRY(_evt_timer)
222         TIMER_INTERRUPT_ENTRY(EVT_IVTMR_P)
223
224 /* interrupt routine for evt7 - 7 */
225 ENTRY(_evt_evt7)
226         INTERRUPT_ENTRY(EVT_IVG7_P)
227 ENTRY(_evt_evt8)
228         INTERRUPT_ENTRY(EVT_IVG8_P)
229 ENTRY(_evt_evt9)
230         INTERRUPT_ENTRY(EVT_IVG9_P)
231 ENTRY(_evt_evt10)
232         INTERRUPT_ENTRY(EVT_IVG10_P)
233 ENTRY(_evt_evt11)
234         INTERRUPT_ENTRY(EVT_IVG11_P)
235 ENTRY(_evt_evt12)
236         INTERRUPT_ENTRY(EVT_IVG12_P)
237 ENTRY(_evt_evt13)
238         INTERRUPT_ENTRY(EVT_IVG13_P)
239
240
241  /* interrupt routine for system_call - 15 */
242 ENTRY(_evt_system_call)
243         SAVE_CONTEXT_SYSCALL
244 #ifdef CONFIG_FRAME_POINTER
245         fp = 0;
246 #endif
247         call _system_call;
248         jump .Lcommon_restore_context;
249 ENDPROC(_evt_system_call)