Linux-2.6.12-rc2
[linux-2.6.git] / arch / arm26 / kernel / vmlinux-arm26.lds.in
1 /* ld script to make ARM Linux kernel
2  * taken from the i386 version by Russell King
3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4  * borrowed from Russels ARM port by Ian Molton and subsequently modified.
5  */
6
7 #include <asm-generic/vmlinux.lds.h>
8
9 OUTPUT_ARCH(arm)
10 ENTRY(stext)
11 jiffies = jiffies_64;
12 SECTIONS
13 {
14         . = TEXTADDR;
15         .init : {                       /* Init code and data           */
16                 _stext = .;
17                 __init_begin = .;
18                         _sinittext = .;
19                         *(.init.text)
20                         _einittext = .;
21                 __proc_info_begin = .;
22                         *(.proc.info)
23                 __proc_info_end = .;
24                 __arch_info_begin = .;
25                         *(.arch.info)
26                 __arch_info_end = .;
27                 __tagtable_begin = .;
28                         *(.taglist)
29                 __tagtable_end = .;
30                         *(.init.data)
31                 . = ALIGN(16);
32                 __setup_start = .;
33                         *(.init.setup)
34                 __setup_end = .;
35                 __early_begin = .;
36                         *(__early_param)
37                 __early_end = .;
38                 __initcall_start = .;
39                         *(.initcall1.init)
40                         *(.initcall2.init)
41                         *(.initcall3.init)
42                         *(.initcall4.init)
43                         *(.initcall5.init)
44                         *(.initcall6.init)
45                         *(.initcall7.init)
46                 __initcall_end = .;
47                 __con_initcall_start = .;
48                         *(.con_initcall.init)
49                 __con_initcall_end = .;
50                 . = ALIGN(32);
51                 __initramfs_start = .;
52                         usr/built-in.o(.init.ramfs)
53                 __initramfs_end = .;
54                 . = ALIGN(32768);
55                 __init_end = .;
56         }
57
58         /DISCARD/ : {                   /* Exit code and data           */
59                 *(.exit.text)
60                 *(.exit.data)
61                 *(.exitcall.exit)
62         }
63
64         .text : {                       /* Real text segment            */
65                 _text = .;              /* Text and read-only data      */
66                         *(.text)
67                         SCHED_TEXT
68                         LOCK_TEXT
69                         *(.fixup)
70                         *(.gnu.warning)
71                         *(.rodata)
72                         *(.rodata.*)
73                         *(.glue_7)
74                         *(.glue_7t)
75                 *(.got)                 /* Global offset table          */
76
77                 _etext = .;             /* End of text section          */
78         }
79
80         . = ALIGN(16);
81         __ex_table : {                  /* Exception table              */
82                 __start___ex_table = .;
83                         *(__ex_table)
84                 __stop___ex_table = .;
85         }
86
87         RODATA
88
89         . = ALIGN(8192);
90
91         .data : {
92                 /*
93                  * first, the init task union, aligned
94                  * to an 8192 byte boundary. (see arm26/kernel/init_task.c)
95                  */
96                 *(.init.task)
97
98                 /*
99                  * The cacheline aligned data
100                  */
101                 . = ALIGN(32);
102                 *(.data.cacheline_aligned)
103
104                 /*
105                  * and the usual data section
106                  */
107                 *(.data)
108                 CONSTRUCTORS
109
110                 _edata = .;
111         }
112
113         .bss : {
114                 __bss_start = .;        /* BSS                          */
115                 *(.bss)
116                 *(COMMON)
117                 _end = . ;
118         }
119                                         /* Stabs debugging sections.    */
120         .stab 0 : { *(.stab) }
121         .stabstr 0 : { *(.stabstr) }
122         .stab.excl 0 : { *(.stab.excl) }
123         .stab.exclstr 0 : { *(.stab.exclstr) }
124         .stab.index 0 : { *(.stab.index) }
125         .stab.indexstr 0 : { *(.stab.indexstr) }
126         .comment 0 : { *(.comment) }
127 }