f9dc84b5e3e3714db399393ececd0b6684ef2ff3
[linux-2.6.git] / arch / arm / mach-tegra / headsmp.S
1 /*
2  * arch/arm/mach-tegra/headsmp.S
3  *
4  * CPU initialization routines for Tegra SoCs
5  *
6  * Copyright (c) 2009-2012, NVIDIA Corporation.
7  * Copyright (c) 2011 Google, Inc.
8  * Author: Colin Cross <ccross@android.com>
9  *         Gary King <gking@nvidia.com>
10  *
11  * This program is free software; you can redistribute it and/or modify
12  * it under the terms of the GNU General Public License as published by
13  * the Free Software Foundation; either version 2 of the License.
14  *
15  * This program is distributed in the hope that it will be useful, but WITHOUT
16  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
17  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
18  * more details.
19  */
20
21 #include <linux/linkage.h>
22 #include <linux/init.h>
23
24 #include <asm/assembler.h>
25 #include <asm/cache.h>
26 #include <asm/page.h>
27
28 #include <mach/iomap.h>
29 #include <mach/io.h>
30
31 #include "asm_macros.h"
32 #include "flowctrl.h"
33 #include "sleep.h"
34 #include "reset.h"
35
36 #define APB_MISC_GP_HIDREV      0x804
37 #define PMC_SCRATCH41   0x140
38
39 #define DEBUG_CPU_RESET_HANDLER 0       /* Non-zero enables debug code */
40
41 #define RESET_DATA(x)   ((TEGRA_RESET_##x)*4)
42
43 #ifdef CONFIG_SMP
44 /*
45  *      tegra_secondary_startup
46  *
47  *       Initial secondary processor boot vector; jumps to kernel's
48  *       secondary_startup routine. Used for initial boot and hotplug
49  *       of secondary CPUs.
50  */
51         __CPUINIT
52 ENTRY(tegra_secondary_startup)
53         bl      __invalidate_cpu_state
54
55         /* enable user space perf counter access */
56         /* only accessible in secure state       */
57         mrc     p15, 0, r0, c9, c12, 0
58         lsr     r0, #11
59         and     r0, r0, #0x1f
60         mov     r1, #1
61         lsl     r1, r1, r0
62         sub     r1, r1, #1
63         movt    r1, #0x8000
64         mcr     p15, 0, r1, c9, c14, 2
65         mov     r0, #1
66         mcr     p15, 0, r0, c9, c14, 0
67
68         b       secondary_startup
69 ENDPROC(tegra_secondary_startup)
70 #endif
71
72         .section ".text.head", "ax"
73 #ifdef CONFIG_PM_SLEEP
74 /*
75  *      tegra_resume
76  *
77  *        CPU boot vector when restarting the a CPU following
78  *        an LP2 transition. Also branched to by LP0 and LP1 resume after
79  *        re-enabling sdram.
80  */
81 ENTRY(tegra_resume)
82 #ifdef CONFIG_TRUSTED_FOUNDATIONS
83         mov32   r1, TEGRA_TMRUS_BASE
84         ldr     r0, [r1]
85         adr     r1, tegra_resume_entry_time
86         str     r0, [r1]
87 #endif
88
89         bl      __invalidate_cpu_state
90
91         cpu_id  r0
92 #ifndef CONFIG_TEGRA_VIRTUAL_CPUID
93         cmp     r0, #0                          @ CPU0?
94         bne     cpu_resume                      @ no
95 #endif
96
97 #ifndef CONFIG_ARCH_TEGRA_2x_SOC
98         @ Clear the flow controller flags for this CPU.
99         cpu_to_csr_reg  r1, r0
100         mov32   r2, TEGRA_FLOW_CTRL_BASE
101         ldr     r1, [r2, r1]
102         orr     r1, r1, #(1 << 15) | (1 << 14)  @ write to clear event & intr
103         movw    r0, #0x3FFD     @ enable, enable_ext, cluster_switch, immed, & bitmaps
104         bic     r1, r1, r0
105         str     r1, [r2]
106 #endif
107
108 #if defined(CONFIG_HAVE_ARM_SCU)
109         /* enable SCU */
110         mov32   r0, TEGRA_ARM_PERIF_BASE
111         ldr     r1, [r0]
112         orr     r1, r1, #1
113         str     r1, [r0]
114 #endif
115
116 #ifdef CONFIG_TRUSTED_FOUNDATIONS
117         mov32   r1, TEGRA_TMRUS_BASE
118         ldr     r0, [r1]
119         adr     r1, tegra_resume_smc_entry_time
120         str     r0, [r1]
121
122         /* wake up (should have specified args?) */
123         bl      tegra_generic_smc
124
125         mov32   r1, TEGRA_TMRUS_BASE
126         ldr     r0, [r1]
127         adr     r1, tegra_resume_smc_exit_time
128         str     r0, [r1]
129 #endif
130
131         b       cpu_resume
132 ENDPROC(tegra_resume)
133
134 #ifdef CONFIG_TRUSTED_FOUNDATIONS
135         .globl tegra_resume_timestamps_start
136         .globl tegra_resume_smc_entry_time
137         .globl tegra_resume_smc_exit_time
138         .globl tegra_resume_entry_time
139         .globl tegra_resume_timestamps_end
140 tegra_resume_timestamps_start:
141 tegra_resume_smc_entry_time:
142         .long   0
143 tegra_resume_smc_exit_time:
144         .long   0
145 tegra_resume_entry_time:
146         .long   0
147 tegra_resume_timestamps_end:
148 ENTRY(__tegra_resume_timestamps_end)
149 #endif
150 #endif
151
152 /*
153  *      __invalidate_cpu_state
154  *
155  *        Invalidates volatile CPU state (SCU tags, caches, branch address
156  *        arrays, exclusive monitor, etc.) so that they can be safely enabled
157  *        instruction caching and branch predicition enabled
158  *
159  *        For tegra chips with CONFIG_HAVE_ARM_SCU undefined, it means there is
160  *        an integrated SCU in L2 memory system, this is true for Cortex-A15
161  *        MP processors. In this case, we only need to set the correct L2 cache
162  *        data RAM latency and enable i-cache/branch prediction
163  */
164 __invalidate_cpu_state:
165         clrex
166         mov     r0, #0
167         mcr     p15, 0, r0, c1, c0, 1   @ disable SMP, prefetch, broadcast
168         isb
169 #if defined(CONFIG_HAVE_ARM_SCU)
170         mcr     p15, 0, r0, c7, c5, 0   @ invalidate BTAC, i-cache
171         mcr     p15, 0, r0, c7, c5, 6   @ invalidate branch pred array
172         mcr     p15, 0, r0, c8, c5, 0   @ invalidate instruction TLB
173         mcr     p15, 0, r0, c8, c6, 0   @ invalidate data TLB
174         mcr     p15, 0, r0, c8, c7, 0   @ invalidate unified TLB
175         dsb
176         isb
177
178         cpu_id  r0
179         cmp     r0, #0
180         mov32   r1, (TEGRA_ARM_PERIF_BASE + 0xC)
181         movne   r0, r0, lsl #2
182         movne   r2, #0xf
183         movne   r2, r2, lsl r0
184         strne   r2, [r1]                @ invalidate SCU tags for CPU
185
186         dsb
187         mov     r0, #0x1800
188         mcr     p15, 0, r0, c1, c0, 0   @ enable branch prediction, i-cache
189         isb
190         /* fall through */
191 #else
192         /*      This is only needed for cluster 0 with integrated L2 cache */
193         mov32   r0, TEGRA_FLOW_CTRL_BASE+0x2c   @ CLUSTER_CONTROL
194         ldr     r0, [r0]
195         tst     r0, #1
196         bne     __enable_i_cache_branch_pred
197         mrc     p15, 0x1, r0, c9, c0, 2
198         and     r1, r0, #7
199         cmp     r1, #2
200         beq     __enable_i_cache_branch_pred
201         bic     r0, r0, #7
202         orr     r0, r0, #2
203         mcr     p15, 0x1, r0, c9, c0, 2
204 __enable_i_cache_branch_pred:
205         mov     r0, #0x1800
206         mcr     p15, 0, r0, c1, c0, 0   @ enable branch prediction, i-cache
207         mov     pc, lr
208         /* no fall through, just return to the caller */
209 #endif
210
211 /*
212  *      tegra_invalidate_cache
213  *
214  *        Invalidates the L1 data cache (no clean) during initial boot of a cpu
215  *
216  *        Corrupted registers: r0-r6
217  */
218 tegra_invalidate_cache:
219         mov     r0, #0
220         mcr     p15, 2, r0, c0, c0, 0
221         mrc     p15, 1, r0, c0, c0, 0
222
223         movw    r1, #0x7fff
224         and     r2, r1, r0, lsr #13
225
226         movw    r1, #0x3ff
227
228         and     r3, r1, r0, lsr #3      @ NumWays - 1
229         add     r2, r2, #1      @ NumSets
230
231         and     r0, r0, #0x7
232         add     r0, r0, #4      @ SetShift
233
234         clz     r1, r3          @ WayShift
235         add     r4, r3, #1      @ NumWays
236 1:      sub     r2, r2, #1      @ NumSets--
237         mov     r3, r4          @ Temp = NumWays
238 2:      subs    r3, r3, #1      @ Temp--
239         mov     r5, r3, lsl r1
240         mov     r6, r2, lsl r0
241         orr     r5, r5, r6      @ Reg = (Temp<<WayShift)|(NumSets<<SetShift)
242         mcr     p15, 0, r5, c7, c6, 2
243         bgt     2b
244         cmp     r2, #0
245         bgt     1b
246         dsb
247         isb
248         mov     pc, lr
249
250 /*
251  * __tegra_cpu_reset_handler_halt_failed:
252  *
253  * Alternate entry point for reset handler for cases where the
254  * WFI halt failed to take effect.
255  *
256  */
257         .align L1_CACHE_SHIFT
258 ENTRY(__tegra_cpu_reset_handler_start)
259
260 /*
261  * __tegra_cpu_reset_handler:
262  *
263  * Common handler for all CPU reset events.
264  *
265  * Register usage within the reset handler:
266  *
267  *      R7  = CPU present (to the OS) mask
268  *      R8  = CPU in LP1 state mask
269  *      R9  = CPU in LP2 state mask
270  *      R10 = CPU number
271  *      R11 = CPU mask
272  *      R12 = pointer to reset handler data
273  *
274  * NOTE: This code is copied to IRAM. All code and data accesses
275  *       must be position-independent.
276  */
277
278         .align L1_CACHE_SHIFT
279 ENTRY(__tegra_cpu_reset_handler)
280
281 /* DO NOT put any code before the !defined(CONFIG_ARM_SAVE_DEBUG_CONTEXT)
282    block below. It must be the first thing in this subroutine. */
283
284 #if !defined(CONFIG_ARM_SAVE_DEBUG_CONTEXT) || DEBUG_CPU_RESET_HANDLER
285         /* If Debug Architecture v7.1 or later, unlock the OS lock. */
286         mrc     p15, 0, r0, c0, c1, 2           @ ID_DFR0
287         and     r0, r0, #0xF                    @ coprocessor debug model
288         cmp     r0, #5                          @ debug arch >= v7.1?
289         movge   r0, #0                          @ yes, unlock debug
290         mcrge   p14, 0, r0, c1, c0, 4           @ DBGOSLAR
291 #endif
292 #if DEBUG_CPU_RESET_HANDLER
293         b       .
294 #endif
295 #ifndef CONFIG_TRUSTED_FOUNDATIONS
296         cpsid   aif, 0x13                       @ SVC mode, interrupts disabled
297         mrc     p15, 0, r0, c0, c0, 0           @ read main ID register
298         and     r5, r0, #0x00f00000             @ variant
299         and     r6, r0, #0x0000000f             @ revision
300         orr     r6, r6, r5, lsr #20-4           @ combine variant and revision
301 #ifdef CONFIG_ARM_ERRATA_743622
302         teq     r6, #0x20                       @ present in r2p0
303         teqne   r6, #0x21                       @ present in r2p1
304         teqne   r6, #0x22                       @ present in r2p2
305         teqne   r6, #0x27                       @ present in r2p7
306         teqne   r6, #0x29                       @ present in r2p9
307         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
308         orreq   r10, r10, #1 << 6               @ set bit #6
309         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
310 #endif
311 #endif
312         mrc     p15, 0, r10, c0, c0, 5          @ MPIDR
313         and     r10, r10, #0x3                  @ R10 = CPU number
314         mov     r11, #1
315         mov     r11, r11, lsl r10               @ R11 = CPU mask
316         adr     r12, __tegra_cpu_reset_handler_data
317
318 #ifdef CONFIG_SMP
319         /* Does the OS know about this CPU? */
320         ldr     r7, [r12, #RESET_DATA(MASK_PRESENT)]
321         tst     r7, r11                         @ if !present
322         bleq    __die                           @ CPU not present (to OS)
323 #endif
324
325 #ifdef CONFIG_ARCH_TEGRA_2x_SOC
326         /* If CPU1, don't let CPU0 reset CPU1 now that CPU1 is coming up. */
327         mov32   r6, TEGRA_PMC_BASE
328         mov     r0, #0
329         cmp     r10, #0
330         strne   r0, [r6, #PMC_SCRATCH41]
331 #endif
332
333 #ifdef CONFIG_PM_SLEEP
334         /* Waking up from LP1? */
335         ldr     r8, [r12, #RESET_DATA(MASK_LP1)]
336         tst     r8, r11                         @ if in_lp1
337         beq     __is_not_lp1
338         cmp     r10, #0
339         bne     __die                           @ only CPU0 can be here
340         ldr     lr, [r12, #RESET_DATA(STARTUP_LP1)]
341         cmp     lr, #0
342         bleq    __die                           @ no LP1 startup handler
343         bx      lr
344 __is_not_lp1:
345 #endif
346
347         /* Waking up from LP2? */
348         ldr     r9, [r12, #RESET_DATA(MASK_LP2)]
349         tst     r9, r11                         @ if in_lp2
350         beq     __is_not_lp2
351         ldr     lr, [r12, #RESET_DATA(STARTUP_LP2)]
352         cmp     lr, #0
353         bleq    __die                           @ no LP2 startup handler
354         bx      lr
355
356 __is_not_lp2:
357
358 #ifdef CONFIG_SMP
359 #ifndef CONFIG_TEGRA_VIRTUAL_CPUID
360         /* Can only be secondary boot (initial or hotplug) but CPU 0
361            cannot be here. */
362         cmp     r10, #0
363         bleq    __die                           @ CPU0 cannot be here
364 #endif
365         ldr     lr, [r12, #RESET_DATA(STARTUP_SECONDARY)]
366         cmp     lr, #0
367         bleq    __die                           @ no secondary startup handler
368         bx      lr
369 #endif
370
371 /*
372  * We don't know why the CPU reset. Just kill it.
373  * The LR register will contain the address we died at + 4.
374  */
375
376 __die:
377         sub     lr, lr, #4
378         mov32   r7, TEGRA_PMC_BASE
379         str     lr, [r7, #PMC_SCRATCH41]
380
381         mov32   r7, TEGRA_CLK_RESET_BASE
382
383         /* Are we on Tegra20? */
384         mov32   r6, TEGRA_APB_MISC_BASE
385         ldr     r0, [r6, #APB_MISC_GP_HIDREV]
386         and     r0, r0, #0xff00
387         cmp     r0, #(0x20 << 8)
388         bne     1f
389
390 #ifdef CONFIG_ARCH_TEGRA_2x_SOC
391         mov32   r0, 0x1111
392         mov     r1, r0, lsl r10
393         str     r1, [r7, #0x340]                @ CLK_RST_CPU_CMPLX_SET
394 #endif
395 1:
396 #ifdef CONFIG_ARCH_TEGRA_3x_SOC
397         mov32   r6, TEGRA_FLOW_CTRL_BASE
398
399         cmp     r10, #0
400         moveq   r1, #FLOW_CTRL_HALT_CPU0_EVENTS
401         moveq   r2, #FLOW_CTRL_CPU0_CSR
402         movne   r1, r10, lsl #3
403         addne   r2, r1, #(FLOW_CTRL_CPU1_CSR-8)
404         addne   r1, r1, #(FLOW_CTRL_HALT_CPU1_EVENTS-8)
405
406         /* Clear CPU "event" and "interrupt" flags and power gate
407            it when halting but not before it is in the "WFI" state. */
408         ldr     r0, [r6, +r2]
409         orr     r0, r0, #FLOW_CTRL_CSR_INTR_FLAG | FLOW_CTRL_CSR_EVENT_FLAG
410         orr     r0, r0, #FLOW_CTRL_CSR_ENABLE
411         str     r0, [r6, +r2]
412
413         /* Unconditionally halt this CPU */
414         mov     r0, #FLOW_CTRL_WAITEVENT
415         str     r0, [r6, +r1]
416         ldr     r0, [r6, +r1]                   @ memory barrier
417
418         dsb
419         isb
420         wfi                                     @ CPU should be power gated here
421
422         /* If the CPU didn't power gate above just kill it's clock. */
423
424         mov     r0, r11, lsl #8
425         str     r0, [r7, #348]                  @ CLK_CPU_CMPLX_SET
426 #endif
427
428         /* If the CPU still isn't dead, just spin here. */
429         b       .
430 ENDPROC(__tegra_cpu_reset_handler)
431
432         .align L1_CACHE_SHIFT
433         .type   __tegra_cpu_reset_handler_data, %object
434         .globl  __tegra_cpu_reset_handler_data
435 __tegra_cpu_reset_handler_data:
436         .rept   TEGRA_RESET_DATA_SIZE
437         .long   0
438         .endr
439         .size   __tegra_cpu_reset_handler_data, . - __tegra_cpu_reset_handler_data
440         .align L1_CACHE_SHIFT
441 ENTRY(__tegra_cpu_reset_handler_end)