3ca574ee277271e04b05c79ed956337b3e7dfb7a
[linux-2.6.git] / arch / arm / kernel / vmlinux.lds.S
1 /* ld script to make ARM Linux kernel
2  * taken from the i386 version by Russell King
3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4  */
5
6 #include <asm-generic/vmlinux.lds.h>
7 #include <asm/thread_info.h>
8 #include <asm/memory.h>
9         
10 OUTPUT_ARCH(arm)
11 ENTRY(stext)
12
13 #ifndef __ARMEB__
14 jiffies = jiffies_64;
15 #else
16 jiffies = jiffies_64 + 4;
17 #endif
18
19 SECTIONS
20 {
21 #ifdef CONFIG_XIP_KERNEL
22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
23 #else
24         . = PAGE_OFFSET + TEXT_OFFSET;
25 #endif
26         .init : {                       /* Init code and data           */
27                 _stext = .;
28                         _sinittext = .;
29                         *(.init.text)
30                         _einittext = .;
31                 __proc_info_begin = .;
32                         *(.proc.info.init)
33                 __proc_info_end = .;
34                 __arch_info_begin = .;
35                         *(.arch.info.init)
36                 __arch_info_end = .;
37                 __tagtable_begin = .;
38                         *(.taglist.init)
39                 __tagtable_end = .;
40                 . = ALIGN(16);
41                 __setup_start = .;
42                         *(.init.setup)
43                 __setup_end = .;
44                 __early_begin = .;
45                         *(.early_param.init)
46                 __early_end = .;
47                 __initcall_start = .;
48                         *(.initcall1.init)
49                         *(.initcall2.init)
50                         *(.initcall3.init)
51                         *(.initcall4.init)
52                         *(.initcall5.init)
53                         *(.initcall6.init)
54                         *(.initcall7.init)
55                 __initcall_end = .;
56                 __con_initcall_start = .;
57                         *(.con_initcall.init)
58                 __con_initcall_end = .;
59                 __security_initcall_start = .;
60                         *(.security_initcall.init)
61                 __security_initcall_end = .;
62                 . = ALIGN(32);
63                 __initramfs_start = .;
64                         usr/built-in.o(.init.ramfs)
65                 __initramfs_end = .;
66                 . = ALIGN(64);
67                 __per_cpu_start = .;
68                         *(.data.percpu)
69                 __per_cpu_end = .;
70 #ifndef CONFIG_XIP_KERNEL
71                 __init_begin = _stext;
72                 *(.init.data)
73                 . = ALIGN(4096);
74                 __init_end = .;
75 #endif
76         }
77
78         /DISCARD/ : {                   /* Exit code and data           */
79                 *(.exit.text)
80                 *(.exit.data)
81                 *(.exitcall.exit)
82 #ifndef CONFIG_MMU
83                 *(.fixup)
84                 *(__ex_table)
85 #endif
86         }
87
88         .text : {                       /* Real text segment            */
89                 _text = .;              /* Text and read-only data      */
90                         *(.text)
91                         SCHED_TEXT
92                         LOCK_TEXT
93 #ifdef CONFIG_MMU
94                         *(.fixup)
95 #endif
96                         *(.gnu.warning)
97                         *(.rodata)
98                         *(.rodata.*)
99                         *(.glue_7)
100                         *(.glue_7t)
101                 *(.got)                 /* Global offset table          */
102         }
103
104         RODATA
105
106         _etext = .;                     /* End of text and rodata section */
107
108 #ifdef CONFIG_XIP_KERNEL
109         __data_loc = ALIGN(4);          /* location in binary */
110         . = PAGE_OFFSET + TEXT_OFFSET;
111 #else
112         . = ALIGN(THREAD_SIZE);
113         __data_loc = .;
114 #endif
115
116         .data : AT(__data_loc) {
117                 __data_start = .;       /* address in memory */
118
119                 /*
120                  * first, the init task union, aligned
121                  * to an 8192 byte boundary.
122                  */
123                 *(.init.task)
124
125 #ifdef CONFIG_XIP_KERNEL
126                 . = ALIGN(4096);
127                 __init_begin = .;
128                 *(.init.data)
129                 . = ALIGN(4096);
130                 __init_end = .;
131 #endif
132
133                 . = ALIGN(4096);
134                 __nosave_begin = .;
135                 *(.data.nosave)
136                 . = ALIGN(4096);
137                 __nosave_end = .;
138
139                 /*
140                  * then the cacheline aligned data
141                  */
142                 . = ALIGN(32);
143                 *(.data.cacheline_aligned)
144
145                 /*
146                  * The exception fixup table (might need resorting at runtime)
147                  */
148                 . = ALIGN(32);
149                 __start___ex_table = .;
150 #ifdef CONFIG_MMU
151                 *(__ex_table)
152 #endif
153                 __stop___ex_table = .;
154
155                 /*
156                  * and the usual data section
157                  */
158                 *(.data)
159                 CONSTRUCTORS
160
161                 _edata = .;
162         }
163
164         .bss : {
165                 __bss_start = .;        /* BSS                          */
166                 *(.bss)
167                 *(COMMON)
168                 _end = .;
169         }
170                                         /* Stabs debugging sections.    */
171         .stab 0 : { *(.stab) }
172         .stabstr 0 : { *(.stabstr) }
173         .stab.excl 0 : { *(.stab.excl) }
174         .stab.exclstr 0 : { *(.stab.exclstr) }
175         .stab.index 0 : { *(.stab.index) }
176         .stab.indexstr 0 : { *(.stab.indexstr) }
177         .comment 0 : { *(.comment) }
178 }
179
180 /*
181  * These must never be empty
182  * If you have to comment these two assert statements out, your
183  * binutils is too old (for other reasons as well)
184  */
185 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
186 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")