ARM: ftrace: use gas macros to avoid code duplication
[linux-2.6.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10
11 #include <asm/unistd.h>
12 #include <asm/ftrace.h>
13 #include <mach/entry-macro.S>
14 #include <asm/unwind.h>
15
16 #include "entry-header.S"
17
18
19         .align  5
20 /*
21  * This is the fast syscall return path.  We do as little as
22  * possible here, and this includes saving r0 back into the SVC
23  * stack.
24  */
25 ret_fast_syscall:
26  UNWIND(.fnstart        )
27  UNWIND(.cantunwind     )
28         disable_irq                             @ disable interrupts
29         ldr     r1, [tsk, #TI_FLAGS]
30         tst     r1, #_TIF_WORK_MASK
31         bne     fast_work_pending
32
33         /* perform architecture specific actions before user return */
34         arch_ret_to_user r1, lr
35
36         restore_user_regs fast = 1, offset = S_OFF
37  UNWIND(.fnend          )
38
39 /*
40  * Ok, we need to do extra processing, enter the slow path.
41  */
42 fast_work_pending:
43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
44 work_pending:
45         tst     r1, #_TIF_NEED_RESCHED
46         bne     work_resched
47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
48         beq     no_work_pending
49         mov     r0, sp                          @ 'regs'
50         mov     r2, why                         @ 'syscall'
51         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
52         movne   why, #0                         @ prevent further restarts
53         bl      do_notify_resume
54         b       ret_slow_syscall                @ Check work again
55
56 work_resched:
57         bl      schedule
58 /*
59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
60  */
61 ENTRY(ret_to_user)
62 ret_slow_syscall:
63         disable_irq                             @ disable interrupts
64         ldr     r1, [tsk, #TI_FLAGS]
65         tst     r1, #_TIF_WORK_MASK
66         bne     work_pending
67 no_work_pending:
68         /* perform architecture specific actions before user return */
69         arch_ret_to_user r1, lr
70
71         restore_user_regs fast = 0, offset = 0
72 ENDPROC(ret_to_user)
73
74 /*
75  * This is how we return from a fork.
76  */
77 ENTRY(ret_from_fork)
78         bl      schedule_tail
79         get_thread_info tsk
80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
81         mov     why, #1
82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
83         beq     ret_slow_syscall
84         mov     r1, sp
85         mov     r0, #1                          @ trace exit [IP = 1]
86         bl      syscall_trace
87         b       ret_slow_syscall
88 ENDPROC(ret_from_fork)
89
90         .equ NR_syscalls,0
91 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
92 #include "calls.S"
93 #undef CALL
94 #define CALL(x) .long x
95
96 #ifdef CONFIG_FUNCTION_TRACER
97 /*
98  * When compiling with -pg, gcc inserts a call to the mcount routine at the
99  * start of every function.  In mcount, apart from the function's address (in
100  * lr), we need to get hold of the function's caller's address.
101  *
102  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
103  *
104  *      bl      mcount
105  *
106  * These versions have the limitation that in order for the mcount routine to
107  * be able to determine the function's caller's address, an APCS-style frame
108  * pointer (which is set up with something like the code below) is required.
109  *
110  *      mov     ip, sp
111  *      push    {fp, ip, lr, pc}
112  *      sub     fp, ip, #4
113  *
114  * With EABI, these frame pointers are not available unless -mapcs-frame is
115  * specified, and if building as Thumb-2, not even then.
116  *
117  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
118  * with call sites like:
119  *
120  *      push    {lr}
121  *      bl      __gnu_mcount_nc
122  *
123  * With these compilers, frame pointers are not necessary.
124  *
125  * mcount can be thought of as a function called in the middle of a subroutine
126  * call.  As such, it needs to be transparent for both the caller and the
127  * callee: the original lr needs to be restored when leaving mcount, and no
128  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
129  * clobber the ip register.  This is OK because the ARM calling convention
130  * allows it to be clobbered in subroutines and doesn't use it to hold
131  * parameters.)
132  *
133  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
134  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
135  * arch/arm/kernel/ftrace.c).
136  */
137
138 #ifndef CONFIG_OLD_MCOUNT
139 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
140 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
141 #endif
142 #endif
143
144 .macro __mcount suffix
145         mcount_enter
146         ldr     r0, =ftrace_trace_function
147         ldr     r2, [r0]
148         adr     r0, .Lftrace_stub
149         cmp     r0, r2
150         bne     1f
151         mcount_exit
152
153 1:      mcount_get_lr   r1                      @ lr of instrumented func
154         mov     r0, lr                          @ instrumented function
155         sub     r0, r0, #MCOUNT_INSN_SIZE
156         adr     lr, BSYM(2f)
157         mov     pc, r2
158 2:      mcount_exit
159 .endm
160
161 .macro __ftrace_caller suffix
162         mcount_enter
163
164         mcount_get_lr   r1                      @ lr of instrumented func
165         mov     r0, lr                          @ instrumented function
166         sub     r0, r0, #MCOUNT_INSN_SIZE
167
168         .globl ftrace_call\suffix
169 ftrace_call\suffix:
170         bl      ftrace_stub
171
172         mcount_exit
173 .endm
174
175 #ifdef CONFIG_OLD_MCOUNT
176 /*
177  * mcount
178  */
179
180 .macro mcount_enter
181         stmdb   sp!, {r0-r3, lr}
182 .endm
183
184 .macro mcount_get_lr reg
185         ldr     \reg, [fp, #-4]
186 .endm
187
188 .macro mcount_exit
189         ldr     lr, [fp, #-4]
190         ldmia   sp!, {r0-r3, pc}
191 .endm
192
193 ENTRY(mcount)
194 #ifdef CONFIG_DYNAMIC_FTRACE
195         stmdb   sp!, {lr}
196         ldr     lr, [fp, #-4]
197         ldmia   sp!, {pc}
198 #else
199         __mcount _old
200 #endif
201 ENDPROC(mcount)
202
203 #ifdef CONFIG_DYNAMIC_FTRACE
204 ENTRY(ftrace_caller_old)
205         __ftrace_caller _old
206 ENDPROC(ftrace_caller_old)
207 #endif
208
209 .purgem mcount_enter
210 .purgem mcount_get_lr
211 .purgem mcount_exit
212 #endif
213
214 /*
215  * __gnu_mcount_nc
216  */
217
218 .macro mcount_enter
219         stmdb   sp!, {r0-r3, lr}
220 .endm
221
222 .macro mcount_get_lr reg
223         ldr     \reg, [sp, #20]
224 .endm
225
226 .macro mcount_exit
227         ldmia   sp!, {r0-r3, ip, lr}
228         mov     pc, ip
229 .endm
230
231 ENTRY(__gnu_mcount_nc)
232 #ifdef CONFIG_DYNAMIC_FTRACE
233         mov     ip, lr
234         ldmia   sp!, {lr}
235         mov     pc, ip
236 #else
237         __mcount
238 #endif
239 ENDPROC(__gnu_mcount_nc)
240
241 #ifdef CONFIG_DYNAMIC_FTRACE
242 ENTRY(ftrace_caller)
243         __ftrace_caller
244 ENDPROC(ftrace_caller)
245 #endif
246
247 .purgem mcount_enter
248 .purgem mcount_get_lr
249 .purgem mcount_exit
250
251 ENTRY(ftrace_stub)
252 .Lftrace_stub:
253         mov     pc, lr
254 ENDPROC(ftrace_stub)
255
256 #endif /* CONFIG_FUNCTION_TRACER */
257
258 /*=============================================================================
259  * SWI handler
260  *-----------------------------------------------------------------------------
261  */
262
263         /* If we're optimising for StrongARM the resulting code won't 
264            run on an ARM7 and we can save a couple of instructions.  
265                                                                 --pb */
266 #ifdef CONFIG_CPU_ARM710
267 #define A710(code...) code
268 .Larm710bug:
269         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
270         mov     r0, r0
271         add     sp, sp, #S_FRAME_SIZE
272         subs    pc, lr, #4
273 #else
274 #define A710(code...)
275 #endif
276
277         .align  5
278 ENTRY(vector_swi)
279         sub     sp, sp, #S_FRAME_SIZE
280         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
281  ARM(   add     r8, sp, #S_PC           )
282  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
283  THUMB( mov     r8, sp                  )
284  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
285         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
286         str     lr, [sp, #S_PC]                 @ Save calling PC
287         str     r8, [sp, #S_PSR]                @ Save CPSR
288         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
289         zero_fp
290
291         /*
292          * Get the system call number.
293          */
294
295 #if defined(CONFIG_OABI_COMPAT)
296
297         /*
298          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
299          * value to determine if it is an EABI or an old ABI call.
300          */
301 #ifdef CONFIG_ARM_THUMB
302         tst     r8, #PSR_T_BIT
303         movne   r10, #0                         @ no thumb OABI emulation
304         ldreq   r10, [lr, #-4]                  @ get SWI instruction
305 #else
306         ldr     r10, [lr, #-4]                  @ get SWI instruction
307   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
308   A710( teq     ip, #0x0f000000                                         )
309   A710( bne     .Larm710bug                                             )
310 #endif
311 #ifdef CONFIG_CPU_ENDIAN_BE8
312         rev     r10, r10                        @ little endian instruction
313 #endif
314
315 #elif defined(CONFIG_AEABI)
316
317         /*
318          * Pure EABI user space always put syscall number into scno (r7).
319          */
320   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
321   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
322   A710( teq     ip, #0x0f000000                                         )
323   A710( bne     .Larm710bug                                             )
324
325 #elif defined(CONFIG_ARM_THUMB)
326
327         /* Legacy ABI only, possibly thumb mode. */
328         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
329         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
330         ldreq   scno, [lr, #-4]
331
332 #else
333
334         /* Legacy ABI only. */
335         ldr     scno, [lr, #-4]                 @ get SWI instruction
336   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
337   A710( teq     ip, #0x0f000000                                         )
338   A710( bne     .Larm710bug                                             )
339
340 #endif
341
342 #ifdef CONFIG_ALIGNMENT_TRAP
343         ldr     ip, __cr_alignment
344         ldr     ip, [ip]
345         mcr     p15, 0, ip, c1, c0              @ update control register
346 #endif
347         enable_irq
348
349         get_thread_info tsk
350         adr     tbl, sys_call_table             @ load syscall table pointer
351
352 #if defined(CONFIG_OABI_COMPAT)
353         /*
354          * If the swi argument is zero, this is an EABI call and we do nothing.
355          *
356          * If this is an old ABI call, get the syscall number into scno and
357          * get the old ABI syscall table address.
358          */
359         bics    r10, r10, #0xff000000
360         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
361         ldrne   tbl, =sys_oabi_call_table
362 #elif !defined(CONFIG_AEABI)
363         bic     scno, scno, #0xff000000         @ mask off SWI op-code
364         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
365 #endif
366
367         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
368         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
369
370 #ifdef CONFIG_SECCOMP
371         tst     r10, #_TIF_SECCOMP
372         beq     1f
373         mov     r0, scno
374         bl      __secure_computing      
375         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
376         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
377 1:
378 #endif
379
380         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
381         bne     __sys_trace
382
383         cmp     scno, #NR_syscalls              @ check upper syscall limit
384         adr     lr, BSYM(ret_fast_syscall)      @ return address
385         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
386
387         add     r1, sp, #S_OFF
388 2:      mov     why, #0                         @ no longer a real syscall
389         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
390         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
391         bcs     arm_syscall     
392         b       sys_ni_syscall                  @ not private func
393 ENDPROC(vector_swi)
394
395         /*
396          * This is the really slow path.  We're going to be doing
397          * context switches, and waiting for our parent to respond.
398          */
399 __sys_trace:
400         mov     r2, scno
401         add     r1, sp, #S_OFF
402         mov     r0, #0                          @ trace entry [IP = 0]
403         bl      syscall_trace
404
405         adr     lr, BSYM(__sys_trace_return)    @ return address
406         mov     scno, r0                        @ syscall number (possibly new)
407         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
408         cmp     scno, #NR_syscalls              @ check upper syscall limit
409         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
410         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
411         b       2b
412
413 __sys_trace_return:
414         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
415         mov     r2, scno
416         mov     r1, sp
417         mov     r0, #1                          @ trace exit [IP = 1]
418         bl      syscall_trace
419         b       ret_slow_syscall
420
421         .align  5
422 #ifdef CONFIG_ALIGNMENT_TRAP
423         .type   __cr_alignment, #object
424 __cr_alignment:
425         .word   cr_alignment
426 #endif
427         .ltorg
428
429 /*
430  * This is the syscall table declaration for native ABI syscalls.
431  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
432  */
433 #define ABI(native, compat) native
434 #ifdef CONFIG_AEABI
435 #define OBSOLETE(syscall) sys_ni_syscall
436 #else
437 #define OBSOLETE(syscall) syscall
438 #endif
439
440         .type   sys_call_table, #object
441 ENTRY(sys_call_table)
442 #include "calls.S"
443 #undef ABI
444 #undef OBSOLETE
445
446 /*============================================================================
447  * Special system call wrappers
448  */
449 @ r0 = syscall number
450 @ r8 = syscall table
451 sys_syscall:
452                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
453                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
454                 cmpne   scno, #NR_syscalls      @ check range
455                 stmloia sp, {r5, r6}            @ shuffle args
456                 movlo   r0, r1
457                 movlo   r1, r2
458                 movlo   r2, r3
459                 movlo   r3, r4
460                 ldrlo   pc, [tbl, scno, lsl #2]
461                 b       sys_ni_syscall
462 ENDPROC(sys_syscall)
463
464 sys_fork_wrapper:
465                 add     r0, sp, #S_OFF
466                 b       sys_fork
467 ENDPROC(sys_fork_wrapper)
468
469 sys_vfork_wrapper:
470                 add     r0, sp, #S_OFF
471                 b       sys_vfork
472 ENDPROC(sys_vfork_wrapper)
473
474 sys_execve_wrapper:
475                 add     r3, sp, #S_OFF
476                 b       sys_execve
477 ENDPROC(sys_execve_wrapper)
478
479 sys_clone_wrapper:
480                 add     ip, sp, #S_OFF
481                 str     ip, [sp, #4]
482                 b       sys_clone
483 ENDPROC(sys_clone_wrapper)
484
485 sys_sigreturn_wrapper:
486                 add     r0, sp, #S_OFF
487                 mov     why, #0         @ prevent syscall restart handling
488                 b       sys_sigreturn
489 ENDPROC(sys_sigreturn_wrapper)
490
491 sys_rt_sigreturn_wrapper:
492                 add     r0, sp, #S_OFF
493                 mov     why, #0         @ prevent syscall restart handling
494                 b       sys_rt_sigreturn
495 ENDPROC(sys_rt_sigreturn_wrapper)
496
497 sys_sigaltstack_wrapper:
498                 ldr     r2, [sp, #S_OFF + S_SP]
499                 b       do_sigaltstack
500 ENDPROC(sys_sigaltstack_wrapper)
501
502 sys_statfs64_wrapper:
503                 teq     r1, #88
504                 moveq   r1, #84
505                 b       sys_statfs64
506 ENDPROC(sys_statfs64_wrapper)
507
508 sys_fstatfs64_wrapper:
509                 teq     r1, #88
510                 moveq   r1, #84
511                 b       sys_fstatfs64
512 ENDPROC(sys_fstatfs64_wrapper)
513
514 /*
515  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
516  * offset, we return EINVAL.
517  */
518 sys_mmap2:
519 #if PAGE_SHIFT > 12
520                 tst     r5, #PGOFF_MASK
521                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
522                 streq   r5, [sp, #4]
523                 beq     sys_mmap_pgoff
524                 mov     r0, #-EINVAL
525                 mov     pc, lr
526 #else
527                 str     r5, [sp, #4]
528                 b       sys_mmap_pgoff
529 #endif
530 ENDPROC(sys_mmap2)
531
532 #ifdef CONFIG_OABI_COMPAT
533
534 /*
535  * These are syscalls with argument register differences
536  */
537
538 sys_oabi_pread64:
539                 stmia   sp, {r3, r4}
540                 b       sys_pread64
541 ENDPROC(sys_oabi_pread64)
542
543 sys_oabi_pwrite64:
544                 stmia   sp, {r3, r4}
545                 b       sys_pwrite64
546 ENDPROC(sys_oabi_pwrite64)
547
548 sys_oabi_truncate64:
549                 mov     r3, r2
550                 mov     r2, r1
551                 b       sys_truncate64
552 ENDPROC(sys_oabi_truncate64)
553
554 sys_oabi_ftruncate64:
555                 mov     r3, r2
556                 mov     r2, r1
557                 b       sys_ftruncate64
558 ENDPROC(sys_oabi_ftruncate64)
559
560 sys_oabi_readahead:
561                 str     r3, [sp]
562                 mov     r3, r2
563                 mov     r2, r1
564                 b       sys_readahead
565 ENDPROC(sys_oabi_readahead)
566
567 /*
568  * Let's declare a second syscall table for old ABI binaries
569  * using the compatibility syscall entries.
570  */
571 #define ABI(native, compat) compat
572 #define OBSOLETE(syscall) syscall
573
574         .type   sys_oabi_call_table, #object
575 ENTRY(sys_oabi_call_table)
576 #include "calls.S"
577 #undef ABI
578 #undef OBSOLETE
579
580 #endif
581