ARM: 6540/1: Stop irqsoff trace on return to user
[linux-2.6.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10
11 #include <asm/unistd.h>
12 #include <asm/ftrace.h>
13 #include <mach/entry-macro.S>
14 #include <asm/unwind.h>
15
16 #include "entry-header.S"
17
18
19         .align  5
20 /*
21  * This is the fast syscall return path.  We do as little as
22  * possible here, and this includes saving r0 back into the SVC
23  * stack.
24  */
25 ret_fast_syscall:
26  UNWIND(.fnstart        )
27  UNWIND(.cantunwind     )
28         disable_irq                             @ disable interrupts
29         ldr     r1, [tsk, #TI_FLAGS]
30         tst     r1, #_TIF_WORK_MASK
31         bne     fast_work_pending
32 #if defined(CONFIG_IRQSOFF_TRACER)
33         asm_trace_hardirqs_on
34 #endif
35
36         /* perform architecture specific actions before user return */
37         arch_ret_to_user r1, lr
38
39         restore_user_regs fast = 1, offset = S_OFF
40  UNWIND(.fnend          )
41
42 /*
43  * Ok, we need to do extra processing, enter the slow path.
44  */
45 fast_work_pending:
46         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
47 work_pending:
48         tst     r1, #_TIF_NEED_RESCHED
49         bne     work_resched
50         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
51         beq     no_work_pending
52         mov     r0, sp                          @ 'regs'
53         mov     r2, why                         @ 'syscall'
54         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
55         movne   why, #0                         @ prevent further restarts
56         bl      do_notify_resume
57         b       ret_slow_syscall                @ Check work again
58
59 work_resched:
60         bl      schedule
61 /*
62  * "slow" syscall return path.  "why" tells us if this was a real syscall.
63  */
64 ENTRY(ret_to_user)
65 ret_slow_syscall:
66         disable_irq                             @ disable interrupts
67         ldr     r1, [tsk, #TI_FLAGS]
68         tst     r1, #_TIF_WORK_MASK
69         bne     work_pending
70 no_work_pending:
71 #if defined(CONFIG_IRQSOFF_TRACER)
72         asm_trace_hardirqs_on
73 #endif
74         /* perform architecture specific actions before user return */
75         arch_ret_to_user r1, lr
76
77         restore_user_regs fast = 0, offset = 0
78 ENDPROC(ret_to_user)
79
80 /*
81  * This is how we return from a fork.
82  */
83 ENTRY(ret_from_fork)
84         bl      schedule_tail
85         get_thread_info tsk
86         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
87         mov     why, #1
88         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
89         beq     ret_slow_syscall
90         mov     r1, sp
91         mov     r0, #1                          @ trace exit [IP = 1]
92         bl      syscall_trace
93         b       ret_slow_syscall
94 ENDPROC(ret_from_fork)
95
96         .equ NR_syscalls,0
97 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
98 #include "calls.S"
99 #undef CALL
100 #define CALL(x) .long x
101
102 #ifdef CONFIG_FUNCTION_TRACER
103 /*
104  * When compiling with -pg, gcc inserts a call to the mcount routine at the
105  * start of every function.  In mcount, apart from the function's address (in
106  * lr), we need to get hold of the function's caller's address.
107  *
108  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
109  *
110  *      bl      mcount
111  *
112  * These versions have the limitation that in order for the mcount routine to
113  * be able to determine the function's caller's address, an APCS-style frame
114  * pointer (which is set up with something like the code below) is required.
115  *
116  *      mov     ip, sp
117  *      push    {fp, ip, lr, pc}
118  *      sub     fp, ip, #4
119  *
120  * With EABI, these frame pointers are not available unless -mapcs-frame is
121  * specified, and if building as Thumb-2, not even then.
122  *
123  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
124  * with call sites like:
125  *
126  *      push    {lr}
127  *      bl      __gnu_mcount_nc
128  *
129  * With these compilers, frame pointers are not necessary.
130  *
131  * mcount can be thought of as a function called in the middle of a subroutine
132  * call.  As such, it needs to be transparent for both the caller and the
133  * callee: the original lr needs to be restored when leaving mcount, and no
134  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
135  * clobber the ip register.  This is OK because the ARM calling convention
136  * allows it to be clobbered in subroutines and doesn't use it to hold
137  * parameters.)
138  *
139  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
140  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
141  * arch/arm/kernel/ftrace.c).
142  */
143
144 #ifndef CONFIG_OLD_MCOUNT
145 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
146 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
147 #endif
148 #endif
149
150 #ifdef CONFIG_DYNAMIC_FTRACE
151 ENTRY(__gnu_mcount_nc)
152         mov     ip, lr
153         ldmia   sp!, {lr}
154         mov     pc, ip
155 ENDPROC(__gnu_mcount_nc)
156
157 ENTRY(ftrace_caller)
158         stmdb   sp!, {r0-r3, lr}
159         mov     r0, lr
160         sub     r0, r0, #MCOUNT_INSN_SIZE
161         ldr     r1, [sp, #20]
162
163         .global ftrace_call
164 ftrace_call:
165         bl      ftrace_stub
166         ldmia   sp!, {r0-r3, ip, lr}
167         mov     pc, ip
168 ENDPROC(ftrace_caller)
169
170 #ifdef CONFIG_OLD_MCOUNT
171 ENTRY(mcount)
172         stmdb   sp!, {lr}
173         ldr     lr, [fp, #-4]
174         ldmia   sp!, {pc}
175 ENDPROC(mcount)
176
177 ENTRY(ftrace_caller_old)
178         stmdb   sp!, {r0-r3, lr}
179         ldr     r1, [fp, #-4]
180         mov     r0, lr
181         sub     r0, r0, #MCOUNT_INSN_SIZE
182
183         .globl ftrace_call_old
184 ftrace_call_old:
185         bl      ftrace_stub
186         ldr     lr, [fp, #-4]                   @ restore lr
187         ldmia   sp!, {r0-r3, pc}
188 ENDPROC(ftrace_caller_old)
189 #endif
190
191 #else
192
193 ENTRY(__gnu_mcount_nc)
194         stmdb   sp!, {r0-r3, lr}
195         ldr     r0, =ftrace_trace_function
196         ldr     r2, [r0]
197         adr     r0, .Lftrace_stub
198         cmp     r0, r2
199         bne     gnu_trace
200         ldmia   sp!, {r0-r3, ip, lr}
201         mov     pc, ip
202
203 gnu_trace:
204         ldr     r1, [sp, #20]                   @ lr of instrumented routine
205         mov     r0, lr
206         sub     r0, r0, #MCOUNT_INSN_SIZE
207         adr     lr, BSYM(1f)
208         mov     pc, r2
209 1:
210         ldmia   sp!, {r0-r3, ip, lr}
211         mov     pc, ip
212 ENDPROC(__gnu_mcount_nc)
213
214 #ifdef CONFIG_OLD_MCOUNT
215 /*
216  * This is under an ifdef in order to force link-time errors for people trying
217  * to build with !FRAME_POINTER with a GCC which doesn't use the new-style
218  * mcount.
219  */
220 ENTRY(mcount)
221         stmdb   sp!, {r0-r3, lr}
222         ldr     r0, =ftrace_trace_function
223         ldr     r2, [r0]
224         adr     r0, ftrace_stub
225         cmp     r0, r2
226         bne     trace
227         ldr     lr, [fp, #-4]                   @ restore lr
228         ldmia   sp!, {r0-r3, pc}
229
230 trace:
231         ldr     r1, [fp, #-4]                   @ lr of instrumented routine
232         mov     r0, lr
233         sub     r0, r0, #MCOUNT_INSN_SIZE
234         mov     lr, pc
235         mov     pc, r2
236         ldr     lr, [fp, #-4]                   @ restore lr
237         ldmia   sp!, {r0-r3, pc}
238 ENDPROC(mcount)
239 #endif
240
241 #endif /* CONFIG_DYNAMIC_FTRACE */
242
243 ENTRY(ftrace_stub)
244 .Lftrace_stub:
245         mov     pc, lr
246 ENDPROC(ftrace_stub)
247
248 #endif /* CONFIG_FUNCTION_TRACER */
249
250 /*=============================================================================
251  * SWI handler
252  *-----------------------------------------------------------------------------
253  */
254
255         /* If we're optimising for StrongARM the resulting code won't 
256            run on an ARM7 and we can save a couple of instructions.  
257                                                                 --pb */
258 #ifdef CONFIG_CPU_ARM710
259 #define A710(code...) code
260 .Larm710bug:
261         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
262         mov     r0, r0
263         add     sp, sp, #S_FRAME_SIZE
264         subs    pc, lr, #4
265 #else
266 #define A710(code...)
267 #endif
268
269         .align  5
270 ENTRY(vector_swi)
271         sub     sp, sp, #S_FRAME_SIZE
272         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
273  ARM(   add     r8, sp, #S_PC           )
274  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
275  THUMB( mov     r8, sp                  )
276  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
277         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
278         str     lr, [sp, #S_PC]                 @ Save calling PC
279         str     r8, [sp, #S_PSR]                @ Save CPSR
280         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
281         zero_fp
282
283         /*
284          * Get the system call number.
285          */
286
287 #if defined(CONFIG_OABI_COMPAT)
288
289         /*
290          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
291          * value to determine if it is an EABI or an old ABI call.
292          */
293 #ifdef CONFIG_ARM_THUMB
294         tst     r8, #PSR_T_BIT
295         movne   r10, #0                         @ no thumb OABI emulation
296         ldreq   r10, [lr, #-4]                  @ get SWI instruction
297 #else
298         ldr     r10, [lr, #-4]                  @ get SWI instruction
299   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
300   A710( teq     ip, #0x0f000000                                         )
301   A710( bne     .Larm710bug                                             )
302 #endif
303 #ifdef CONFIG_CPU_ENDIAN_BE8
304         rev     r10, r10                        @ little endian instruction
305 #endif
306
307 #elif defined(CONFIG_AEABI)
308
309         /*
310          * Pure EABI user space always put syscall number into scno (r7).
311          */
312   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
313   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
314   A710( teq     ip, #0x0f000000                                         )
315   A710( bne     .Larm710bug                                             )
316
317 #elif defined(CONFIG_ARM_THUMB)
318
319         /* Legacy ABI only, possibly thumb mode. */
320         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
321         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
322         ldreq   scno, [lr, #-4]
323
324 #else
325
326         /* Legacy ABI only. */
327         ldr     scno, [lr, #-4]                 @ get SWI instruction
328   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
329   A710( teq     ip, #0x0f000000                                         )
330   A710( bne     .Larm710bug                                             )
331
332 #endif
333
334 #ifdef CONFIG_ALIGNMENT_TRAP
335         ldr     ip, __cr_alignment
336         ldr     ip, [ip]
337         mcr     p15, 0, ip, c1, c0              @ update control register
338 #endif
339         enable_irq
340
341         get_thread_info tsk
342         adr     tbl, sys_call_table             @ load syscall table pointer
343
344 #if defined(CONFIG_OABI_COMPAT)
345         /*
346          * If the swi argument is zero, this is an EABI call and we do nothing.
347          *
348          * If this is an old ABI call, get the syscall number into scno and
349          * get the old ABI syscall table address.
350          */
351         bics    r10, r10, #0xff000000
352         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
353         ldrne   tbl, =sys_oabi_call_table
354 #elif !defined(CONFIG_AEABI)
355         bic     scno, scno, #0xff000000         @ mask off SWI op-code
356         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
357 #endif
358
359         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
360         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
361
362 #ifdef CONFIG_SECCOMP
363         tst     r10, #_TIF_SECCOMP
364         beq     1f
365         mov     r0, scno
366         bl      __secure_computing      
367         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
368         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
369 1:
370 #endif
371
372         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
373         bne     __sys_trace
374
375         cmp     scno, #NR_syscalls              @ check upper syscall limit
376         adr     lr, BSYM(ret_fast_syscall)      @ return address
377         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
378
379         add     r1, sp, #S_OFF
380 2:      mov     why, #0                         @ no longer a real syscall
381         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
382         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
383         bcs     arm_syscall     
384         b       sys_ni_syscall                  @ not private func
385 ENDPROC(vector_swi)
386
387         /*
388          * This is the really slow path.  We're going to be doing
389          * context switches, and waiting for our parent to respond.
390          */
391 __sys_trace:
392         mov     r2, scno
393         add     r1, sp, #S_OFF
394         mov     r0, #0                          @ trace entry [IP = 0]
395         bl      syscall_trace
396
397         adr     lr, BSYM(__sys_trace_return)    @ return address
398         mov     scno, r0                        @ syscall number (possibly new)
399         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
400         cmp     scno, #NR_syscalls              @ check upper syscall limit
401         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
402         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
403         b       2b
404
405 __sys_trace_return:
406         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
407         mov     r2, scno
408         mov     r1, sp
409         mov     r0, #1                          @ trace exit [IP = 1]
410         bl      syscall_trace
411         b       ret_slow_syscall
412
413         .align  5
414 #ifdef CONFIG_ALIGNMENT_TRAP
415         .type   __cr_alignment, #object
416 __cr_alignment:
417         .word   cr_alignment
418 #endif
419         .ltorg
420
421 /*
422  * This is the syscall table declaration for native ABI syscalls.
423  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
424  */
425 #define ABI(native, compat) native
426 #ifdef CONFIG_AEABI
427 #define OBSOLETE(syscall) sys_ni_syscall
428 #else
429 #define OBSOLETE(syscall) syscall
430 #endif
431
432         .type   sys_call_table, #object
433 ENTRY(sys_call_table)
434 #include "calls.S"
435 #undef ABI
436 #undef OBSOLETE
437
438 /*============================================================================
439  * Special system call wrappers
440  */
441 @ r0 = syscall number
442 @ r8 = syscall table
443 sys_syscall:
444                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
445                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
446                 cmpne   scno, #NR_syscalls      @ check range
447                 stmloia sp, {r5, r6}            @ shuffle args
448                 movlo   r0, r1
449                 movlo   r1, r2
450                 movlo   r2, r3
451                 movlo   r3, r4
452                 ldrlo   pc, [tbl, scno, lsl #2]
453                 b       sys_ni_syscall
454 ENDPROC(sys_syscall)
455
456 sys_fork_wrapper:
457                 add     r0, sp, #S_OFF
458                 b       sys_fork
459 ENDPROC(sys_fork_wrapper)
460
461 sys_vfork_wrapper:
462                 add     r0, sp, #S_OFF
463                 b       sys_vfork
464 ENDPROC(sys_vfork_wrapper)
465
466 sys_execve_wrapper:
467                 add     r3, sp, #S_OFF
468                 b       sys_execve
469 ENDPROC(sys_execve_wrapper)
470
471 sys_clone_wrapper:
472                 add     ip, sp, #S_OFF
473                 str     ip, [sp, #4]
474                 b       sys_clone
475 ENDPROC(sys_clone_wrapper)
476
477 sys_sigreturn_wrapper:
478                 add     r0, sp, #S_OFF
479                 mov     why, #0         @ prevent syscall restart handling
480                 b       sys_sigreturn
481 ENDPROC(sys_sigreturn_wrapper)
482
483 sys_rt_sigreturn_wrapper:
484                 add     r0, sp, #S_OFF
485                 mov     why, #0         @ prevent syscall restart handling
486                 b       sys_rt_sigreturn
487 ENDPROC(sys_rt_sigreturn_wrapper)
488
489 sys_sigaltstack_wrapper:
490                 ldr     r2, [sp, #S_OFF + S_SP]
491                 b       do_sigaltstack
492 ENDPROC(sys_sigaltstack_wrapper)
493
494 sys_statfs64_wrapper:
495                 teq     r1, #88
496                 moveq   r1, #84
497                 b       sys_statfs64
498 ENDPROC(sys_statfs64_wrapper)
499
500 sys_fstatfs64_wrapper:
501                 teq     r1, #88
502                 moveq   r1, #84
503                 b       sys_fstatfs64
504 ENDPROC(sys_fstatfs64_wrapper)
505
506 /*
507  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
508  * offset, we return EINVAL.
509  */
510 sys_mmap2:
511 #if PAGE_SHIFT > 12
512                 tst     r5, #PGOFF_MASK
513                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
514                 streq   r5, [sp, #4]
515                 beq     sys_mmap_pgoff
516                 mov     r0, #-EINVAL
517                 mov     pc, lr
518 #else
519                 str     r5, [sp, #4]
520                 b       sys_mmap_pgoff
521 #endif
522 ENDPROC(sys_mmap2)
523
524 #ifdef CONFIG_OABI_COMPAT
525
526 /*
527  * These are syscalls with argument register differences
528  */
529
530 sys_oabi_pread64:
531                 stmia   sp, {r3, r4}
532                 b       sys_pread64
533 ENDPROC(sys_oabi_pread64)
534
535 sys_oabi_pwrite64:
536                 stmia   sp, {r3, r4}
537                 b       sys_pwrite64
538 ENDPROC(sys_oabi_pwrite64)
539
540 sys_oabi_truncate64:
541                 mov     r3, r2
542                 mov     r2, r1
543                 b       sys_truncate64
544 ENDPROC(sys_oabi_truncate64)
545
546 sys_oabi_ftruncate64:
547                 mov     r3, r2
548                 mov     r2, r1
549                 b       sys_ftruncate64
550 ENDPROC(sys_oabi_ftruncate64)
551
552 sys_oabi_readahead:
553                 str     r3, [sp]
554                 mov     r3, r2
555                 mov     r2, r1
556                 b       sys_readahead
557 ENDPROC(sys_oabi_readahead)
558
559 /*
560  * Let's declare a second syscall table for old ABI binaries
561  * using the compatibility syscall entries.
562  */
563 #define ABI(native, compat) compat
564 #define OBSOLETE(syscall) syscall
565
566         .type   sys_oabi_call_table, #object
567 ENTRY(sys_oabi_call_table)
568 #include "calls.S"
569 #undef ABI
570 #undef OBSOLETE
571
572 #endif
573