[ARM] 2974/1: fix ARM710 swi bug workaround
[linux-2.6.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10 #include <linux/config.h>
11
12 #include <asm/unistd.h>
13
14 #include "entry-header.S"
15
16
17         .align  5
18 /*
19  * This is the fast syscall return path.  We do as little as
20  * possible here, and this includes saving r0 back into the SVC
21  * stack.
22  */
23 ret_fast_syscall:
24         disable_irq                             @ disable interrupts
25         ldr     r1, [tsk, #TI_FLAGS]
26         tst     r1, #_TIF_WORK_MASK
27         bne     fast_work_pending
28
29         @ fast_restore_user_regs
30         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
31         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
32         msr     spsr_cxsf, r1                   @ save in spsr_svc
33         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
34         mov     r0, r0
35         add     sp, sp, #S_FRAME_SIZE - S_PC
36         movs    pc, lr                          @ return & move spsr_svc into cpsr
37
38 /*
39  * Ok, we need to do extra processing, enter the slow path.
40  */
41 fast_work_pending:
42         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
43 work_pending:
44         tst     r1, #_TIF_NEED_RESCHED
45         bne     work_resched
46         tst     r1, #_TIF_NOTIFY_RESUME | _TIF_SIGPENDING
47         beq     no_work_pending
48         mov     r0, sp                          @ 'regs'
49         mov     r2, why                         @ 'syscall'
50         bl      do_notify_resume
51         disable_irq                             @ disable interrupts
52         b       no_work_pending
53
54 work_resched:
55         bl      schedule
56 /*
57  * "slow" syscall return path.  "why" tells us if this was a real syscall.
58  */
59 ENTRY(ret_to_user)
60 ret_slow_syscall:
61         disable_irq                             @ disable interrupts
62         ldr     r1, [tsk, #TI_FLAGS]
63         tst     r1, #_TIF_WORK_MASK
64         bne     work_pending
65 no_work_pending:
66         @ slow_restore_user_regs
67         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
68         ldr     lr, [sp, #S_PC]!                @ get pc
69         msr     spsr_cxsf, r1                   @ save in spsr_svc
70         ldmdb   sp, {r0 - lr}^                  @ get calling r1 - lr
71         mov     r0, r0
72         add     sp, sp, #S_FRAME_SIZE - S_PC
73         movs    pc, lr                          @ return & move spsr_svc into cpsr
74
75 /*
76  * This is how we return from a fork.
77  */
78 ENTRY(ret_from_fork)
79         bl      schedule_tail
80         get_thread_info tsk
81         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
82         mov     why, #1
83         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
84         beq     ret_slow_syscall
85         mov     r1, sp
86         mov     r0, #1                          @ trace exit [IP = 1]
87         bl      syscall_trace
88         b       ret_slow_syscall
89         
90
91 #include "calls.S"
92
93 /*=============================================================================
94  * SWI handler
95  *-----------------------------------------------------------------------------
96  */
97
98         /* If we're optimising for StrongARM the resulting code won't 
99            run on an ARM7 and we can save a couple of instructions.  
100                                                                 --pb */
101 #ifdef CONFIG_CPU_ARM710
102         .macro  arm710_bug_check, instr, temp
103         and     \temp, \instr, #0x0f000000      @ check for SWI
104         teq     \temp, #0x0f000000
105         bne     .Larm700bug
106         .endm
107
108 .Larm700bug:
109         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
110         mov     r0, r0
111         add     sp, sp, #S_FRAME_SIZE
112         subs    pc, lr, #4
113 #else
114         .macro  arm710_bug_check, instr, temp
115         .endm
116 #endif
117
118         .align  5
119 ENTRY(vector_swi)
120         sub     sp, sp, #S_FRAME_SIZE
121         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
122         add     r8, sp, #S_PC
123         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
124         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
125         str     lr, [sp, #S_PC]                 @ Save calling PC
126         str     r8, [sp, #S_PSR]                @ Save CPSR
127         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
128         zero_fp
129
130         /*
131          * Get the system call number.
132          */
133 #ifdef CONFIG_ARM_THUMB
134         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
135         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
136         ldreq   scno, [lr, #-4]
137 #else
138         ldr     scno, [lr, #-4]                 @ get SWI instruction
139 #endif
140         arm710_bug_check scno, ip
141
142 #ifdef CONFIG_ALIGNMENT_TRAP
143         ldr     ip, __cr_alignment
144         ldr     ip, [ip]
145         mcr     p15, 0, ip, c1, c0              @ update control register
146 #endif
147         enable_irq
148
149         str     r4, [sp, #-S_OFF]!              @ push fifth arg
150
151         get_thread_info tsk
152         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
153         bic     scno, scno, #0xff000000         @ mask off SWI op-code
154         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
155         adr     tbl, sys_call_table             @ load syscall table pointer
156         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
157         bne     __sys_trace
158
159         adr     lr, ret_fast_syscall            @ return address
160         cmp     scno, #NR_syscalls              @ check upper syscall limit
161         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
162
163         add     r1, sp, #S_OFF
164 2:      mov     why, #0                         @ no longer a real syscall
165         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
166         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
167         bcs     arm_syscall     
168         b       sys_ni_syscall                  @ not private func
169
170         /*
171          * This is the really slow path.  We're going to be doing
172          * context switches, and waiting for our parent to respond.
173          */
174 __sys_trace:
175         add     r1, sp, #S_OFF
176         mov     r0, #0                          @ trace entry [IP = 0]
177         bl      syscall_trace
178
179         adr     lr, __sys_trace_return          @ return address
180         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
181         cmp     scno, #NR_syscalls              @ check upper syscall limit
182         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
183         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
184         b       2b
185
186 __sys_trace_return:
187         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
188         mov     r1, sp
189         mov     r0, #1                          @ trace exit [IP = 1]
190         bl      syscall_trace
191         b       ret_slow_syscall
192
193         .align  5
194 #ifdef CONFIG_ALIGNMENT_TRAP
195         .type   __cr_alignment, #object
196 __cr_alignment:
197         .word   cr_alignment
198 #endif
199
200         .type   sys_call_table, #object
201 ENTRY(sys_call_table)
202 #include "calls.S"
203
204 /*============================================================================
205  * Special system call wrappers
206  */
207 @ r0 = syscall number
208 @ r5 = syscall table
209                 .type   sys_syscall, #function
210 sys_syscall:
211                 eor     scno, r0, #__NR_SYSCALL_BASE
212                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
213                 cmpne   scno, #NR_syscalls      @ check range
214                 stmloia sp, {r5, r6}            @ shuffle args
215                 movlo   r0, r1
216                 movlo   r1, r2
217                 movlo   r2, r3
218                 movlo   r3, r4
219                 ldrlo   pc, [tbl, scno, lsl #2]
220                 b       sys_ni_syscall
221
222 sys_fork_wrapper:
223                 add     r0, sp, #S_OFF
224                 b       sys_fork
225
226 sys_vfork_wrapper:
227                 add     r0, sp, #S_OFF
228                 b       sys_vfork
229
230 sys_execve_wrapper:
231                 add     r3, sp, #S_OFF
232                 b       sys_execve
233
234 sys_clone_wrapper:
235                 add     ip, sp, #S_OFF
236                 str     ip, [sp, #4]
237                 b       sys_clone
238
239 sys_sigsuspend_wrapper:
240                 add     r3, sp, #S_OFF
241                 b       sys_sigsuspend
242
243 sys_rt_sigsuspend_wrapper:
244                 add     r2, sp, #S_OFF
245                 b       sys_rt_sigsuspend
246
247 sys_sigreturn_wrapper:
248                 add     r0, sp, #S_OFF
249                 b       sys_sigreturn
250
251 sys_rt_sigreturn_wrapper:
252                 add     r0, sp, #S_OFF
253                 b       sys_rt_sigreturn
254
255 sys_sigaltstack_wrapper:
256                 ldr     r2, [sp, #S_OFF + S_SP]
257                 b       do_sigaltstack
258
259 sys_futex_wrapper:
260                 str     r5, [sp, #4]            @ push sixth arg
261                 b       sys_futex
262
263 sys_arm_fadvise64_64_wrapper:
264                 str     r5, [sp, #4]            @ push r5 to stack
265                 b       sys_arm_fadvise64_64
266
267 sys_mbind_wrapper:
268                 str     r5, [sp, #4]
269                 b       sys_mbind
270
271 sys_ipc_wrapper:
272                 str     r5, [sp, #4]            @ push sixth arg
273                 b       sys_ipc
274
275 /*
276  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
277  * offset, we return EINVAL.
278  */
279 sys_mmap2:
280 #if PAGE_SHIFT > 12
281                 tst     r5, #PGOFF_MASK
282                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
283                 streq   r5, [sp, #4]
284                 beq     do_mmap2
285                 mov     r0, #-EINVAL
286                 RETINSTR(mov,pc, lr)
287 #else
288                 str     r5, [sp, #4]
289                 b       do_mmap2
290 #endif