ARM: ftrace: function graph tracer support
[linux-2.6.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10
11 #include <asm/unistd.h>
12 #include <asm/ftrace.h>
13 #include <mach/entry-macro.S>
14 #include <asm/unwind.h>
15
16 #include "entry-header.S"
17
18
19         .align  5
20 /*
21  * This is the fast syscall return path.  We do as little as
22  * possible here, and this includes saving r0 back into the SVC
23  * stack.
24  */
25 ret_fast_syscall:
26  UNWIND(.fnstart        )
27  UNWIND(.cantunwind     )
28         disable_irq                             @ disable interrupts
29         ldr     r1, [tsk, #TI_FLAGS]
30         tst     r1, #_TIF_WORK_MASK
31         bne     fast_work_pending
32
33         /* perform architecture specific actions before user return */
34         arch_ret_to_user r1, lr
35
36         restore_user_regs fast = 1, offset = S_OFF
37  UNWIND(.fnend          )
38
39 /*
40  * Ok, we need to do extra processing, enter the slow path.
41  */
42 fast_work_pending:
43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
44 work_pending:
45         tst     r1, #_TIF_NEED_RESCHED
46         bne     work_resched
47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
48         beq     no_work_pending
49         mov     r0, sp                          @ 'regs'
50         mov     r2, why                         @ 'syscall'
51         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
52         movne   why, #0                         @ prevent further restarts
53         bl      do_notify_resume
54         b       ret_slow_syscall                @ Check work again
55
56 work_resched:
57         bl      schedule
58 /*
59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
60  */
61 ENTRY(ret_to_user)
62 ret_slow_syscall:
63         disable_irq                             @ disable interrupts
64         ldr     r1, [tsk, #TI_FLAGS]
65         tst     r1, #_TIF_WORK_MASK
66         bne     work_pending
67 no_work_pending:
68         /* perform architecture specific actions before user return */
69         arch_ret_to_user r1, lr
70
71         restore_user_regs fast = 0, offset = 0
72 ENDPROC(ret_to_user)
73
74 /*
75  * This is how we return from a fork.
76  */
77 ENTRY(ret_from_fork)
78         bl      schedule_tail
79         get_thread_info tsk
80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
81         mov     why, #1
82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
83         beq     ret_slow_syscall
84         mov     r1, sp
85         mov     r0, #1                          @ trace exit [IP = 1]
86         bl      syscall_trace
87         b       ret_slow_syscall
88 ENDPROC(ret_from_fork)
89
90         .equ NR_syscalls,0
91 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
92 #include "calls.S"
93 #undef CALL
94 #define CALL(x) .long x
95
96 #ifdef CONFIG_FUNCTION_TRACER
97 /*
98  * When compiling with -pg, gcc inserts a call to the mcount routine at the
99  * start of every function.  In mcount, apart from the function's address (in
100  * lr), we need to get hold of the function's caller's address.
101  *
102  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
103  *
104  *      bl      mcount
105  *
106  * These versions have the limitation that in order for the mcount routine to
107  * be able to determine the function's caller's address, an APCS-style frame
108  * pointer (which is set up with something like the code below) is required.
109  *
110  *      mov     ip, sp
111  *      push    {fp, ip, lr, pc}
112  *      sub     fp, ip, #4
113  *
114  * With EABI, these frame pointers are not available unless -mapcs-frame is
115  * specified, and if building as Thumb-2, not even then.
116  *
117  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
118  * with call sites like:
119  *
120  *      push    {lr}
121  *      bl      __gnu_mcount_nc
122  *
123  * With these compilers, frame pointers are not necessary.
124  *
125  * mcount can be thought of as a function called in the middle of a subroutine
126  * call.  As such, it needs to be transparent for both the caller and the
127  * callee: the original lr needs to be restored when leaving mcount, and no
128  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
129  * clobber the ip register.  This is OK because the ARM calling convention
130  * allows it to be clobbered in subroutines and doesn't use it to hold
131  * parameters.)
132  *
133  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
134  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
135  * arch/arm/kernel/ftrace.c).
136  */
137
138 #ifndef CONFIG_OLD_MCOUNT
139 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
140 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
141 #endif
142 #endif
143
144 .macro __mcount suffix
145         mcount_enter
146         ldr     r0, =ftrace_trace_function
147         ldr     r2, [r0]
148         adr     r0, .Lftrace_stub
149         cmp     r0, r2
150         bne     1f
151
152 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
153         ldr     r1, =ftrace_graph_return
154         ldr     r2, [r1]
155         cmp     r0, r2
156         bne     ftrace_graph_caller\suffix
157
158         ldr     r1, =ftrace_graph_entry
159         ldr     r2, [r1]
160         ldr     r0, =ftrace_graph_entry_stub
161         cmp     r0, r2
162         bne     ftrace_graph_caller\suffix
163 #endif
164
165         mcount_exit
166
167 1:      mcount_get_lr   r1                      @ lr of instrumented func
168         mov     r0, lr                          @ instrumented function
169         sub     r0, r0, #MCOUNT_INSN_SIZE
170         adr     lr, BSYM(2f)
171         mov     pc, r2
172 2:      mcount_exit
173 .endm
174
175 .macro __ftrace_caller suffix
176         mcount_enter
177
178         mcount_get_lr   r1                      @ lr of instrumented func
179         mov     r0, lr                          @ instrumented function
180         sub     r0, r0, #MCOUNT_INSN_SIZE
181
182         .globl ftrace_call\suffix
183 ftrace_call\suffix:
184         bl      ftrace_stub
185
186         mcount_exit
187 .endm
188
189 .macro __ftrace_graph_caller
190         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
191         mov     r1, lr                  @ instrumented routine (func)
192         sub     r1, r1, #MCOUNT_INSN_SIZE
193         mov     r2, fp                  @ frame pointer
194         bl      prepare_ftrace_return
195         mcount_exit
196 .endm
197
198 #ifdef CONFIG_OLD_MCOUNT
199 /*
200  * mcount
201  */
202
203 .macro mcount_enter
204         stmdb   sp!, {r0-r3, lr}
205 .endm
206
207 .macro mcount_get_lr reg
208         ldr     \reg, [fp, #-4]
209 .endm
210
211 .macro mcount_exit
212         ldr     lr, [fp, #-4]
213         ldmia   sp!, {r0-r3, pc}
214 .endm
215
216 ENTRY(mcount)
217 #ifdef CONFIG_DYNAMIC_FTRACE
218         stmdb   sp!, {lr}
219         ldr     lr, [fp, #-4]
220         ldmia   sp!, {pc}
221 #else
222         __mcount _old
223 #endif
224 ENDPROC(mcount)
225
226 #ifdef CONFIG_DYNAMIC_FTRACE
227 ENTRY(ftrace_caller_old)
228         __ftrace_caller _old
229 ENDPROC(ftrace_caller_old)
230 #endif
231
232 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
233 ENTRY(ftrace_graph_caller_old)
234         __ftrace_graph_caller
235 ENDPROC(ftrace_graph_caller_old)
236 #endif
237
238 .purgem mcount_enter
239 .purgem mcount_get_lr
240 .purgem mcount_exit
241 #endif
242
243 /*
244  * __gnu_mcount_nc
245  */
246
247 .macro mcount_enter
248         stmdb   sp!, {r0-r3, lr}
249 .endm
250
251 .macro mcount_get_lr reg
252         ldr     \reg, [sp, #20]
253 .endm
254
255 .macro mcount_exit
256         ldmia   sp!, {r0-r3, ip, lr}
257         mov     pc, ip
258 .endm
259
260 ENTRY(__gnu_mcount_nc)
261 #ifdef CONFIG_DYNAMIC_FTRACE
262         mov     ip, lr
263         ldmia   sp!, {lr}
264         mov     pc, ip
265 #else
266         __mcount
267 #endif
268 ENDPROC(__gnu_mcount_nc)
269
270 #ifdef CONFIG_DYNAMIC_FTRACE
271 ENTRY(ftrace_caller)
272         __ftrace_caller
273 ENDPROC(ftrace_caller)
274 #endif
275
276 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
277 ENTRY(ftrace_graph_caller)
278         __ftrace_graph_caller
279 ENDPROC(ftrace_graph_caller)
280 #endif
281
282 .purgem mcount_enter
283 .purgem mcount_get_lr
284 .purgem mcount_exit
285
286 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
287         .globl return_to_handler
288 return_to_handler:
289         stmdb   sp!, {r0-r3}
290         mov     r0, fp                  @ frame pointer
291         bl      ftrace_return_to_handler
292         mov     lr, r0                  @ r0 has real ret addr
293         ldmia   sp!, {r0-r3}
294         mov     pc, lr
295 #endif
296
297 ENTRY(ftrace_stub)
298 .Lftrace_stub:
299         mov     pc, lr
300 ENDPROC(ftrace_stub)
301
302 #endif /* CONFIG_FUNCTION_TRACER */
303
304 /*=============================================================================
305  * SWI handler
306  *-----------------------------------------------------------------------------
307  */
308
309         /* If we're optimising for StrongARM the resulting code won't 
310            run on an ARM7 and we can save a couple of instructions.  
311                                                                 --pb */
312 #ifdef CONFIG_CPU_ARM710
313 #define A710(code...) code
314 .Larm710bug:
315         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
316         mov     r0, r0
317         add     sp, sp, #S_FRAME_SIZE
318         subs    pc, lr, #4
319 #else
320 #define A710(code...)
321 #endif
322
323         .align  5
324 ENTRY(vector_swi)
325         sub     sp, sp, #S_FRAME_SIZE
326         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
327  ARM(   add     r8, sp, #S_PC           )
328  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
329  THUMB( mov     r8, sp                  )
330  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
331         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
332         str     lr, [sp, #S_PC]                 @ Save calling PC
333         str     r8, [sp, #S_PSR]                @ Save CPSR
334         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
335         zero_fp
336
337         /*
338          * Get the system call number.
339          */
340
341 #if defined(CONFIG_OABI_COMPAT)
342
343         /*
344          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
345          * value to determine if it is an EABI or an old ABI call.
346          */
347 #ifdef CONFIG_ARM_THUMB
348         tst     r8, #PSR_T_BIT
349         movne   r10, #0                         @ no thumb OABI emulation
350         ldreq   r10, [lr, #-4]                  @ get SWI instruction
351 #else
352         ldr     r10, [lr, #-4]                  @ get SWI instruction
353   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
354   A710( teq     ip, #0x0f000000                                         )
355   A710( bne     .Larm710bug                                             )
356 #endif
357 #ifdef CONFIG_CPU_ENDIAN_BE8
358         rev     r10, r10                        @ little endian instruction
359 #endif
360
361 #elif defined(CONFIG_AEABI)
362
363         /*
364          * Pure EABI user space always put syscall number into scno (r7).
365          */
366   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
367   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
368   A710( teq     ip, #0x0f000000                                         )
369   A710( bne     .Larm710bug                                             )
370
371 #elif defined(CONFIG_ARM_THUMB)
372
373         /* Legacy ABI only, possibly thumb mode. */
374         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
375         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
376         ldreq   scno, [lr, #-4]
377
378 #else
379
380         /* Legacy ABI only. */
381         ldr     scno, [lr, #-4]                 @ get SWI instruction
382   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
383   A710( teq     ip, #0x0f000000                                         )
384   A710( bne     .Larm710bug                                             )
385
386 #endif
387
388 #ifdef CONFIG_ALIGNMENT_TRAP
389         ldr     ip, __cr_alignment
390         ldr     ip, [ip]
391         mcr     p15, 0, ip, c1, c0              @ update control register
392 #endif
393         enable_irq
394
395         get_thread_info tsk
396         adr     tbl, sys_call_table             @ load syscall table pointer
397
398 #if defined(CONFIG_OABI_COMPAT)
399         /*
400          * If the swi argument is zero, this is an EABI call and we do nothing.
401          *
402          * If this is an old ABI call, get the syscall number into scno and
403          * get the old ABI syscall table address.
404          */
405         bics    r10, r10, #0xff000000
406         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
407         ldrne   tbl, =sys_oabi_call_table
408 #elif !defined(CONFIG_AEABI)
409         bic     scno, scno, #0xff000000         @ mask off SWI op-code
410         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
411 #endif
412
413         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
414         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
415
416 #ifdef CONFIG_SECCOMP
417         tst     r10, #_TIF_SECCOMP
418         beq     1f
419         mov     r0, scno
420         bl      __secure_computing      
421         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
422         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
423 1:
424 #endif
425
426         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
427         bne     __sys_trace
428
429         cmp     scno, #NR_syscalls              @ check upper syscall limit
430         adr     lr, BSYM(ret_fast_syscall)      @ return address
431         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
432
433         add     r1, sp, #S_OFF
434 2:      mov     why, #0                         @ no longer a real syscall
435         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
436         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
437         bcs     arm_syscall     
438         b       sys_ni_syscall                  @ not private func
439 ENDPROC(vector_swi)
440
441         /*
442          * This is the really slow path.  We're going to be doing
443          * context switches, and waiting for our parent to respond.
444          */
445 __sys_trace:
446         mov     r2, scno
447         add     r1, sp, #S_OFF
448         mov     r0, #0                          @ trace entry [IP = 0]
449         bl      syscall_trace
450
451         adr     lr, BSYM(__sys_trace_return)    @ return address
452         mov     scno, r0                        @ syscall number (possibly new)
453         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
454         cmp     scno, #NR_syscalls              @ check upper syscall limit
455         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
456         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
457         b       2b
458
459 __sys_trace_return:
460         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
461         mov     r2, scno
462         mov     r1, sp
463         mov     r0, #1                          @ trace exit [IP = 1]
464         bl      syscall_trace
465         b       ret_slow_syscall
466
467         .align  5
468 #ifdef CONFIG_ALIGNMENT_TRAP
469         .type   __cr_alignment, #object
470 __cr_alignment:
471         .word   cr_alignment
472 #endif
473         .ltorg
474
475 /*
476  * This is the syscall table declaration for native ABI syscalls.
477  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
478  */
479 #define ABI(native, compat) native
480 #ifdef CONFIG_AEABI
481 #define OBSOLETE(syscall) sys_ni_syscall
482 #else
483 #define OBSOLETE(syscall) syscall
484 #endif
485
486         .type   sys_call_table, #object
487 ENTRY(sys_call_table)
488 #include "calls.S"
489 #undef ABI
490 #undef OBSOLETE
491
492 /*============================================================================
493  * Special system call wrappers
494  */
495 @ r0 = syscall number
496 @ r8 = syscall table
497 sys_syscall:
498                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
499                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
500                 cmpne   scno, #NR_syscalls      @ check range
501                 stmloia sp, {r5, r6}            @ shuffle args
502                 movlo   r0, r1
503                 movlo   r1, r2
504                 movlo   r2, r3
505                 movlo   r3, r4
506                 ldrlo   pc, [tbl, scno, lsl #2]
507                 b       sys_ni_syscall
508 ENDPROC(sys_syscall)
509
510 sys_fork_wrapper:
511                 add     r0, sp, #S_OFF
512                 b       sys_fork
513 ENDPROC(sys_fork_wrapper)
514
515 sys_vfork_wrapper:
516                 add     r0, sp, #S_OFF
517                 b       sys_vfork
518 ENDPROC(sys_vfork_wrapper)
519
520 sys_execve_wrapper:
521                 add     r3, sp, #S_OFF
522                 b       sys_execve
523 ENDPROC(sys_execve_wrapper)
524
525 sys_clone_wrapper:
526                 add     ip, sp, #S_OFF
527                 str     ip, [sp, #4]
528                 b       sys_clone
529 ENDPROC(sys_clone_wrapper)
530
531 sys_sigreturn_wrapper:
532                 add     r0, sp, #S_OFF
533                 mov     why, #0         @ prevent syscall restart handling
534                 b       sys_sigreturn
535 ENDPROC(sys_sigreturn_wrapper)
536
537 sys_rt_sigreturn_wrapper:
538                 add     r0, sp, #S_OFF
539                 mov     why, #0         @ prevent syscall restart handling
540                 b       sys_rt_sigreturn
541 ENDPROC(sys_rt_sigreturn_wrapper)
542
543 sys_sigaltstack_wrapper:
544                 ldr     r2, [sp, #S_OFF + S_SP]
545                 b       do_sigaltstack
546 ENDPROC(sys_sigaltstack_wrapper)
547
548 sys_statfs64_wrapper:
549                 teq     r1, #88
550                 moveq   r1, #84
551                 b       sys_statfs64
552 ENDPROC(sys_statfs64_wrapper)
553
554 sys_fstatfs64_wrapper:
555                 teq     r1, #88
556                 moveq   r1, #84
557                 b       sys_fstatfs64
558 ENDPROC(sys_fstatfs64_wrapper)
559
560 /*
561  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
562  * offset, we return EINVAL.
563  */
564 sys_mmap2:
565 #if PAGE_SHIFT > 12
566                 tst     r5, #PGOFF_MASK
567                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
568                 streq   r5, [sp, #4]
569                 beq     sys_mmap_pgoff
570                 mov     r0, #-EINVAL
571                 mov     pc, lr
572 #else
573                 str     r5, [sp, #4]
574                 b       sys_mmap_pgoff
575 #endif
576 ENDPROC(sys_mmap2)
577
578 #ifdef CONFIG_OABI_COMPAT
579
580 /*
581  * These are syscalls with argument register differences
582  */
583
584 sys_oabi_pread64:
585                 stmia   sp, {r3, r4}
586                 b       sys_pread64
587 ENDPROC(sys_oabi_pread64)
588
589 sys_oabi_pwrite64:
590                 stmia   sp, {r3, r4}
591                 b       sys_pwrite64
592 ENDPROC(sys_oabi_pwrite64)
593
594 sys_oabi_truncate64:
595                 mov     r3, r2
596                 mov     r2, r1
597                 b       sys_truncate64
598 ENDPROC(sys_oabi_truncate64)
599
600 sys_oabi_ftruncate64:
601                 mov     r3, r2
602                 mov     r2, r1
603                 b       sys_ftruncate64
604 ENDPROC(sys_oabi_ftruncate64)
605
606 sys_oabi_readahead:
607                 str     r3, [sp]
608                 mov     r3, r2
609                 mov     r2, r1
610                 b       sys_readahead
611 ENDPROC(sys_oabi_readahead)
612
613 /*
614  * Let's declare a second syscall table for old ABI binaries
615  * using the compatibility syscall entries.
616  */
617 #define ABI(native, compat) compat
618 #define OBSOLETE(syscall) syscall
619
620         .type   sys_oabi_call_table, #object
621 ENTRY(sys_oabi_call_table)
622 #include "calls.S"
623 #undef ABI
624 #undef OBSOLETE
625
626 #endif
627