Thumb-2: Implementation of the unified start-up and exceptions code
[linux-2.6.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10
11 #include <asm/unistd.h>
12 #include <asm/ftrace.h>
13 #include <mach/entry-macro.S>
14 #include <asm/unwind.h>
15
16 #include "entry-header.S"
17
18
19         .align  5
20 /*
21  * This is the fast syscall return path.  We do as little as
22  * possible here, and this includes saving r0 back into the SVC
23  * stack.
24  */
25 ret_fast_syscall:
26  UNWIND(.fnstart        )
27  UNWIND(.cantunwind     )
28         disable_irq                             @ disable interrupts
29         ldr     r1, [tsk, #TI_FLAGS]
30         tst     r1, #_TIF_WORK_MASK
31         bne     fast_work_pending
32
33         /* perform architecture specific actions before user return */
34         arch_ret_to_user r1, lr
35
36         restore_user_regs fast = 1, offset = S_OFF
37  UNWIND(.fnend          )
38
39 /*
40  * Ok, we need to do extra processing, enter the slow path.
41  */
42 fast_work_pending:
43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
44 work_pending:
45         tst     r1, #_TIF_NEED_RESCHED
46         bne     work_resched
47         tst     r1, #_TIF_SIGPENDING
48         beq     no_work_pending
49         mov     r0, sp                          @ 'regs'
50         mov     r2, why                         @ 'syscall'
51         bl      do_notify_resume
52         b       ret_slow_syscall                @ Check work again
53
54 work_resched:
55         bl      schedule
56 /*
57  * "slow" syscall return path.  "why" tells us if this was a real syscall.
58  */
59 ENTRY(ret_to_user)
60 ret_slow_syscall:
61         disable_irq                             @ disable interrupts
62         ldr     r1, [tsk, #TI_FLAGS]
63         tst     r1, #_TIF_WORK_MASK
64         bne     work_pending
65 no_work_pending:
66         /* perform architecture specific actions before user return */
67         arch_ret_to_user r1, lr
68
69         restore_user_regs fast = 0, offset = 0
70 ENDPROC(ret_to_user)
71
72 /*
73  * This is how we return from a fork.
74  */
75 ENTRY(ret_from_fork)
76         bl      schedule_tail
77         get_thread_info tsk
78         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
79         mov     why, #1
80         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
81         beq     ret_slow_syscall
82         mov     r1, sp
83         mov     r0, #1                          @ trace exit [IP = 1]
84         bl      syscall_trace
85         b       ret_slow_syscall
86 ENDPROC(ret_from_fork)
87
88         .equ NR_syscalls,0
89 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
90 #include "calls.S"
91 #undef CALL
92 #define CALL(x) .long x
93
94 #ifdef CONFIG_FUNCTION_TRACER
95 #ifdef CONFIG_DYNAMIC_FTRACE
96 ENTRY(mcount)
97         stmdb sp!, {r0-r3, lr}
98         mov r0, lr
99         sub r0, r0, #MCOUNT_INSN_SIZE
100
101         .globl mcount_call
102 mcount_call:
103         bl ftrace_stub
104         ldr lr, [fp, #-4]                       @ restore lr
105         ldmia sp!, {r0-r3, pc}
106
107 ENTRY(ftrace_caller)
108         stmdb sp!, {r0-r3, lr}
109         ldr r1, [fp, #-4]
110         mov r0, lr
111         sub r0, r0, #MCOUNT_INSN_SIZE
112
113         .globl ftrace_call
114 ftrace_call:
115         bl ftrace_stub
116         ldr lr, [fp, #-4]                       @ restore lr
117         ldmia sp!, {r0-r3, pc}
118
119 #else
120
121 ENTRY(mcount)
122         stmdb sp!, {r0-r3, lr}
123         ldr r0, =ftrace_trace_function
124         ldr r2, [r0]
125         adr r0, ftrace_stub
126         cmp r0, r2
127         bne trace
128         ldr lr, [fp, #-4]                       @ restore lr
129         ldmia sp!, {r0-r3, pc}
130
131 trace:
132         ldr r1, [fp, #-4]                       @ lr of instrumented routine
133         mov r0, lr
134         sub r0, r0, #MCOUNT_INSN_SIZE
135         mov lr, pc
136         mov pc, r2
137         mov lr, r1                              @ restore lr
138         ldmia sp!, {r0-r3, pc}
139
140 #endif /* CONFIG_DYNAMIC_FTRACE */
141
142         .globl ftrace_stub
143 ftrace_stub:
144         mov pc, lr
145
146 #endif /* CONFIG_FUNCTION_TRACER */
147
148 /*=============================================================================
149  * SWI handler
150  *-----------------------------------------------------------------------------
151  */
152
153         /* If we're optimising for StrongARM the resulting code won't 
154            run on an ARM7 and we can save a couple of instructions.  
155                                                                 --pb */
156 #ifdef CONFIG_CPU_ARM710
157 #define A710(code...) code
158 .Larm710bug:
159         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
160         mov     r0, r0
161         add     sp, sp, #S_FRAME_SIZE
162         subs    pc, lr, #4
163 #else
164 #define A710(code...)
165 #endif
166
167         .align  5
168 ENTRY(vector_swi)
169         sub     sp, sp, #S_FRAME_SIZE
170         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
171  ARM(   add     r8, sp, #S_PC           )
172  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
173  THUMB( mov     r8, sp                  )
174  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
175         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
176         str     lr, [sp, #S_PC]                 @ Save calling PC
177         str     r8, [sp, #S_PSR]                @ Save CPSR
178         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
179         zero_fp
180
181         /*
182          * Get the system call number.
183          */
184
185 #if defined(CONFIG_OABI_COMPAT)
186
187         /*
188          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
189          * value to determine if it is an EABI or an old ABI call.
190          */
191 #ifdef CONFIG_ARM_THUMB
192         tst     r8, #PSR_T_BIT
193         movne   r10, #0                         @ no thumb OABI emulation
194         ldreq   r10, [lr, #-4]                  @ get SWI instruction
195 #else
196         ldr     r10, [lr, #-4]                  @ get SWI instruction
197   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
198   A710( teq     ip, #0x0f000000                                         )
199   A710( bne     .Larm710bug                                             )
200 #endif
201 #ifdef CONFIG_CPU_ENDIAN_BE8
202         rev     r10, r10                        @ little endian instruction
203 #endif
204
205 #elif defined(CONFIG_AEABI)
206
207         /*
208          * Pure EABI user space always put syscall number into scno (r7).
209          */
210   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
211   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
212   A710( teq     ip, #0x0f000000                                         )
213   A710( bne     .Larm710bug                                             )
214
215 #elif defined(CONFIG_ARM_THUMB)
216
217         /* Legacy ABI only, possibly thumb mode. */
218         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
219         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
220         ldreq   scno, [lr, #-4]
221
222 #else
223
224         /* Legacy ABI only. */
225         ldr     scno, [lr, #-4]                 @ get SWI instruction
226   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
227   A710( teq     ip, #0x0f000000                                         )
228   A710( bne     .Larm710bug                                             )
229
230 #endif
231
232 #ifdef CONFIG_ALIGNMENT_TRAP
233         ldr     ip, __cr_alignment
234         ldr     ip, [ip]
235         mcr     p15, 0, ip, c1, c0              @ update control register
236 #endif
237         enable_irq
238
239         get_thread_info tsk
240         adr     tbl, sys_call_table             @ load syscall table pointer
241         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
242
243 #if defined(CONFIG_OABI_COMPAT)
244         /*
245          * If the swi argument is zero, this is an EABI call and we do nothing.
246          *
247          * If this is an old ABI call, get the syscall number into scno and
248          * get the old ABI syscall table address.
249          */
250         bics    r10, r10, #0xff000000
251         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
252         ldrne   tbl, =sys_oabi_call_table
253 #elif !defined(CONFIG_AEABI)
254         bic     scno, scno, #0xff000000         @ mask off SWI op-code
255         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
256 #endif
257
258         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
259         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
260         bne     __sys_trace
261
262         cmp     scno, #NR_syscalls              @ check upper syscall limit
263         adr     lr, BSYM(ret_fast_syscall)      @ return address
264         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
265
266         add     r1, sp, #S_OFF
267 2:      mov     why, #0                         @ no longer a real syscall
268         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
269         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
270         bcs     arm_syscall     
271         b       sys_ni_syscall                  @ not private func
272 ENDPROC(vector_swi)
273
274         /*
275          * This is the really slow path.  We're going to be doing
276          * context switches, and waiting for our parent to respond.
277          */
278 __sys_trace:
279         mov     r2, scno
280         add     r1, sp, #S_OFF
281         mov     r0, #0                          @ trace entry [IP = 0]
282         bl      syscall_trace
283
284         adr     lr, BSYM(__sys_trace_return)    @ return address
285         mov     scno, r0                        @ syscall number (possibly new)
286         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
287         cmp     scno, #NR_syscalls              @ check upper syscall limit
288         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
289         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
290         b       2b
291
292 __sys_trace_return:
293         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
294         mov     r2, scno
295         mov     r1, sp
296         mov     r0, #1                          @ trace exit [IP = 1]
297         bl      syscall_trace
298         b       ret_slow_syscall
299
300         .align  5
301 #ifdef CONFIG_ALIGNMENT_TRAP
302         .type   __cr_alignment, #object
303 __cr_alignment:
304         .word   cr_alignment
305 #endif
306         .ltorg
307
308 /*
309  * This is the syscall table declaration for native ABI syscalls.
310  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
311  */
312 #define ABI(native, compat) native
313 #ifdef CONFIG_AEABI
314 #define OBSOLETE(syscall) sys_ni_syscall
315 #else
316 #define OBSOLETE(syscall) syscall
317 #endif
318
319         .type   sys_call_table, #object
320 ENTRY(sys_call_table)
321 #include "calls.S"
322 #undef ABI
323 #undef OBSOLETE
324
325 /*============================================================================
326  * Special system call wrappers
327  */
328 @ r0 = syscall number
329 @ r8 = syscall table
330 sys_syscall:
331                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
332                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
333                 cmpne   scno, #NR_syscalls      @ check range
334                 stmloia sp, {r5, r6}            @ shuffle args
335                 movlo   r0, r1
336                 movlo   r1, r2
337                 movlo   r2, r3
338                 movlo   r3, r4
339                 ldrlo   pc, [tbl, scno, lsl #2]
340                 b       sys_ni_syscall
341 ENDPROC(sys_syscall)
342
343 sys_fork_wrapper:
344                 add     r0, sp, #S_OFF
345                 b       sys_fork
346 ENDPROC(sys_fork_wrapper)
347
348 sys_vfork_wrapper:
349                 add     r0, sp, #S_OFF
350                 b       sys_vfork
351 ENDPROC(sys_vfork_wrapper)
352
353 sys_execve_wrapper:
354                 add     r3, sp, #S_OFF
355                 b       sys_execve
356 ENDPROC(sys_execve_wrapper)
357
358 sys_clone_wrapper:
359                 add     ip, sp, #S_OFF
360                 str     ip, [sp, #4]
361                 b       sys_clone
362 ENDPROC(sys_clone_wrapper)
363
364 sys_sigsuspend_wrapper:
365                 add     r3, sp, #S_OFF
366                 b       sys_sigsuspend
367 ENDPROC(sys_sigsuspend_wrapper)
368
369 sys_rt_sigsuspend_wrapper:
370                 add     r2, sp, #S_OFF
371                 b       sys_rt_sigsuspend
372 ENDPROC(sys_rt_sigsuspend_wrapper)
373
374 sys_sigreturn_wrapper:
375                 add     r0, sp, #S_OFF
376                 b       sys_sigreturn
377 ENDPROC(sys_sigreturn_wrapper)
378
379 sys_rt_sigreturn_wrapper:
380                 add     r0, sp, #S_OFF
381                 b       sys_rt_sigreturn
382 ENDPROC(sys_rt_sigreturn_wrapper)
383
384 sys_sigaltstack_wrapper:
385                 ldr     r2, [sp, #S_OFF + S_SP]
386                 b       do_sigaltstack
387 ENDPROC(sys_sigaltstack_wrapper)
388
389 sys_statfs64_wrapper:
390                 teq     r1, #88
391                 moveq   r1, #84
392                 b       sys_statfs64
393 ENDPROC(sys_statfs64_wrapper)
394
395 sys_fstatfs64_wrapper:
396                 teq     r1, #88
397                 moveq   r1, #84
398                 b       sys_fstatfs64
399 ENDPROC(sys_fstatfs64_wrapper)
400
401 /*
402  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
403  * offset, we return EINVAL.
404  */
405 sys_mmap2:
406 #if PAGE_SHIFT > 12
407                 tst     r5, #PGOFF_MASK
408                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
409                 streq   r5, [sp, #4]
410                 beq     do_mmap2
411                 mov     r0, #-EINVAL
412                 mov     pc, lr
413 #else
414                 str     r5, [sp, #4]
415                 b       do_mmap2
416 #endif
417 ENDPROC(sys_mmap2)
418
419 ENTRY(pabort_ifar)
420                 mrc     p15, 0, r0, cr6, cr0, 2
421 ENTRY(pabort_noifar)
422                 mov     pc, lr
423 ENDPROC(pabort_ifar)
424 ENDPROC(pabort_noifar)
425
426 #ifdef CONFIG_OABI_COMPAT
427
428 /*
429  * These are syscalls with argument register differences
430  */
431
432 sys_oabi_pread64:
433                 stmia   sp, {r3, r4}
434                 b       sys_pread64
435 ENDPROC(sys_oabi_pread64)
436
437 sys_oabi_pwrite64:
438                 stmia   sp, {r3, r4}
439                 b       sys_pwrite64
440 ENDPROC(sys_oabi_pwrite64)
441
442 sys_oabi_truncate64:
443                 mov     r3, r2
444                 mov     r2, r1
445                 b       sys_truncate64
446 ENDPROC(sys_oabi_truncate64)
447
448 sys_oabi_ftruncate64:
449                 mov     r3, r2
450                 mov     r2, r1
451                 b       sys_ftruncate64
452 ENDPROC(sys_oabi_ftruncate64)
453
454 sys_oabi_readahead:
455                 str     r3, [sp]
456                 mov     r3, r2
457                 mov     r2, r1
458                 b       sys_readahead
459 ENDPROC(sys_oabi_readahead)
460
461 /*
462  * Let's declare a second syscall table for old ABI binaries
463  * using the compatibility syscall entries.
464  */
465 #define ABI(native, compat) compat
466 #define OBSOLETE(syscall) syscall
467
468         .type   sys_oabi_call_table, #object
469 ENTRY(sys_oabi_call_table)
470 #include "calls.S"
471 #undef ABI
472 #undef OBSOLETE
473
474 #endif
475