kmemleak: Initialise kmemleak after debug_objects_mem_init()
[linux-2.6.git] / arch / arm / boot / compressed / vmlinux.lds.in
1 /*
2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10 OUTPUT_ARCH(arm)
11 ENTRY(_start)
12 SECTIONS
13 {
14   /DISCARD/ : {
15     *(.ARM.exidx*)
16     *(.ARM.extab*)
17     /*
18      * Discard any r/w data - this produces a link error if we have any,
19      * which is required for PIC decompression.  Local data generates
20      * GOTOFF relocations, which prevents it being relocated independently
21      * of the text/got segments.
22      */
23     *(.data)
24   }
25
26   . = TEXT_START;
27   _text = .;
28
29   .text : {
30     _start = .;
31     *(.start)
32     *(.text)
33     *(.text.*)
34     *(.fixup)
35     *(.gnu.warning)
36     *(.rodata)
37     *(.rodata.*)
38     *(.glue_7)
39     *(.glue_7t)
40     *(.piggydata)
41     . = ALIGN(4);
42   }
43
44   _etext = .;
45
46   _got_start = .;
47   .got                  : { *(.got) }
48   _got_end = .;
49   .got.plt              : { *(.got.plt) }
50   _edata = .;
51
52   . = BSS_START;
53   __bss_start = .;
54   .bss                  : { *(.bss) }
55   _end = .;
56
57   .stack                : { *(.stack) }
58
59   .stab 0               : { *(.stab) }
60   .stabstr 0            : { *(.stabstr) }
61   .stab.excl 0          : { *(.stab.excl) }
62   .stab.exclstr 0       : { *(.stab.exclstr) }
63   .stab.index 0         : { *(.stab.index) }
64   .stab.indexstr 0      : { *(.stab.indexstr) }
65   .comment 0            : { *(.comment) }
66 }
67