First version
[3rdparty/ote_partner/tlk.git] / arch / arm / arm / monitor_interface.S
1 /*
2  * Copyright (c) 2014, NVIDIA CORPORATION. All rights reserved
3  *
4  * Permission is hereby granted, free of charge, to any person obtaining
5  * a copy of this software and associated documentation files
6  * (the "Software"), to deal in the Software without restriction,
7  * including without limitation the rights to use, copy, modify, merge,
8  * publish, distribute, sublicense, and/or sell copies of the Software,
9  * and to permit persons to whom the Software is furnished to do so,
10  * subject to the following conditions:
11  *
12  * The above copyright notice and this permission notice shall be
13  * included in all copies or substantial portions of the Software.
14  *
15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
16  * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
17  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
18  * IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
19  * CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
20  * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
21  * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
22  */
23 #include <asm.h>
24 #include <lib/monitor/monitor_vector.h>
25
26 /* registers in a struct tz_monitor_frame: (r0-r12, pc, spsr) */
27 #define TZ_MONITOR_FRAME_REG_COUNT      (13 + 2)
28
29 .macro copy_frame, dst, src, tmp_low, tmp_high
30         .rept   TZ_MONITOR_FRAME_REG_COUNT
31         ldmia   \src!, {\tmp_low, \tmp_high}
32         stmia   \dst!, {\tmp_low, \tmp_high}
33         .endr
34 .endm
35
36 /* corrupts r0-r3 */
37 .macro send_shared_smc_addr
38         adr     r2, mon_smc_args_res
39         ldr     r3, =__load_phys_offset
40         ldr     r3, [r3]
41
42         ldr     r0, =SMC_TOS_INIT_SHARED_ADDR
43         sub     r1, r2, r3      /* r1: phys mon_smc_args_res */
44         smc     #0
45
46         /* update flag */
47         mov     r2, #1
48         str     r2, sent_shared_smc_addr
49 .endm
50
51 /* takes smc_type and frame ptr */
52 FUNCTION(monitor_send_receive)
53         push    {r4-r5}
54
55         /* save smc_type and frame ptr */
56         mov     r4, r0
57         mov     r5, r1
58
59         /* if needed, send shared mon_smc_args */
60         ldr     r2, sent_shared_smc_addr
61         cmp     r2, #0
62         bne     1f
63
64         /* send phys address of buffer (corrupts r0-r3) */
65         send_shared_smc_addr
66
67         mov     r0, r4
68         mov     r1, r5
69
70 1:
71         /* copy from frame to mon_smc_args_res */
72         adr     r0, mon_smc_args_res
73         copy_frame r0, r1, r2, r3
74         mov     r0, r4
75
76         smc     #0
77
78         /* copy from mon_smc_args_res to frame */
79         adr     r0, mon_smc_args_res
80         mov     r1, r5
81         copy_frame r1, r0, r2, r3
82         mov     r0, r4
83
84         /*
85          * On return from SMC_TOS_COMPLETION or SMC_TOS_INITIAL_NS_RETURN,
86          * a new SMC is incoming. For compatibility, set the return value
87          * to the frame.
88          *
89          * For all other types (e.g. CALLBACK), the return value comes from
90          * the monitor filled in frame.
91          */
92         ldr     r3, =SMC_TOS_COMPLETION
93         cmp     r0, r3
94         ldrne   r3, =SMC_TOS_INITIAL_NS_RETURN
95         cmpne   r0, r3
96
97         moveq   r0, r5                  /* return frame ptr in r0 */
98         adrne   r1, mon_smc_args_res
99         ldrne   r0, [r1]                /* otherwise, r0 from the frame */
100
101         pop     {r4-r5}
102         mov     pc, lr                  /* return */
103
104 .align 3
105 mon_smc_args_res:
106         .rept   TZ_MONITOR_FRAME_REG_COUNT
107         .quad   0
108         .endr
109
110 sent_shared_smc_addr:
111         .int 0